767605_it-IT

liliconcom

Modifica automaticamente le impostazioni dei fattori di un oggetto del profiler utilizzando un ciclo for

Ciao a tutti,

Vorrei modificare automaticamente le impostazioni del fattore di un oggetto profiler. Se affronto direttamente ciascun fattore, funziona come previsto:

dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
obj = dt << Profiler(
	Y(
		:Pred Formula ABRASION, :Pred Formula MODULUS, :Pred Formula ELONG,
		:Pred Formula HARDNESS
	),
	Desirability Functions( 1 )
);

//works
obj << Term Value("SILICA"(5, Min( -10 ), Max( 6 ), Lock( 1 ), Show( 1 ) ));

However, if I want to loop over all factors to change the respective settings, nothing happens.

dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
obj = dt << Profiler(
	Y(
		:Pred Formula ABRASION, :Pred Formula MODULUS, :Pred Formula ELONG,
		:Pred Formula HARDNESS
	),
	Desirability Functions( 1 )
);

//does not work
FactorList = {"SILICA", "SILANE"};
for(i=1, i<=n items(FactorList), i++,
	Eval( 
		Eval Expr( 
			obj << Term Value(
				Expr(FactorList[i])( 5, Min( -10 ), Max( 6 ), Lock( 1 ), Show( 1 ) )
			)
		)
	)
);

Using Valutazione(EsprValuta()) usually solved it when I had similar issues. Sadly, this isn't helping this time.
Thanks for your help!

Automazione e scriptingRi: Modificare automaticamente le impostazioni dei fattori di un oggetto profiler utilizzando un ciclo for

L'uso di questo metodo sembra funzionare

dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
obj = dt << Profiler(
	Y(
		:Pred Formula ABRASION, :Pred Formula MODULUS, :Pred Formula ELONG,
		:Pred Formula HARDNESS
	),
	Desirability Functions( 1 )
);

//does not work
FactorList = {"SILICA", "SILANE"};
for(i=1, i<=n items(FactorList), i++,
	Eval( 
		Parse( 
			"obj << Term Value(
				\!""||FactorList[i]|| "\!"( 5, Min( -10 ), Max( 6 ), Lock( 1 ), Show( 1 ) )
			);"
		)
	)
);

Ri: Modificare automaticamente le impostazioni dei fattori di un oggetto profiler utilizzando un ciclo for

Per eseguire il debug del tuo script, puoi controllare cosa restituisce la parte EvalExpr()

FactorList = {"SILICA", "SILANE"};
i = 1;
term_expr = Eval Expr(obj << Term Value(Expr(FactorList[i])(5, Min(-10), Max(6), Lock(1), Show(1))));
show(term_expr);

è qualcosa del genere che è una sintassi errata

term_expr = obj << Term Value("SILICA" << {5, Min(-10), Max(6), Lock(1), Show(1)});

Ed ecco un modo per affrontare la situazione

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Tiretread.jmp");
obj = dt << Profiler(
	Y(:Pred Formula ABRASION, :Pred Formula MODULUS, :Pred Formula ELONG, :Pred Formula HARDNESS),
	Desirability Functions(1)
);

terms = {"SILICA", "SILANE"};

For Each({term}, terms,
	Eval(Substitute(
		Expr(obj << Term Value(_term_(5, Min(-10), Max(6), Lock(1), Show(1)))),
		Expr(_term_), Name Expr(AsColumn(dt, term));
	));
);