768978_fr-FR

liliconcom

Traiter plusieurs colonnes avec la boucle for

J'ai 100 colonnes de caractères nommées Column_1, Column_2,....Column_100. Chaque colonne contient des entrées comme A1, A2, ... A100. J'essaie de créer 200 colonnes à partir de ces 100 colonnes où chaque colonne d'entrée créera 2 colonnes de sortie, une colonne de sortie aura la lettre (A) et l'autre colonne aura le numéro (1,2,...). Comment écrire cela ?

Automatisation et scriptsles fenêtresRe : Traiter plusieurs colonnes avec la boucle for

Voici un exemple

names default to here(1);
dt =
New Table( "Example",
	Add Rows( 20 ),
	New Column( "column 1",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	),
	New Column( "column 2",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	)
);

colList = dt << get column names( string );
For Each( {col}, colList,
	dt << New Column( col || " Letter",
		character,
		set each value( Substr( As Column( col ), 1, 1 ) )
	);
	dt << New Column( col || " Number",
		set each value( Num( Substr( As Column( col ), 2 ) ) )
	);
);

Ou en utilisant une boucle For()

names default to here(1);
dt =
New Table( "Example",
	Add Rows( 20 ),
	New Column( "column 1",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	),
	New Column( "column 2",
		Character,
		Formula( "A" || Char( Random Integer( 1, 100 ) ) )
	)
);

colList = dt << get column names( string );
For( i=1,i<= NItems(colList), i++,
	dt << New Column( colList[i] || " Letter",
		character,
		set each value( Substr( As Column( colList[i] ), 1, 1 ) )
	);
	dt << New Column( colList[i] || " Number",
		set each value( Num( Substr( As Column( colList[i] ), 2 ) ) )
	);
);

Re : Traiter plusieurs colonnes avec la boucle for

J'ai également d'autres colonnes dans le tableau. Dites Colonne X, Colonne Y. Je ne veux pas que ces colonnes fassent partie du traitement. Comment puis-je modifier votre ligne pour me concentrer uniquement sur les colonnes qui m'intéressent.

colList = dt << get column names( string );

Re : Traiter plusieurs colonnes avec la boucle for

remove from(colList,contains(colList,"Column X"),1);

Veuillez prendre le temps de lire les informations sous Aide => Aide en ligne JMP dans la section Guide de script. Familiarisez-vous également avec l'index de script dans le menu déroulant Aide. Ces éléments de documentation vous fourniront une bonne base sur le langage de script et les conventions de JMP.