773540_es-ES

liliconcom

Obtener datos XML a JMP

Hola, estoy intentando recuperar datos meteorológicos desde XML (servicio meteorológico finlandés: https://en.ilmatieteenlaitos.fi/open-data-manual-fmi-wfs-services ) a JMP de forma que el usuario pueda definir la hora. período. Mi código no funciona, siempre aparece el mensaje de error "Estado de solicitud HTTP no válido".

// User-defined start and end dates (modify as needed)
startDate = "2024-07-10";
endDate = "2024-07-24";

// Construct the URL with user-defined dates and parameters
url = "https://opendata.fmi.fi/wfs?service=WFS&version=2.0.0&request=getFeature&storedquery_id=fmi::observations::weather::timevaluepair&place=helsinki-vantaa_airport&timestep=1&starttime=" || startDate || "T00:00:00Z&endtime=" || endDate || "T23:59:59Z&parameters=temperature%2Chumidity%2Cpressure";

// Create HTTP request object
httpRequest = New HTTP Request();

// Send HTTP GET request
response = httpRequest << Send("GET", url);

// Check if the request was successful
If(response << Get Status Code == 200,

// Parse the XML response
    xmlResponse = response << Get As XML,
    
// Extract data from XML response
    dataNodes = xmlResponse << XPath("//wml2:MeasurementTVP"),
    
// Initialize lists to store data
    temperatureList = {},
    humidityList = {},
    pressureList = {},
    
// Loop through each data node and extract values
   ForEach(node in dataNodes,
        // Extract timestamp
        timestamp = node << XPath("wml2:time"),
        
        // Extract temperature value
        temperature = node << XPath("wml2:value[@parameter='temperature']"),
        temperatureValue = temperature << NodeText,
        
        // Extract humidity value
        humidity = node << XPath("wml2:value[@parameter='humidity']"),
        humidityValue = humidity << NodeText,
        
        // Extract pressure value
        pressure = node << XPath("wml2:value[@parameter='pressure']"),
        pressureValue = pressure << NodeText,
        
        // Convert timestamp to JMP DateTime format
        timestampDT = Parse DateTime(timestamp, "YYYY-MM-DDThh:mm:ssZ"),
        
        // Append data to lists
        Append(temperatureList, {timestampDT, As Number(temperatureValue)}),
        Append(humidityList, {timestampDT, As Number(humidityValue)}),
        Append(pressureList, {timestampDT, As Number(pressureValue)})
    );
    
    // Create a new JMP data table and add columns
    dt = New Table("Helsinki-Vantaa Weather Data",
        Add Rows(Num Rows(temperatureList)),
        New Column("Timestamp", Numeric, "DateTime"),
        New Column("Temperature (°C)", Numeric, "Continuous", Format(3)),
        New Column("Relative Humidity (%)", Numeric, "Continuous", Format(3)),
        New Column("Pressure (hPa)", Numeric, "Continuous", Format(3))
    );
    
// Populate the data table with values
    dt:"Timestamp" << Set Values(temperatureList);
    dt:"Temperature (°C)" << Set Values(humidityList);
    dt:"Relative Humidity (%)" << Set Values(pressureList);
    dt:"Pressure (hPa)" << Set Values(pressureList);
    
// Show the data table
    dt << Show;
,
// Display error if request failed
    Throw("Failed to fetch data. HTTP status code: " || Char(response << Get Status Code))
);

Automatización y secuencias de comandosAcceso a los datosRe: Obtener datos XML a JMP

La sintaxis de Nueva solicitud HTTP es incorrecta. Aquí hay un pequeño ejemplo que debería devolver algunos datos.

Names Default To Here(1);

startDate = "2024-07-10";
endDate = "2024-07-11";

// Construct the URL with user-defined dates and parameters
url = "https://opendata.fmi.fi/wfs?service=WFS&version=2.0.0&request=getFeature&storedquery_id=fmi::observations::weather::timevaluepair&place=helsinki-vantaa_airport&timestep=1&starttime=" || startDate || "T00:00:00Z&endtime=" || endDate || "T23:59:59Z&parameters=temperature%2Chumidity%2Cpressure";

// Create HTTP request object
request = New HTTP Request(
	Method("GET"),
	URL(url)
);

data = request << send;

/*
Show(request << Get MIME Type);
*/

Re: Obtener datos XML a JMP

Gracias @jthi, la solicitud HTTP funciona ahora, pero parece que el resto del script también es defectuoso. Esta es la primera vez que intento obtener datos de XML.

Re: Obtener datos XML a JMP

¿Parece que estás utilizando bacalao generado por LLM? Si es así, en mi opinión, son horribles con JSL.

Le sugiero que guarde los datos resultantes como un archivo xml y use la vista previa de JMP para obtener el script fuente.

Esto requerirá algo de juego, pero se puede analizar con esto (o podría usar XPath Query() o Parse XML() ).

Luego puede usar el script fuente para automatizar aún más su proceso y puede terminar con algo como

Re: Obtener datos XML a JMP

Re: Obtener datos XML a JMP

A continuación se muestra el script que utilicé (he usado datos abiertos de Ilmatieteenlaitos en JMP anteriormente, pero creo que usé datos diferentes o los analicé de una manera un poco diferente). Utiliza algunas técnicas más avanzadas como open(char to blob(), "text"), pero eso se puede evitar simplemente guardando el archivo primero como archivo de texto. También tiene limpieza de datos y creación de gráficos (verifique que los datos que crea sean correctos, no hice ninguna verificación para eso).

Ver más...

Names Default To Here(1);
/*
https://en.ilmatieteenlaitos.fi/open-data
	https://en.ilmatieteenlaitos.fi/open-data-manual-accessing-data
*/

location = "helsinki-vantaa_airport";
start_date = "2024-07-10";
end_date = "2024-07-11";

fmi_url = "https://opendata.fmi.fi/wfs?service=WFS&version=2.0.0&request=getFeature&storedquery_id=fmi::observations::weather::timevaluepair&place=^location^&timestep=1&starttime=^start_date^T00:00:00Z&endtime=^end_date^T23:59:59Z&parameters=temperature%2Chumidity%2Cpressure";


// Create HTTP request object
request = New HTTP Request(
	Method("GET"),
	URL(Eval Insert(fmi_url))
);

data = request << send;

dt = Open(
	Char to blob(data),
	XML Settings(
		Stack(0),
		Row(
			"/wfs:FeatureCollection/wfs:member/omso:PointTimeSeriesObservation/om:result/wml2:MeasurementTimeseries/wml2:point"
		),
		Col(
			"/wfs:FeatureCollection/wfs:member/omso:PointTimeSeriesObservation/om:result/wml2:MeasurementTimeseries/@gml:id",
			Column Name(
				"MeasurementID"
			),
			Fill("Use Forever"),
			Type("Character"),
			Format({"Best"}),
			Modeling Type("Continuous")
		),
		Col(
			"/wfs:FeatureCollection/wfs:member/omso:PointTimeSeriesObservation/om:result/wml2:MeasurementTimeseries/wml2:point/wml2:MeasurementTVP/wml2:time",
			Column Name(
				"Timestamp"
			),
			Fill("Use Once"),
			Type("Character"),
			Format({"Best"}),
			Modeling Type("Continuous")
		),
		Col(
			"/wfs:FeatureCollection/wfs:member/omso:PointTimeSeriesObservation/om:result/wml2:MeasurementTimeseries/wml2:point/wml2:MeasurementTVP/wml2:value",
			Column Name(
				"Value"
			),
			Fill("Use Once"),
			Type("Numeric"),
			Format({"Best"}),
			Modeling Type("Continuous")
		)
	),
	XML Wizard(0),
	"text"
);

For Each Row(dt,
	:MeasurementID = Word(-1, :MeasurementID, "-");
	:Timestamp = Substitute(:Timestamp, "Z", "");
);
Column(dt, "Timestamp") << Data Type(Numeric) << Modeling Type(Continuous) << Format("yyyy-mm-ddThh:mm:ss", 19, 0);


dt_split = dt << Split(
	Split By(:MeasurementID),
	Split(:Value),
	Group(:Timestamp),
	Output Table("FMI " || location),
	Sort by Column Property
);
Close(dt, no save);

dt_split << Delete Scripts(dt_split << Get Table Script Names);


gb = dt_split << Graph Builder(
	Size(857, 524),
	Show Control Panel(0),
	Variables(X(:Timestamp), Y(:humidity), Y(:pressure), Y(:temperature)),
	Elements(Position(1, 1), Line(X, Y, Legend(15))),
	Elements(Position(1, 2), Line(X, Y, Legend(16))),
	Elements(Position(1, 3), Line(X, Y, Legend(17)))
);
gb << Save Script to Data Table("Plot");

If you wish to see how I filled XML Wizard, you can change the XML Wizard(0), to XML Wizard(1), and run code until that point. You can then see the settings in the GUI I used. And here is some sort of explanation of what those mean

Puedes llegar bastante lejos simplemente usando Tall Guess

Pero se perderán los tipos de medidas y tendrás que hacer esos pocos cambios que hice para repetirlos en todas las filas (también puedes completar una vez -> completar el resto en la tabla JMP).

Re: Obtener datos XML a JMP

Probé el complemento de importación XML en JMP antes, pero me perdí; sin embargo, ahora, según su explicación, entiendo cómo funciona. @jthi ¡ Gracias! Además, realmente aprecio que hayas compartido la forma en que obtuviste estos datos usando open(char to blob(), "text").