765331_it-IT

liliconcom

Grafico di distribuzione con capacità di processo che non funziona nello script

CIAO,
Voglio utilizzare questo script generato su numerose colonne:

Distribution(
	Stack( 1 ),
	Continuous Distribution(
		Column( :"VDD_ILIMIT"n ),
		Horizontal Layout( 1 ),
		Vertical( 0 ),
		Outlier Box Plot( 0 ),
		Process Capability( LSL( . ), Target( . ), USL( 0.5 ), Show as Graph Reference Lines )
	),
	SendToReport( Dispatch( {"VDD_ILIMIT"}, "1", ScaleBox, {Add Ref Line( 0.5, "Solid", "Blue", "USL", 1 )} ) )
);

Quando utilizzo questo script, tutto funziona bene e ottengo un grafico di distribuzione con il grafico della capacità del processo nella stessa finestra.
Quando provo a eseguirlo su un numero di colonne, ottengo solo i grafici di distribuzione per ciascuna colonna, senza il grafico e i dati della capacità del processo.

// Open the data table
dt = Current Data Table();
colnames = dt << get column names( numeric, string );
For( i = 1, i <= N Items( colnames ), i++,
	If( Contains( Column( colnames[i] ) << Get Name, "ILIMIT" ), 
        // Create a distribution graph for the column
		meanValue = Col Mean( colnames[i] );
		stdDevValue = Col Std Dev( colnames[i] );
		ppkValue = 2;
		uslValue = meanValue + ppkValue * 3 * stdDevValue;
		Distribution(
			Stack( 1 ),
			Continuous Distribution(
				Column( colnames[i] ),
				Horizontal Layout( 1 ),
				Vertical( 0 ),
				Outlier Box Plot( 0 ),
				Process Capability( LSL( . ), Target( . ), USL( uslValue ), Show as Graph Reference Lines )
			),
			SendToReport( Dispatch( {colnames[i]}, "1", ScaleBox, {Add Ref Line( uslValue, "Solid", "Blue", "USL", 1 )} ) )
		);
	)
);

Cosa sto facendo di sbagliato e perché si comporta in questo modo?

Automazione e scriptingRi: Grafico di distribuzione con capacità di processo che non funziona nello script

Di seguito è riportata una modifica al codice che dovrebbe funzionare per te

// Open the data table
dt = Current Data Table();
colnames = dt << get column names( numeric, string );
i = 2;
For( i = 1, i <= N Items( colnames ), i++, 
	//If( Contains( Column( colnames[i] ) << Get Name, "eight" ), 
	If( Contains( colnames[i], "ILIMIT" ), 
        // Create a distribution graph for the column
		//meanValue = Col Mean( colnames[i] );
		meanValue = Col Mean( Column( dt, colnames[i] ) );
		//stdDevValue = Col Std Dev( colnames[i] );
		stdDevValue = Col Std Dev( Column( dt, colnames[i] ) );
		ppkValue = 2; // ???
		
		uslValue = .5; // this value is used below, but was not assigned
		
		Eval(
			Eval Expr(  // JMP does not evaluate items in a list as parsing
				        // therefore it has to be preprocessed
				Distribution(
					Stack( 1 ),
					Continuous Distribution(
						Column( colnames[i] ),
						Horizontal Layout( 1 ),
						Vertical( 0 ),
						Outlier Box Plot( 0 ),
						Process Capability( LSL( . ), Target( . ), USL( Expr( uslValue ) ), Show as Graph Reference Lines )
					),
					SendToReport(
						Dispatch( {Expr( colnames[i] )}, "1", ScaleBox, {Add Ref Line( Expr( uslValue ), "Solid", "Blue", "USL", 1 )} )
					)
				)
			)
		);
	)
);

Ri: Grafico di distribuzione con capacità di processo che non funziona nello script

JMP non è in grado di aggiungere correttamente le linee di riferimento (e sembra che tu non abbia valore per upperlimit?). Di seguito è riportato un esempio che può darti alcune idee

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Open the data table
colnames = dt << get column names(numeric, continuous, string);
dists = {};
For Each({colname}, colnames,
	meanValue = Col Mean(Column(dt, colname));
	stdDevValue = Col Std Dev(Column(dt, colname));
	ppkValue = 2;
	uslValue = 3*stddevValue + meanValue;
	dist = Eval(EvalExpr(dt << Distribution(
		Stack(1),
		Continuous Distribution(
			Column(Eval(colname)),
			Horizontal Layout(1),
			Vertical(0),
			Outlier Box Plot(0),
			Process Capability(
				LSL(.),
				Target(.),
				USL(Expr(uslValue)),
				Show as Graph Reference Lines
			)
		),
		SendToReport(
			Dispatch(
				{colnames[i]},
				"1",
				ScaleBox,
				{Add Ref Line(Expr(uslValue), "Solid", "Blue", "USL", 1)}
			)
		)
	)));
	Insert Into(dists, dist);
	
);