773347_it-IT

liliconcom

Come ottenere la resa dei parametri di processo per wafer in un lotto?

Desidero ottenere la resa dei parametri di processo per "ID wafer nell'ID lotto" dalla tabella dati di esempio "Semiconductor Capability.jmp".

However, I am not able to proceed as I am getting an error: "Process Screening requires at least 7 rows of data."

Names Default To Here (1);
clear log ();
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

col_names = dt << Get Column Group("Processes"); 
ps = dt << Process Screening (Process Variables( Eval( col_names )),  
                  Spec Limits Dialog( "No (skip columns with no spec limits)" ), 
                  Control Chart Type ("Indiv and MR"),
                  By( :wafer );// Just to demonstrate	
                  //By (:"Wafer ID in lot ID");I need this but this throws error in JMP 16.2.0 (Error: Process Screening requires at least 7 rows of data.). Why?
                  );

Dove sbaglio?

Una volta che lo script sopra funziona per Per: ID wafer nell'ID lotto, vorrei ottenere una tabella dati (Riepilogo?) nel modulo

Colonna1: ID wafer nell'ID lotto

Colonna2: nomi dei processi

Colonna3:

Resa del parametro di processo = 100* # siti che passano (per parametro fornito dallo script sopra, penso (5 - "conteggio fuori specifica"))/ # siti misurati per "ID wafer in ID lotto"

(5 siti misurati per wafer in questo caso di dati di esempio)

Come farlo tramite JSL?

Automazione e scriptingfinestreRi: Come ottenere la resa dei parametri di processo per wafer in un lotto?

Hai provato a utilizzare Raggruppa anziché Per per la colonna di raggruppamento?

Ri: Come ottenere la resa dei parametri di processo per wafer in un lotto?

@jthi sì, ho provato il raggruppamento per " ID wafer in ID lotto", che mi fornisce una tabella con i dati richiesti, ma non sono stato in grado di estrarre da essa la resa dei parametri che desidero. Sto pensando di utilizzare la funzione Riepiloga ma non sono ancora sicuro di come utilizzarla. Qualsiasi aiuto sarebbe molto utile.

Ri: Come ottenere la resa dei parametri di processo per wafer in un lotto?

Non sono sicuro per cosa desideri utilizzare Riepiloga? Puoi ottenere molto facilmente una tabella come questa da Process Screening e poi aggiungi semplicemente una formula e dovresti ottenere ciò di cui hai bisogno (o forse mi manca qualcosa)

Ri: Come ottenere la resa dei parametri di processo per wafer in un lotto?

Poiché il problema è stato contrassegnato come risolto, fornirò anche almeno una sorta di soluzione finale

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

ps = dt << Process Screening(
	Process Variables(Column Group("Processes")),
	Grouping(:Wafer ID in lot ID),
	Control Chart Type("Indiv and MR"),
	Within Sigma(0),
	Overall Sigma(0),
	Stability Index(0),
	Mean(0),
	Show Tests(0),
	Test 1(0),
	Out of Spec Rate(0),
	Latest Out of Spec(0),
	Cpk(0),
	Ppk(0)
);

dt_result = Report(ps)[Outline Box("Process Screening"), Table Box(1)] << Make Into Data Table;
ps << close window;
wait(0);

new_col = dt_result << New Column("Yield", Numeric, Continuous, Format("Percent", 12, 3), Formula(
	(:Count - :"Out of Spec Count"n) / :Count)
);
dt_result << run formulas;
new_col << delete formula;