768978_ko-KR

liliconcom

for 루프를 사용하여 많은 열 처리

Column_1, Column_2,....Column_100이라는 100개의 문자 열이 있습니다. 각 열에는 A1, A2, ... A100과 같은 항목이 있습니다. 각 입력 열이 2개의 출력 열을 생성하는 이 100개의 열에서 200개의 열을 만들려고 합니다. 한 출력 열에는 문자(A)가 있고 다른 열에는 숫자(1,2,...)가 있습니다. 이것을 어떻게 작성하나요?

자동화 및 스크립팅윈도우Re: for 루프를 사용하여 많은 열을 처리합니다.

여기에 예가 있습니다.

names default to here(1);
dt =
New Table( "Example",
	Add Rows( 20 ),
	New Column( "column 1",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	),
	New Column( "column 2",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	)
);

colList = dt << get column names( string );
For Each( {col}, colList,
	dt << New Column( col || " Letter",
		character,
		set each value( Substr( As Column( col ), 1, 1 ) )
	);
	dt << New Column( col || " Number",
		set each value( Num( Substr( As Column( col ), 2 ) ) )
	);
);

또는 For() 루프를 사용하여

names default to here(1);
dt =
New Table( "Example",
	Add Rows( 20 ),
	New Column( "column 1",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	),
	New Column( "column 2",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	)
);

colList = dt << get column names( string );
For( i=1,i<= NItems(colList), i++,
	dt << New Column( colList[i] || " Letter",
		character,
		set each value( Substr( As Column( colList[i] ), 1, 1 ) )
	);
	dt << New Column( colList[i] || " Number",
		set each value( Num( Substr( As Column( colList[i] ), 2 ) ) )
	);
);

Re: for 루프를 사용하여 많은 열을 처리합니다.

테이블에 다른 열도 있습니다. 열 X, 열 Y를 가정해 보겠습니다. 이러한 열이 처리의 일부가 되는 것을 원하지 않습니다. 내가 관심 있는 열에만 집중하도록 라인을 어떻게 변경합니까?

colList = dt << get column names( string );

Re: for 루프를 사용하여 많은 열을 처리합니다.

remove from(colList,contains(colList,"Column X"),1);

스크립팅 가이드 섹션의 도움말=>JMP 온라인 도움말에서 시간을 내어 자료를 읽어 보십시오. 또한 도움말 풀다운 메뉴에 있는 스크립팅 색인을 숙지하십시오. 이러한 문서는 JMP의 스크립팅 언어 및 규칙에 대한 좋은 배경 지식을 제공합니다.