771920_de-DE

liliconcom

Fenstertabs mit aktiver Lag

Hallo,

mein Skript erstellt für jedes bivariate Trenddiagramm ein Fenster mit einer neuen Registerkarte. Mein Problem ist, dass die Legende inaktiv ist.

Mein Endziel ist die Möglichkeit, Legendengruppen in interaktivem HTML hervorheben zu können.

Ich habe versucht, einen lokalen Datenfilter hinzuzufügen – und es hat bei mir nicht funktioniert.

Ich habe auch versucht, dasselbe Lagenverteilungsdiagramm hinzuzufügen.

Ich freue mich über weitere Ideen oder Erkenntnisse darüber, was ich falsch mache.

names default to here(1);
dt=open("$SAMPLE_DATA/big class.jmp");

NW = New Window( "new window", Text Box( "Creation Date: " || Substitute( Format( Today(), "ddMonyyyy h:m:s" ), "-", ":" ) ),  tb = tab Box() );

sex_list = Associative Array( :sex ) << Get Keys;

For( i = 1, i <= N items( sex_list ), i++,
	dt << Clear Row States;
	dt << Select Where( :sex == sex_list[i] ) << Invert Row Selection <<  Hide and Exclude;
	dt << clear select;
		
		// create trend chart with limits
	
		Biv = dt << Bivariate(
			Y( :height ),
			X( :weight ),
/*			By( :Var ),
			Local Data Filter(
			Mode( Include( 0 ) ),
			Add Filter( columns( :CHAMBER ), Display( :CHAMBER) )
			),*/
			SendToReport(
				Dispatch(
					{},
					"Bivar Plot",
					FrameBox,
					{Frame Size( 1000, 300 ), Row Legend(
						name,
						Color( 1 ),
						Color Theme( "JMP Default"(1) ),
						Marker( 1 ),
						Marker Theme( "Standard" )
					)}
				)
			)
		);
		
		Dis = dt << Distribution( Nominal Distribution( Column( :name ), Frequencies( 0 ) ) );
	

	tb  << Append( Char(Sex_list[i]) , H list box(Report( Dis ), Report( Biv )));
	Biv << Close window;
	Dis << Close window;

);


NW << save Interactive HTML( SaveDirectory || "new window.htm" ) << close window;
dt << close window;

Betreff: Fenstertabs mit aktiver Lag

Sie fügen nur den Bericht an das neue Fenster an und das ist nicht interaktiv (es gibt zwei „Ebenen“ in JMP-Plattformen). Sie können etwas Interaktivität erreichen, indem Sie die Plattformen anhängen, ABER die Legende wird nicht interaktiv sein

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/big class.jmp");

NW = New Window("new window",
	Text Box("Creation Date: " || Substitute(Format(Today(), "ddMonyyyy h:m:s"), "-", ":")),
	tb = Tab Box()
);

sex_list = Associative Array(:sex) << Get Keys;

For(i = 1, i <= N Items(sex_list), i++,
	dt << Clear Row States;
	dt << Select Where(:sex == sex_list[i]) << Invert Row Selection << Hide and Exclude;
	dt << clear select;
	
	biv_expr = Expr(dt << Bivariate(
		Y(:height),
		X(:weight), 
		SendToReport(
			Dispatch({}, "Bivar Plot", FrameBox,
				{Frame Size(1000, 300), Row Legend(
					name,
					Color(1),
					Color Theme("JMP Default"(1)),
					Marker(1),
					Marker Theme("Standard")
				)}
			)
		)
	));

	dist_expr = Expr(dt << Distribution(Automatic Recalc(1), Nominal Distribution(Column(:name), Frequencies(0))));

	tb << Append(
		Char(Sex_list[i]), 
		H List Box(
			dist_expr,
			biv_expr
		)
	);
);


nw << Save Interactive HTML("$TEMP/deleteme.html");
Close(dt, no save);

Web("$TEMP/deleteme.html");

Write();

Wenn Sie JMP18 haben und Graph Builder zum Erstellen Ihres Streudiagramms verwenden, können Sie meiner Meinung nach mit etwas zusätzlichem Aufwand eine interaktive Legende erhalten (verwenden Sie Markierungszeilenzustände und verwenden Sie dann dieselbe Spalte als Overlay/Farbe im Graph Builder).