773540_it-IT

liliconcom

Recupera i dati XML in JMP

Salve, sto cercando di recuperare i dati meteorologici dal formato XML (servizio meteorologico finlandese - https://en.ilmatieteenlaitos.fi/open-data-manual-fmi-wfs-services ) a JMP in modo che l'utente possa definire l'ora periodo. Il mio codice non funziona, ricevo sempre il messaggio di errore "Stato richiesta HTTP non valida".

// User-defined start and end dates (modify as needed)
startDate = "2024-07-10";
endDate = "2024-07-24";

// Construct the URL with user-defined dates and parameters
url = "https://opendata.fmi.fi/wfs?service=WFS&version=2.0.0&request=getFeature&storedquery_id=fmi::observations::weather::timevaluepair&place=helsinki-vantaa_airport&timestep=1&starttime=" || startDate || "T00:00:00Z&endtime=" || endDate || "T23:59:59Z&parameters=temperature%2Chumidity%2Cpressure";

// Create HTTP request object
httpRequest = New HTTP Request();

// Send HTTP GET request
response = httpRequest << Send("GET", url);

// Check if the request was successful
If(response << Get Status Code == 200,

// Parse the XML response
    xmlResponse = response << Get As XML,
    
// Extract data from XML response
    dataNodes = xmlResponse << XPath("//wml2:MeasurementTVP"),
    
// Initialize lists to store data
    temperatureList = {},
    humidityList = {},
    pressureList = {},
    
// Loop through each data node and extract values
   ForEach(node in dataNodes,
        // Extract timestamp
        timestamp = node << XPath("wml2:time"),
        
        // Extract temperature value
        temperature = node << XPath("wml2:value[@parameter='temperature']"),
        temperatureValue = temperature << NodeText,
        
        // Extract humidity value
        humidity = node << XPath("wml2:value[@parameter='humidity']"),
        humidityValue = humidity << NodeText,
        
        // Extract pressure value
        pressure = node << XPath("wml2:value[@parameter='pressure']"),
        pressureValue = pressure << NodeText,
        
        // Convert timestamp to JMP DateTime format
        timestampDT = Parse DateTime(timestamp, "YYYY-MM-DDThh:mm:ssZ"),
        
        // Append data to lists
        Append(temperatureList, {timestampDT, As Number(temperatureValue)}),
        Append(humidityList, {timestampDT, As Number(humidityValue)}),
        Append(pressureList, {timestampDT, As Number(pressureValue)})
    );
    
    // Create a new JMP data table and add columns
    dt = New Table("Helsinki-Vantaa Weather Data",
        Add Rows(Num Rows(temperatureList)),
        New Column("Timestamp", Numeric, "DateTime"),
        New Column("Temperature (°C)", Numeric, "Continuous", Format(3)),
        New Column("Relative Humidity (%)", Numeric, "Continuous", Format(3)),
        New Column("Pressure (hPa)", Numeric, "Continuous", Format(3))
    );
    
// Populate the data table with values
    dt:"Timestamp" << Set Values(temperatureList);
    dt:"Temperature (°C)" << Set Values(humidityList);
    dt:"Relative Humidity (%)" << Set Values(pressureList);
    dt:"Pressure (hPa)" << Set Values(pressureList);
    
// Show the data table
    dt << Show;
,
// Display error if request failed
    Throw("Failed to fetch data. HTTP status code: " || Char(response << Get Status Code))
);

Automazione e scriptingAccesso ai datiRi: Recuperare i dati XML in JMP

La sintassi per la nuova richiesta HTTP non è corretta. Ecco un piccolo esempio che dovrebbe restituire alcuni dati

Names Default To Here(1);

startDate = "2024-07-10";
endDate = "2024-07-11";

// Construct the URL with user-defined dates and parameters
url = "https://opendata.fmi.fi/wfs?service=WFS&version=2.0.0&request=getFeature&storedquery_id=fmi::observations::weather::timevaluepair&place=helsinki-vantaa_airport&timestep=1&starttime=" || startDate || "T00:00:00Z&endtime=" || endDate || "T23:59:59Z&parameters=temperature%2Chumidity%2Cpressure";

// Create HTTP request object
request = New HTTP Request(
	Method("GET"),
	URL(url)
);

data = request << send;

/*
Show(request << Get MIME Type);
*/

Ri: Recuperare i dati XML in JMP

Grazie @jthi la richiesta HTTP ora funziona, ma sembra che anche il resto dello script sia difettoso. Questa è la prima volta che provo a ottenere dati da XML.

Ri: Recuperare i dati XML in JMP

Sembra che tu stia utilizzando il codice generato da LLM? Se è così, secondo me sono orribili con JSL.

Ti suggerirei di salvare i dati risultanti come file xml e utilizzare l'anteprima di JMP per ottenere lo script sorgente

Ciò richiederà un po' di gioco, ma può essere analizzato con questo (o potrebbe utilizzare XPath Query() o Parse XML() )

Puoi quindi utilizzare lo script sorgente per automatizzare ulteriormente il tuo processo e puoi ottenere qualcosa di simile

Ri: Recuperare i dati XML in JMP

Ri: Recuperare i dati XML in JMP

Di seguito è riportato lo script che ho utilizzato (in precedenza ho utilizzato i dati aperti di Ilmatieteenlaitos in JMP, ma penso di aver utilizzato dati diversi o di averli analizzati in modo leggermente diverso). Utilizza alcune tecniche più avanzate come open(char to blob(), "text"), ma ciò può essere evitato semplicemente salvando prima il file come file di testo. Ha anche la pulizia dei dati e la creazione di grafici (verifica che i dati che crea siano corretti, non ho fatto alcun controllo per questo).

Visualizza altro...

Names Default To Here(1);
/*
https://en.ilmatieteenlaitos.fi/open-data
	https://en.ilmatieteenlaitos.fi/open-data-manual-accessing-data
*/

location = "helsinki-vantaa_airport";
start_date = "2024-07-10";
end_date = "2024-07-11";

fmi_url = "https://opendata.fmi.fi/wfs?service=WFS&version=2.0.0&request=getFeature&storedquery_id=fmi::observations::weather::timevaluepair&place=^location^&timestep=1&starttime=^start_date^T00:00:00Z&endtime=^end_date^T23:59:59Z&parameters=temperature%2Chumidity%2Cpressure";


// Create HTTP request object
request = New HTTP Request(
	Method("GET"),
	URL(Eval Insert(fmi_url))
);

data = request << send;

dt = Open(
	Char to blob(data),
	XML Settings(
		Stack(0),
		Row(
			"/wfs:FeatureCollection/wfs:member/omso:PointTimeSeriesObservation/om:result/wml2:MeasurementTimeseries/wml2:point"
		),
		Col(
			"/wfs:FeatureCollection/wfs:member/omso:PointTimeSeriesObservation/om:result/wml2:MeasurementTimeseries/@gml:id",
			Column Name(
				"MeasurementID"
			),
			Fill("Use Forever"),
			Type("Character"),
			Format({"Best"}),
			Modeling Type("Continuous")
		),
		Col(
			"/wfs:FeatureCollection/wfs:member/omso:PointTimeSeriesObservation/om:result/wml2:MeasurementTimeseries/wml2:point/wml2:MeasurementTVP/wml2:time",
			Column Name(
				"Timestamp"
			),
			Fill("Use Once"),
			Type("Character"),
			Format({"Best"}),
			Modeling Type("Continuous")
		),
		Col(
			"/wfs:FeatureCollection/wfs:member/omso:PointTimeSeriesObservation/om:result/wml2:MeasurementTimeseries/wml2:point/wml2:MeasurementTVP/wml2:value",
			Column Name(
				"Value"
			),
			Fill("Use Once"),
			Type("Numeric"),
			Format({"Best"}),
			Modeling Type("Continuous")
		)
	),
	XML Wizard(0),
	"text"
);

For Each Row(dt,
	:MeasurementID = Word(-1, :MeasurementID, "-");
	:Timestamp = Substitute(:Timestamp, "Z", "");
);
Column(dt, "Timestamp") << Data Type(Numeric) << Modeling Type(Continuous) << Format("yyyy-mm-ddThh:mm:ss", 19, 0);


dt_split = dt << Split(
	Split By(:MeasurementID),
	Split(:Value),
	Group(:Timestamp),
	Output Table("FMI " || location),
	Sort by Column Property
);
Close(dt, no save);

dt_split << Delete Scripts(dt_split << Get Table Script Names);


gb = dt_split << Graph Builder(
	Size(857, 524),
	Show Control Panel(0),
	Variables(X(:Timestamp), Y(:humidity), Y(:pressure), Y(:temperature)),
	Elements(Position(1, 1), Line(X, Y, Legend(15))),
	Elements(Position(1, 2), Line(X, Y, Legend(16))),
	Elements(Position(1, 3), Line(X, Y, Legend(17)))
);
gb << Save Script to Data Table("Plot");

If you wish to see how I filled XML Wizard, you can change the XML Wizard(0), to XML Wizard(1), and run code until that point. You can then see the settings in the GUI I used. And here is some sort of explanation of what those mean

Puoi arrivare molto lontano semplicemente usando Tall Guess

Ma mancheranno i tipi di misurazione e dovrai apportare quelle poche modifiche che ho fatto per ripeterle su tutte le righe (potresti anche riempire una volta -> riempi il resto nella tabella JMP).

Ri: Recuperare i dati XML in JMP

Ho già provato il componente aggiuntivo di importazione XML in JMP ma mi sono perso, tuttavia ora in base alla tua spiegazione capisco come funziona! @jthi Grazie! Inoltre, apprezzo molto che tu abbia condiviso il modo in cui hai recuperato questi dati utilizzando open(char to blob(), "text")!