771920_ja-JP

liliconcom

アクティブなラグのあるウィンドウタブ

こんにちは、

私のスクリプトは、二変量トレンド チャートごとに新しいタブを持つウィンドウを作成しますが、凡例が非アクティブであるという問題があります。

私の最終目標は、インタラクティブな HTML で凡例グループを強調表示できるようにすることです。

ローカル データ フィルターを追加しようとしましたが、機能しませんでした。

同じラグ分布図も追加してみました。

自分が何を間違っているのかについて、より多くのアイデアや洞察を得るのが大好きです。

names default to here(1);
dt=open("$SAMPLE_DATA/big class.jmp");

NW = New Window( "new window", Text Box( "Creation Date: " || Substitute( Format( Today(), "ddMonyyyy h:m:s" ), "-", ":" ) ),  tb = tab Box() );

sex_list = Associative Array( :sex ) << Get Keys;

For( i = 1, i <= N items( sex_list ), i++,
	dt << Clear Row States;
	dt << Select Where( :sex == sex_list[i] ) << Invert Row Selection <<  Hide and Exclude;
	dt << clear select;
		
		// create trend chart with limits
	
		Biv = dt << Bivariate(
			Y( :height ),
			X( :weight ),
/*			By( :Var ),
			Local Data Filter(
			Mode( Include( 0 ) ),
			Add Filter( columns( :CHAMBER ), Display( :CHAMBER) )
			),*/
			SendToReport(
				Dispatch(
					{},
					"Bivar Plot",
					FrameBox,
					{Frame Size( 1000, 300 ), Row Legend(
						name,
						Color( 1 ),
						Color Theme( "JMP Default"(1) ),
						Marker( 1 ),
						Marker Theme( "Standard" )
					)}
				)
			)
		);
		
		Dis = dt << Distribution( Nominal Distribution( Column( :name ), Frequencies( 0 ) ) );
	

	tb  << Append( Char(Sex_list[i]) , H list box(Report( Dis ), Report( Biv )));
	Biv << Close window;
	Dis << Close window;

);


NW << save Interactive HTML( SaveDirectory || "new window.htm" ) << close window;
dt << close window;

Re: アクティブ ラグのあるウィンドウ タブ

新しいウィンドウにレポートのみを追加すると、インタラクティブではなくなります (JMP プラットフォームには 2 つの「レイヤー」があります)。プラットフォームを追加することで、ある程度のインタラクティブ性が得られますが、凡例はインタラクティブになりません。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/big class.jmp");

NW = New Window("new window",
	Text Box("Creation Date: " || Substitute(Format(Today(), "ddMonyyyy h:m:s"), "-", ":")),
	tb = Tab Box()
);

sex_list = Associative Array(:sex) << Get Keys;

For(i = 1, i <= N Items(sex_list), i++,
	dt << Clear Row States;
	dt << Select Where(:sex == sex_list[i]) << Invert Row Selection << Hide and Exclude;
	dt << clear select;
	
	biv_expr = Expr(dt << Bivariate(
		Y(:height),
		X(:weight), 
		SendToReport(
			Dispatch({}, "Bivar Plot", FrameBox,
				{Frame Size(1000, 300), Row Legend(
					name,
					Color(1),
					Color Theme("JMP Default"(1)),
					Marker(1),
					Marker Theme("Standard")
				)}
			)
		)
	));

	dist_expr = Expr(dt << Distribution(Automatic Recalc(1), Nominal Distribution(Column(:name), Frequencies(0))));

	tb << Append(
		Char(Sex_list[i]), 
		H List Box(
			dist_expr,
			biv_expr
		)
	);
);


nw << Save Interactive HTML("$TEMP/deleteme.html");
Close(dt, no save);

Web("$TEMP/deleteme.html");

Write();

JMP18 をお持ちで、グラフ ビルダーを使用して散布図を作成する場合は、少しの追加作業でインタラクティブな凡例を取得できると思います (マーカー行の状態を使用し、グラフ ビルダーでオーバーレイ/色として同じ列を使用します)。