768978_it-IT

liliconcom

Elabora molte colonne con il ciclo for

Ho 100 colonne di caratteri denominate Colonna_1, Colonna_2,....Colonna_100. Ogni colonna ha voci come A1, A2, ... A100. Sto cercando di creare 200 colonne da queste 100 colonne in cui ciascuna colonna di input creerà 2 colonne di output, una colonna di output avrà la lettera (A) e l'altra colonna avrà il numero (1,2,...). Come scrivere questo?

Automazione e scriptingfinestreRi: Elabora molte colonne con il ciclo for

Ecco un esempio

names default to here(1);
dt =
New Table( "Example",
	Add Rows( 20 ),
	New Column( "column 1",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	),
	New Column( "column 2",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	)
);

colList = dt << get column names( string );
For Each( {col}, colList,
	dt << New Column( col || " Letter",
		character,
		set each value( Substr( As Column( col ), 1, 1 ) )
	);
	dt << New Column( col || " Number",
		set each value( Num( Substr( As Column( col ), 2 ) ) )
	);
);

Oppure utilizzando un ciclo For()

names default to here(1);
dt =
New Table( "Example",
	Add Rows( 20 ),
	New Column( "column 1",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	),
	New Column( "column 2",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	)
);

colList = dt << get column names( string );
For( i=1,i<= NItems(colList), i++,
	dt << New Column( colList[i] || " Letter",
		character,
		set each value( Substr( As Column( colList[i] ), 1, 1 ) )
	);
	dt << New Column( colList[i] || " Number",
		set each value( Num( Substr( As Column( colList[i] ), 2 ) ) )
	);
);

Ri: Elabora molte colonne con il ciclo for

Ho anche altre colonne nella tabella. Di' Colonna X, Colonna Y. Non voglio che queste colonne facciano parte dell'elaborazione. Come faccio a cambiare la tua riga per concentrarmi solo sulle colonne che mi interessano.

colList = dt << get column names( string );

Ri: Elabora molte colonne con il ciclo for

remove from(colList,contains(colList,"Column X"),1);

Si prega di leggere il materiale nella sezione Guida => Guida in linea di JMP nella sezione Guida allo scripting. Inoltre, familiarizzare con l'indice degli script nel menu a discesa Guida. Questi documenti forniranno una buona conoscenza del linguaggio di scripting e delle convenzioni di JMP.