770561_ja-JP

liliconcom

正常性と能力

こんにちは、

1) Minitab では複数の変数の正規性をテストできますが、JMP でも同じことができますか? - 画像を参照 - Prob_normality

2) Minitab では Before と After が表示できますが、JMP でも再現できますか? - CPK Before and After を参照してください。

3) CPk および Minitab では、不適合の % ではなく PPM を表示できますが、代わりに PPM も取得できますか?

ありがとう

マイケル

データの探索と視覚化品質およびプロセスエンジニアリングウィンドウズ正常性と能力について

1. はい。[分析] > [分布] を使用して、複数の変数を選択します。Ctrl キーを押したままにします。変数名の赤い三角のメニューの 1 つから、連続分布を適合します。Ctrl キーを押すと、これがすべての変数にブロードキャストされます。Ctrl キーを押したまま、適合分布モデルの赤い三角のメニューから、適合度検定をクリックします。

2. 配信プラットフォームを起動するときに、前後のフェーズ列を By ロールに配置します。

(JMP 開発者の誰かがあなたのサンプル画像を見てくれることを願っています。JMP よりもはるかにきれいで、おそらく MS Word にきれいに貼り付けることができ、印刷もできると思います。)

3. 不適合レポートの列を右クリックするとメニューがポップアップ表示されるので、列をクリックして必要な追加の統計情報をオンにします。

良い点としては、JMP では多くの変数を素早く確認しやすく、データをテーブルに簡単かつ動的にリンクできることです。

また、Fit Continuous の最後のオプションを試してください。このオプションは、多数の分布モデルを適合させて順番にランク付けし、適合分布のいずれかから RTM の工程能力を選択します。データを変換せずに Cpk Ppk を取得できます。

正常性と能力について

Minitab との徹底的な比較については、以下をお読みになることをお勧めします。

Minitab® から JMP® への移行: 移行ガイド、バージョン 2

https://www.jmp.com/en_us/whitepapers/jmp/moving-from-minitab-to-jmp-and-jmp-pro-a-transition-guide-version-2.html

正常性と能力について

こんにちは、

1 と 3 は明確です。動作しています。2 についてもう少し具体的に教えていただけますか?

ありがとう

マイケル

正常性と能力について

JMP テーブルに、before/after のようなタイトルの列があるはずです。分布プラットフォームを実行する場合、By オプションを入力するオプションがあります。By オプションで before after 列を使用すると、前後の分布が表示されます。

 

 

正常性と能力について

prob_normalityの問題に関しては、ぜひ投票していただきたい。
https://community.jmp.com/t5/JMP-Wish-List/Add-CDFs-to-Graph-Builder/idi-p/551634

ここでも私はバイロンの希望を共有します。

@Byron_JMP は次のように書いています:

JMP 開発者の誰かがあなたのサンプル画像を見てくれることを願っています。JMP よりもはるかにきれいで、おそらく MS Word にきれいに貼り付けることができ、印刷もできると思います。

CDF が Graph Builder で利用できるようになると、Minitab とのこのギャップは解消されます。
たぶんJMP18.1でしょうか?

そしていま？

回避策のコレクションについては、 「JMP で累積確率プロットを作成する方法」を参照してください。

正常性と能力について

こんにちは、

1 列目に測定値、2 列目にステータスがあるにもかかわらず、Minitab で表示される内容を再現できません。結果の写真を共有していただけますか?

ホール-前 13,9445
ホール - 13,9612以降
ホール-前 14,031
ホール - 14,0403 以降
ホール- 14,2363以前
ホール - 14,0423 以降
ホール-前 14,0605
ホール - 13,9773以降
ホール-前 14,2448
ホール - 14,0903以降
ホール - 14,3006以前
ホール - 13,9198以降
穴-前 14,0294
ホール - 13,9568以降
ホール-前 13,9381
ホール - 13,9731以降
穴- 14,1617以前
ホール - 14,0621の後
ホール-前 13,8853
ホール - 14,0253 以降
ホール-前 14,0038
ホール - 14,0468 以降
ホール-前 13,6758
ホール - 14,0333 以降
ホール-前 13,6735
ホール - 14,1074以降
ホール- 14,1156以前
ホール - 14,0396以降
ホール- 14,2386以前
ホール - 13,9335以降
穴- 14,1268以前
ホール - 13,9734以降
ホール-前 13,8388
ホール - 14,0022以降
ホール-前 14,0422
ホール - 13,9869以降
ホール-前 13,9771
ホール - 13,9939以降
ホール-前 13,9529
ホール - 14,0271 以降
ホール-前 14,0051
ホール - 14,0045以降
ホール-前 13,9315
ホール - 13,972後
ホール-前 13,9159
ホール - 13,9924以降
ホール-前 14,0973
ホール - 13,9723以降
ホール- 14,1115以前
ホール - 13,9787 以降
ホール-前 14,0744
ホール - 13,9936以降
ホール-前 14,332
ホール - 13,9986以降
ホール-前 13,7861
ホール - 14,041 以降
穴 - 14,1448 以前
ホール - 13,902後
ホール-前 14,0634
ホール - 13,9935以降

正常性と能力について

JMP テーブルを添付してください。JMP データ セットから JMP テーブルを添付しました。マシンごとに Distribution プラットフォームを実行しました (オプションは多数あります)。スクリプトを実行するには、緑の矢印をクリックします。

正常性と能力について

おそらくこれが役に立つでしょう。添付されているのは JMP のデータ テーブルです。Before After 列に値の順序列プロパティを追加し、測定列に仕様限界列プロパティを追加しました。以下の出力表示は、データ テーブルに添付されている Before-After テーブル スクリプトを実行することで再生成できます。

正常性と能力について

ありがとうございます。論理的には2つのデータセットがありますが、私は添付のように両方を比較した1つの全体を探しています。

正常性と能力について

2 つの能力調査を比較する分析の特定の列を取得する方法がわかりません。Jim が提供したように、それぞれの分析が表示され、値の比較を行うことができます。個人的には、変更前と変更後のプロセスの比較にこのプラットフォーム (または Minitab のプラットフォーム) は使用しません。2 つの数値がある場合、1 つが大きくなります。それで何になるのでしょうか。

正常性と能力について

Minitab レポートフォームを複製したい場合は、非常に粗雑なハードコード版があります。これを汎用形式にし、JMP アドインとして追加するのは簡単です。しかし、それは皆さんの努力に任せます。

これは JSL のみを使用して、以前に提供した出力からオブジェクトを取得し、Minitab フォームに再フォーマットします。大量のクリーンアップと汎用化が必要です。

これがコードの最初のパスです

Names Default To Here( 1 );
dt = Current Data Table();
dis = dt << Distribution( invisible,
	SendToByGroup( {:Before After == "Hole - Before"} ),
	Continuous Distribution( Column( :Measurement ), Process Capability( Use Column Property Specs ) ),
	By( :Before After ),
	Group Options( Layout( "Horizontal List" ) ),
	SendToByGroup(
		{:Before After == "Hole - Before"},
		SendToReport(
			Dispatch( {"Measurement", "Process Capability", "Measurement Capability", "Nonconformance"},
				"Observed PPM", NumberColBox,
				{Visibility( "Visible" )}
			)
		)
	),
	SendToByGroup(
		{:Before After == "Hole - After"},
		SendToReport(
			Dispatch( {"Measurement", "Process Capability", "Measurement Capability", "Histogram"},
				"Process Capability Analysis Histogram", FrameBox,
				{DispatchSeg( CustomStreamSeg( 1 ), {Font} )}
			),
			Dispatch( {"Measurement", "Process Capability", "Measurement Capability", "Nonconformance"},
				"Observed PPM", NumberColBox,
				{Visibility( "Visible" )}
			)
		)
	)
);

// Build the report

// Set the Histograms to the same axis
theMin = Min(
	Report( Dis[1] )["Histogram", AxisBox( 1 )] << get min,
	Report( Dis[2] )["Histogram", AxisBox( 1 )] << get min
);
theMax = Max(
	Report( Dis[1] )["Histogram", AxisBox( 1 )] << get max,
	Report( Dis[2] )["Histogram", AxisBox( 1 )] << get max
);
Report( Dis[1] )["Histogram", AxisBox( 1 )] << Min( theMin );
Report( Dis[1] )["Histogram", AxisBox( 1 )] << Max( theMax );
Report( Dis[2] )["Histogram", AxisBox( 1 )] << Min( theMin );
Report( Dis[2] )["Histogram", AxisBox( 1 )] << Max( theMax );
Summarize( dt, baGroups = by( :Before After ) );
nw = New Window( "Report",
	Outline Box( "Before/After Capability Comparison for " || baGroups[1] || " vs. " || baGroups[2],
		V List Box(
			H List Box(
				Text Box( "Before: " || baGroups[1] ),
				Spacer Box( size( 200, 0 ) ),
				Text Box( "Process Performance Report" )
			),
			Text Box( "After: " || baGroups[2] )
		),
		Spacer Box( size( 0, 5 ) ),
		Lineup Box( N Col( 2 ),
			Outline Box( "Capability Histogram",
				lub1 = Lineup Box( N Col( 1 ),
					H List Box( Spacer Box( size( 60, 0 ) ), Text Box( "Are the data inside the limits?" ) )
				)
			
			),
			V List Box(
				obPC = Outline Box( "Process Characterization" ),
				Spacer Box( size( 0, 15 ) ),
				obCS = Outline Box( "Capability Statistics" )
			)
		)
	)
);
lub1 << Append( Report( Dis[1] )["Histogram", framebox( 1 )] );
lub1 << Append(
	Border Box( top( 0 ), bottom( 0 ), Left( 0 ), Right( 0 ), sides( 15 ),
		Text Box( "                                          Before" )
	)
);
lub1 << Append(
	Border Box( top( 0 ), bottom( 0 ), Left( 0 ), Right( 0 ), sides( 15 ),
		Report( Dis[1] )["Histogram", framebox( 2 )]
	)
);
lub1 << Append(
	Border Box( top( 0 ), bottom( 0 ), Left( 0 ), Right( 0 ), sides( 15 ),
		Text Box( "                                          After" )
	)
);
lub1 << Append(
	Border Box( top( 0 ), bottom( 0 ), Left( 0 ), Right( 0 ), sides( 15 ),
		Report( Dis[2] )["Histogram", framebox( 2 )]
	)
);
lub1 << Append(
	Border Box( top( 0 ), bottom( 0 ), Left( 0 ), Right( 0 ), sides( 15 ),
		Report( Dis[1] )["Histogram", axisbox( 1 )]
	)
);

// Build Process Characterization table

beforePCList = Report( Dis[1] )["Process Summary", Number Col Box( 1 )] << get;
Remove From( beforePCList, 1, 2 );
Remove From( beforePCList, 5, 1 );
Insert Into( beforePCList, 1, 2 );
afterPCList = Report( Dis[2] )["Process Summary", Number Col Box( 1 )] << get;
Remove From( afterPCList, 1, 2 );
Remove From( afterPCList, 5, 1 );
Insert Into( afterPCList, 1, 2 );
changeList = {., .};
Insert Into( changeList, beforePCList[3] - afterPCList[3] );
Insert Into( changeList, beforePCList[4] - afterPCList[4] );
Insert Into( changeList, beforePCList[5] - afterPCList[5] );
obPC << append(
	Table Box(
		String Col Box( "", {"Total N", "Subgroup size", "Mean", "STDev(within)", "StDev(overall)"} ),
		Number Col Box( "Before", beforePCList ),
		Number Col Box( "After", afterPCList ),
		Number Col Box( "Change", changeList )
	)
);

beforeCSList = {.};
Insert Into( beforeCSList, (Report( Dis[1] )["Overall Sigma Capability", Number Col Box( 1 )] << get)[4] );
Insert Into( beforeCSList, (Report( Dis[1] )["Overall Sigma Capability", Number Col Box( 1 )] << get)[1] );
Insert Into( beforeCSList, . );
Insert Into( beforeCSList, (Report( Dis[1] )["Nonconformance", Number Col Box( 1 )] << get)[3] );
Insert Into( beforeCSList, (Report( Dis[1] )["Nonconformance", Number Col Box( 3 )] << get)[3] );
Insert Into( beforeCSList, (Report( Dis[1] )["Nonconformance", Number Col Box( 4 )] << get)[3] );
Insert Into( beforeCSList, beforeCSList[6] * 1000000 );
Insert Into( beforeCSList, . );
Insert Into( beforeCSList, (Report( Dis[1] )["Within Sigma Capability", Number Col Box( 1 )] << get)[4] );
Insert Into( beforeCSList, (Report( Dis[1] )["Within Sigma Capability", Number Col Box( 1 )] << get)[1] );
Insert Into( beforeCSList, . );
Insert Into( beforeCSList, (Report( Dis[1] )["Nonconformance", Number Col Box( 2 )] << get)[3] );
Insert Into( beforeCSList, Round( beforeCSList[13] * 1000000, 0 ) );

afterCSList = {.};
Insert Into( afterCSList, (Report( Dis[2] )["Overall Sigma Capability", Number Col Box( 1 )] << get)[4] );
Insert Into( afterCSLIST, (Report( Dis[2] )["Overall Sigma Capability", Number Col Box( 1 )] << get)[1] );
Insert Into( afterCSLIST, . );
Insert Into( afterCSLIST, (Report( Dis[2] )["Nonconformance", Number Col Box( 1 )] << get)[3] );
Insert Into( afterCSLIST, (Report( Dis[2] )["Nonconformance", Number Col Box( 3 )] << get)[3] );
Insert Into( afterCSLIST, (Report( Dis[2] )["Nonconformance", Number Col Box( 4 )] << get)[3] );
Insert Into( afterCSLIST, afterCSLIST[6] * 1000000 );
Insert Into( afterCSLIST, . );
Insert Into( afterCSLIST, (Report( Dis[2] )["Within Sigma Capability", Number Col Box( 1 )] << get)[4] );
Insert Into( afterCSLIST, (Report( Dis[2] )["Within Sigma Capability", Number Col Box( 1 )] << get)[1] );
Insert Into( afterCSLIST, . );
Insert Into( afterCSLIST, (Report( Dis[2] )["Nonconformance", Number Col Box( 2 )] << get)[3] );
Insert Into( afterCSLIST, Round( afterCSLIST[13] * 1000000, 0 ) );
change = Matrix( beforeCSList ) - Matrix( afterCSList );
obcs << append(
	Table Box(
		String Col Box( "",
			{"Actual (overall)", "    Pp", "    Ppk", "    Z Bench", "    % Out of spec (obs)",
			"    % Out of spec (exp)", "    PPM (DPMO) (obs)", "    PPM (DPMO) (exp)", "Potential (within)",
			"    Cp", "    Cpk", "    Z Bench", "    % Out of spec (exp)", "    PM (DPMO) (exp)"}
		),
		Number Col Box( "Before", beforeCSList ),
		Number Col Box( "After", afterCSList ),
		Number Col Box( "Change", change )
	)
);

dis << close window;

正常性と能力について

こんにちは、ジムさん

本当にありがとう。とても助かりました。