765331_es-ES

liliconcom

El gráfico de distribución con capacidad de proceso no funciona en el script

Hola,
Quiero usar este script generado en numerosas columnas:

Distribution(
	Stack( 1 ),
	Continuous Distribution(
		Column( :"VDD_ILIMIT"n ),
		Horizontal Layout( 1 ),
		Vertical( 0 ),
		Outlier Box Plot( 0 ),
		Process Capability( LSL( . ), Target( . ), USL( 0.5 ), Show as Graph Reference Lines )
	),
	SendToReport( Dispatch( {"VDD_ILIMIT"}, "1", ScaleBox, {Add Ref Line( 0.5, "Solid", "Blue", "USL", 1 )} ) )
);

Cuando uso este script, todo funciona bien y obtengo un gráfico de distribución con un gráfico de capacidad del proceso en la misma ventana.
Cuando intento ejecutarlo en varias columnas, solo obtengo los gráficos de distribución para cada columna, sin el gráfico de capacidad del proceso ni los datos.

// Open the data table
dt = Current Data Table();
colnames = dt << get column names( numeric, string );
For( i = 1, i <= N Items( colnames ), i++,
	If( Contains( Column( colnames[i] ) << Get Name, "ILIMIT" ), 
        // Create a distribution graph for the column
		meanValue = Col Mean( colnames[i] );
		stdDevValue = Col Std Dev( colnames[i] );
		ppkValue = 2;
		uslValue = meanValue + ppkValue * 3 * stdDevValue;
		Distribution(
			Stack( 1 ),
			Continuous Distribution(
				Column( colnames[i] ),
				Horizontal Layout( 1 ),
				Vertical( 0 ),
				Outlier Box Plot( 0 ),
				Process Capability( LSL( . ), Target( . ), USL( uslValue ), Show as Graph Reference Lines )
			),
			SendToReport( Dispatch( {colnames[i]}, "1", ScaleBox, {Add Ref Line( uslValue, "Solid", "Blue", "USL", 1 )} ) )
		);
	)
);

¿Qué estoy haciendo mal y por qué se comporta de esta manera?

Automatización y secuencias de comandosRe: El gráfico de distribución con capacidad de proceso no funciona en el script

A continuación se muestra una modificación de su código que debería funcionar para usted.

// Open the data table
dt = Current Data Table();
colnames = dt << get column names( numeric, string );
i = 2;
For( i = 1, i <= N Items( colnames ), i++, 
	//If( Contains( Column( colnames[i] ) << Get Name, "eight" ), 
	If( Contains( colnames[i], "ILIMIT" ), 
        // Create a distribution graph for the column
		//meanValue = Col Mean( colnames[i] );
		meanValue = Col Mean( Column( dt, colnames[i] ) );
		//stdDevValue = Col Std Dev( colnames[i] );
		stdDevValue = Col Std Dev( Column( dt, colnames[i] ) );
		ppkValue = 2; // ???
		
		uslValue = .5; // this value is used below, but was not assigned
		
		Eval(
			Eval Expr(  // JMP does not evaluate items in a list as parsing
				        // therefore it has to be preprocessed
				Distribution(
					Stack( 1 ),
					Continuous Distribution(
						Column( colnames[i] ),
						Horizontal Layout( 1 ),
						Vertical( 0 ),
						Outlier Box Plot( 0 ),
						Process Capability( LSL( . ), Target( . ), USL( Expr( uslValue ) ), Show as Graph Reference Lines )
					),
					SendToReport(
						Dispatch( {Expr( colnames[i] )}, "1", ScaleBox, {Add Ref Line( Expr( uslValue ), "Solid", "Blue", "USL", 1 )} )
					)
				)
			)
		);
	)
);

Re: El gráfico de distribución con capacidad de proceso no funciona en el script

JMP no puede agregar las líneas de referencia correctamente (¿y parece que no tiene valor para el límite superior?). A continuación se muestra un ejemplo que puede darle algunas ideas.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Open the data table
colnames = dt << get column names(numeric, continuous, string);
dists = {};
For Each({colname}, colnames,
	meanValue = Col Mean(Column(dt, colname));
	stdDevValue = Col Std Dev(Column(dt, colname));
	ppkValue = 2;
	uslValue = 3*stddevValue + meanValue;
	dist = Eval(EvalExpr(dt << Distribution(
		Stack(1),
		Continuous Distribution(
			Column(Eval(colname)),
			Horizontal Layout(1),
			Vertical(0),
			Outlier Box Plot(0),
			Process Capability(
				LSL(.),
				Target(.),
				USL(Expr(uslValue)),
				Show as Graph Reference Lines
			)
		),
		SendToReport(
			Dispatch(
				{colnames[i]},
				"1",
				ScaleBox,
				{Add Ref Line(Expr(uslValue), "Solid", "Blue", "USL", 1)}
			)
		)
	)));
	Insert Into(dists, dist);
	
);