772807_fr-FR

liliconcom

Enregistrement du paramètre de mémorisation du profileur saisi dans le script de modèle

J'utilise le modèle de croissance de la fiabilité (JMP 16.2.0) et je saisis environ 20 valeurs uniques dans le profileur d'événements cumulatifs à l'aide de la fonction Mémoriser les paramètres. Malheureusement, ces valeurs ne sont pas enregistrées avec le script Reliability Growth JSL, donc chaque fois que je rouvre le modèle, je suis obligé de saisir à nouveau manuellement les 20 valeurs si je souhaite comparer les valeurs, une partie nécessaire de mon analyse.

Existe-t-il un moyen de générer le code JSL pour ces valeurs saisies que je peux joindre au script du modèle afin que lorsque je le lance, les 20 valeurs restent toujours ?

Merci!

JP

Automatisation et scriptsAnalyse de fiabilitéRe : Enregistrement du paramètre de mémorisation du profileur saisi dans le script de modèle

Je suis le développeur de la plateforme. La plateforme peut mémoriser ces paramètres dans le script enregistré depuis JMP17. Veuillez envisager une mise à niveau.

Re : Enregistrement du paramètre de mémorisation du profileur saisi dans le script de modèle

Merci pour ce conseil. J'ai ouvert une enquête concernant la mise à jour vers une version plus récente avec mon entreprise. Pendant que cela est en cours d'exploration, est-il possible de partager le script JSL que je peux utiliser immédiatement ?

Re : Enregistrement du paramètre de mémorisation du profileur saisi dans le script de modèle

Le mécanisme de mémorisation de ces paramètres dans JMP17 et les versions supérieures n'est pas applicable dans JMP16. Autrement dit, le script dans JMP17 ne sera pas reconnu dans JMP16.

Dans JMP16, cependant, vous pouvez le coder manuellement. Voici un exemple avec une brève explication :

dt = open("$Sample_Data/Reliability/NewEngineOperation.jmp");
//Following runs the platform, fit a model, and returns a handle.
//We usually call it "obj" as a convention.
obj = dt << Reliability Growth(
	Input Format( Time to Event ),
	Time to Event( :Hours ),
	Event Count( :Fixes ),
	Crow AMSAA( Show Profilers( 1 ), Show Profilers( 1 ) ),
);

//Report(obj) gets the display part that you see for "obj"
//What are in the squared brackets navigate the display and find the Profiler
//Eventually, get scriptable object command to the display of the profiler retrieves the Profiler itself. Assign it to "cef". Now "cef" can accept messages.
cef = (report(obj)["Models", "Crow-AMSAA", "Profilers", "Cumulative Events Profiler"]) << get scriptable object();
//This command sets up the profiler with desired values.
cef	<< Term Value(Hours( 5102.5, Lock( 0 ), Show( 1 ) ) );
//This command tell the profiler to "remember" the current setting.
cef << Remember Settings( "Setting 1", Differences Report( 0 ) );
//This command sets up the profiler with a different desired value.
cef << Term Value( Hours( 4032, Lock( 0 ), Show( 1 ) ) );
//This command tells the profiler to remember current setting again.
cef << Remember Settings( "Setting 2", Differences Report( 1 ) );
//The last command sets the profiler again, but no remember command follows.
cef << Term Value( Hours( 4032, Lock( 0 ), Show( 1 ) ) );