773347_zh-CN

liliconcom

如何得到晶圆批次的工艺参数良率？

我想从样本数据表“Semiconductor Capability.jmp”中获取每个“批次 ID 中的晶圆 ID”的工艺参数产量。

However, I am not able to proceed as I am getting an error: "Process Screening requires at least 7 rows of data."

Names Default To Here (1);
clear log ();
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

col_names = dt << Get Column Group("Processes"); 
ps = dt << Process Screening (Process Variables( Eval( col_names )),  
                  Spec Limits Dialog( "No (skip columns with no spec limits)" ), 
                  Control Chart Type ("Indiv and MR"),
                  By( :wafer );// Just to demonstrate	
                  //By (:"Wafer ID in lot ID");I need this but this throws error in JMP 16.2.0 (Error: Process Screening requires at least 7 rows of data.). Why?
                  );

我哪里做错了？

一旦上述脚本适用于批次 ID 中的“按：晶圆 ID”，我希望获得以下形式的数据表（摘要？）

第 1 列：批次 ID 中的晶圆 ID

第 2 列：进程名称

第 3 列：

工艺参数产量 = 100* # 通过站点数（我认为是上述脚本给出的每个参数（5 - “超出规格数量”））/ # 根据“批次 ID 中的晶圆 ID”测量的站点数

（本示例数据案例中，每个晶圆测量了 5 个站点）

如何通过 JSL 做到这一点？

自动化和脚本视窗回复：如何获取某一批次晶圆的工艺参数良率？

您是否尝试过使用 Group 而不是 By 来对列进行分组？

回复：如何获取某一批次晶圆的工艺参数良率？

@jthi是的，我确实尝试过按“批次 ID 中的晶圆 ID”进行分组，这给了我一个包含所需数据的表格，但我无法从中提取我想要的参数产量。我正在考虑使用汇总函数，但还不确定如何使用它。任何帮助都会非常有用。

回复：如何获取某一批次晶圆的工艺参数良率？

我不确定您想使用汇总做什么？您可以很容易地从流程筛选中获得这样的表格，然后只需添加一个公式，您就应该得到您需要的内容（或者我可能遗漏了什么）

回复：如何获取某一批次晶圆的工艺参数良率？

由于这个问题已被标记为已解决，我还将提供至少某种最终解决方案

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

ps = dt << Process Screening(
	Process Variables(Column Group("Processes")),
	Grouping(:Wafer ID in lot ID),
	Control Chart Type("Indiv and MR"),
	Within Sigma(0),
	Overall Sigma(0),
	Stability Index(0),
	Mean(0),
	Show Tests(0),
	Test 1(0),
	Out of Spec Rate(0),
	Latest Out of Spec(0),
	Cpk(0),
	Ppk(0)
);

dt_result = Report(ps)[Outline Box("Process Screening"), Table Box(1)] << Make Into Data Table;
ps << close window;
wait(0);

new_col = dt_result << New Column("Yield", Numeric, Continuous, Format("Percent", 12, 3), Formula(
	(:Count - :"Out of Spec Count"n) / :Count)
);
dt_result << run formulas;
new_col << delete formula;