774900_fr-FR

liliconcom

Un rapport ANOM est groupé par colonne et comporte donc plusieurs rapports récapitulatifs. Comment extraire chaque rapport récapitulatif dans une table de données ?

Automatisation et scriptsmacOSRe : Avoir un rapport ANOM regroupé par une colonne et donc avoir plusieurs rapports de synthèse. Comment extraire chaque rapport récapitulatif dans un tableau de données ?

Y a-t-il un problème spécifique avec le script dans l'image que vous avez fournie ? Il semble qu'il accèderait aux zones de tableau, puis utiliserait << Make Into Data Table pour créer des tableaux.

Vous pouvez également envisager d'accéder uniquement à la première zone de tableau et d'utiliser << Créer un tableau de données combinées à la place.

Re : Avoir un rapport ANOM regroupé par une colonne et donc avoir plusieurs rapports de synthèse. Comment extraire chaque rapport récapitulatif dans un tableau de données ?

merci pour la réponse Jarmo

J'ai un rapport à sens unique qui est regroupé par colonne et devrait donc afficher plusieurs rapports.

L'exécution du script affiche les éléments regroupés par colonne comme prévu. Cependant, le rapport enregistré dans le tableau de données n'affiche qu'un seul rapport aller simple.

La syntaxe de script de sauvegarde par groupe pourrait-elle fonctionner pour cela ? et comment est-il mis en œuvre

Re : Avoir un rapport ANOM regroupé par une colonne et donc avoir plusieurs rapports de synthèse. Comment extraire chaque rapport récapitulatif dans un tableau de données ?

Veuillez partager votre code sous forme de texte en utilisant le bloc de code JSL et non sous forme d'images.

Je ne suis toujours pas sûr de ce qui ne va pas (peut-être parce que je ne vois que des parties du code). Avez-vous vérifié que la variable rpt a ce que vous pensez qu'elle a ? Où obtenez-vous le décompte des boîtes de table ? Quelle version de JMP utilisez-vous ? Utilisez-vous LLM pour vous aider dans votre JSL ?

Mais voici deux exemples de ce que je pense que vous essayez de faire

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Column(dt, "age") << Set Data Type("Character");

ow = dt << Oneway(
	Y(:height),
	X(:age),
	ANOM(1, Show Summary Report(1), Point Options("Show Needles")),
	By(:sex)
);

dt_res = Report(ow[1])[Outline Box("Analysis of Means Summary"), Table Box(1)] << Make Combined Data Table;


// Or by looping
dt_res2 = Empty();
For Each({cur_ow}, ow,
	cur_group = Word(-1, Report(cur_ow) << Get Title, "=");
	dt_group = Report(cur_ow)[Outline Box("Analysis of Means Summary"), Table Box(1)] << Make Into Data Table;
	dt_group << New Column("Column", Character, Nominal, Set Each Value(cur_group));
	If(Is Empty(dt_res2),
		dt_res2 = dt_group;
	,
		dt_res2 << Concatenate(
			dt_group,
			"Append to first table"
		);
		Close(dt_group, no save);
	);
);