767792_de-DE

liliconcom

Wie erstelle ich „Prozessfähigkeit“ mit einer Datentabelle einschließlich Grenzwerten und Zielen?

Können Sie mir erklären, wie ich die Prozessfähigkeit mit einer Datentabelle einschließlich LSL, USL und Ziel erstelle?

------------------------------------------------------------------------------------------------------------------------------------

Ich habe die Datentabelle einschließlich LSL, USL, Ziel.

Ich verwende den Spaltendialog und wähle Spalten für die Prozessfähigkeit aus.

Aber … es funktioniert nicht mit der Fehlermeldung „Process Capability kann nicht gestartet werden, da keiner der Prozesse in der Datentabelle gefunden werden kann.“

Können Sie mir sagen, wie ich das Problem beheben kann?

Ein Teil meines JSL ist unten.

//dt <- limits & target<BR />
For( m = 1, m < N Col( dt ), m ++,
	Eval( Eval Expr( Column(dt, m) << Set Property("Spec Limits", {LSL(Expr(lower_limit[m])), Target( Expr(target_val[m]) ),USL (Expr(upper_limit[m]))})));
);

//Select Test Item for Process Capability
colDlg = Column Dialog(
	Title( "Test Item Selct" ),
	ycol = Col List( "Test Item", Min Col( 1 ), Max Col(15) ), //
);

Show (colDlg["ycol"]);

pc =dt << Process Capability(
	Process Variables(:colDlg["ycol"]
	),
	Moving Range Method( Average of Moving Ranges ),
	Overall Sigma Summary Report( 1 ),
	Goal Plot( 0 ),
	Capability Index Plot( 0 ),
	Process Performance Plot( 0 ),
	//Order By( "Overall Sigma Ppk Ascending" )
);

Danke schön.

Automatisierung und SkriptingBetreff: Wie erstelle ich „Prozessfähigkeit“ mit einer Datentabelle einschließlich Grenzwerten und Zielen?

Ändern

	Process Variables(:colDlg["ycol"])

Zu

	Process Variables(Eval(colDlg["ycol"]))

Vollständiges Beispiel

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

colDlg = Column Dialog(
	Title("Test Item Selct"),
	ycol = Col List("Test Item", Min Col(1), Max Col(15))
);

pc = dt << Process Capability(
	Process Variables(eval(colDlg["ycol"])),
	Moving Range Method(Average of Moving Ranges),
	Overall Sigma Summary Report(1),
	Goal Plot(0),
	Capability Index Plot(0),
	Process Performance Plot(0)
);

Betreff: Wie erstelle ich „Prozessfähigkeit“ mit einer Datentabelle einschließlich Grenzwerten und Zielen?

Ihr Vorschlag funktioniert!

Ich kann Ihnen nicht genug danken.