768978_de-DE

liliconcom

Viele Spalten mit For-Schleife verarbeiten

Ich habe 100 Zeichenspalten mit den Namen Column_1, Column_2, ... Column_100. Jede Spalte hat Einträge wie A1, A2, ... A100. Ich versuche, aus diesen 100 Spalten 200 Spalten zu erstellen, wobei jede Eingabespalte zwei Ausgabespalten erzeugt, wobei eine Ausgabespalte den Buchstaben (A) und die andere Spalte die Zahl (1,2, ...) enthält. Wie schreibt man das?

Automatisierung und SkriptingWindowsBetreff: Viele Spalten mit For-Schleife verarbeiten

Hier ist ein Beispiel

names default to here(1);
dt =
New Table( "Example",
	Add Rows( 20 ),
	New Column( "column 1",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	),
	New Column( "column 2",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	)
);

colList = dt << get column names( string );
For Each( {col}, colList,
	dt << New Column( col || " Letter",
		character,
		set each value( Substr( As Column( col ), 1, 1 ) )
	);
	dt << New Column( col || " Number",
		set each value( Num( Substr( As Column( col ), 2 ) ) )
	);
);

Oder mit einer For()-Schleife

names default to here(1);
dt =
New Table( "Example",
	Add Rows( 20 ),
	New Column( "column 1",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	),
	New Column( "column 2",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	)
);

colList = dt << get column names( string );
For( i=1,i<= NItems(colList), i++,
	dt << New Column( colList[i] || " Letter",
		character,
		set each value( Substr( As Column( colList[i] ), 1, 1 ) )
	);
	dt << New Column( colList[i] || " Number",
		set each value( Num( Substr( As Column( colList[i] ), 2 ) ) )
	);
);

Betreff: Viele Spalten mit For-Schleife verarbeiten

Ich habe auch andere Spalten in der Tabelle. Sagen wir Spalte X, Spalte Y. Ich möchte nicht, dass diese Spalten Teil der Verarbeitung sind. Wie ändere ich Ihre Zeile, um mich nur auf die Spalten zu konzentrieren, die mich interessieren?

colList = dt << get column names( string );

Betreff: Viele Spalten mit For-Schleife verarbeiten

remove from(colList,contains(colList,"Column X"),1);

Nehmen Sie sich bitte die Zeit, das Material unter „Hilfe=>JMP-Onlinehilfe“ im Abschnitt „Skripthandbuch“ zu lesen. Machen Sie sich außerdem mit dem Skriptindex im Pulldown-Menü „Hilfe“ vertraut. Diese Dokumentationen bieten Ihnen einen guten Hintergrund zur Skriptsprache und den Konventionen in JMP.