772510_it-IT

liliconcom

Crea una nuova colonna e aggiungi note

Trovo utile la proprietà Notes in una colonna JMP come mezzo per aggiungere automaticamente etichette ai grafici risultanti. Il problema che riscontro riguarda la generazione di nuove colonne di dati relative alle colonne principali e l'applicazione automatica delle note principali. Nello script seguente, avevo sperato che la linea

<< set property( "Notes", Notes );

andrebbe bene ma mi manca qualcosa. Ecco la sceneggiatura principale.

Names Default To Here( 1 );
dt = Current Data Table();
colList = dt << get column names( numeric, string );
foundCols = "";
For( i = 1, i <= N Col( dt ), i++,
	Spud = ":" || colList[i];
	Spuds = Parse( Eval Insert( Spud ) );
	Show(Spuds);
	spec = Column( dt, colList[i] ) << get property( "Spec Limits" );
	Notes = Column( dt, colList[i] ) << get property( "Notes" );
	Show(Notes);
	dt << clear select;
	If( Is Empty( spec ) == 0,
		dt << New Column(
			(Column( dt, colList[i] ) << get name) || " % Delta From Target",
			Formula(
				If( Spuds > (Spuds << get property( "Spec Limits" ))["Target"],
					Num(
						(Spuds - (Spuds << get property( "Spec Limits" ))["Target"])
						 / ((Spuds << get property( "Spec Limits" ))["USL"] - (Spuds
						 << get property( "Spec Limits" ))["Target"])
					) * 100,
					If( Spuds < (Spuds << get property( "Spec Limits" ))["Target"],
						Num(
							((Spuds << get property( "Spec Limits" ))["Target"]
							-Spuds) / ((Spuds << get property( "Spec Limits" ))[
							"LSL"] - (Spuds << get property( "Spec Limits" ))[
							"Target"]) * 100
						),
						0
					)
				)
			)
		) << set property( "Notes", Notes );
		If( Is Missing( Try( spec["LSL"], . ) ) == 0,
			dt << select where( As Column( dt, colList[i] ) + spec["LSL"] );
			Try( Column( dt, N Cols( dt ) )[dt << get selected rows] = 0 );
		);
		If( Is Missing( Try( spec["USL"], . ) ) == 0,
			dt << select where(
				As Column( dt, colList[i] ) - spec["USL"],
				current selection( "extend" )
			);
			Try( Column( dt, N Cols( dt ) )[dt << get selected rows] = 0 );
		);
		dt << select where(
			Is Missing( As Column( dt, colList[i] ) ),
			current selection( "extend" )
		);
		dt << invert row selection;
		Try( Column( dt, N Cols( dt ) )[dt << get selected rows] = 1 );
		Column( dt, N Cols( dt ) );
		If( foundCols == "",
			foundCols = ":Name(\!"" || (Column( dt, colList[i] ) << get name) ||
			" % Delta From Target\!")",
			foundCols = foundCols || ", " || ":Name(\!"" || (
			Column( dt, colList[i] ) << get name) || " % Delta From Target\!")"
		);
	);
);

Qualsiasi aiuto apprezzato

Ciao

Testa di chiave

Automazione e scriptingRe: Crea una nuova colonna e aggiungi note

Separa l'impostazione della nota in modo che avvenga dopo la nuova colonna

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

For Each({colname}, dt << Get Column Names("String"),
	curnote = Column(dt, colname) << Get Property("Notes");
	new_col = dt << New Column("A", Character, Nominal);
	new_col << Set Property("Notes", curnote);
);

o spostalo all'interno di una nuova colonna

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

For Each({colname}, dt << Get Column Names("String"),
	curnote = Column(dt, colname) << Get Property("Notes");
	new_col = dt << New Column("A", Character, Nominal, Set Property("Notes", curnote));
);

Puoi avere un'idea per lo script selezionando una colonna con una proprietà di nota, fare clic sull'intestazione con il tasto destro e selezionare Copia Copia colonne oppure puoi creare una nuova colonna e aggiungere immediatamente la proprietà e ottenere lo script dal registro avanzato

Data Table("Big Class") << New Column("Column 6",
	Numeric,
	"Continuous",
	Format("Best", 12),
	Set Property("Notes", "asdasd")
);

Ri: Crea una nuova colonna e aggiungi note

Jarmo

Ho scelto il secondo, funziona perfettamente!

Grazie

Ciao

Testa di chiave