765331_fr-FR

liliconcom

Le graphique de distribution avec capacité de processus ne fonctionne pas dans le script

Salut,
Je souhaite utiliser ce script généré sur de nombreuses colonnes :

Distribution(
	Stack( 1 ),
	Continuous Distribution(
		Column( :"VDD_ILIMIT"n ),
		Horizontal Layout( 1 ),
		Vertical( 0 ),
		Outlier Box Plot( 0 ),
		Process Capability( LSL( . ), Target( . ), USL( 0.5 ), Show as Graph Reference Lines )
	),
	SendToReport( Dispatch( {"VDD_ILIMIT"}, "1", ScaleBox, {Add Ref Line( 0.5, "Solid", "Blue", "USL", 1 )} ) )
);

Lorsque vous utilisez ce script, tout fonctionne bien et j'obtiens un graphique de distribution avec un tracé des capacités du processus dans la même fenêtre.
Lorsque j'essaie de l'exécuter sur un certain nombre de colonnes, j'obtiens uniquement les graphiques de distribution pour chaque colonne, sans le tracé et les données de capacité du processus.

// Open the data table
dt = Current Data Table();
colnames = dt << get column names( numeric, string );
For( i = 1, i <= N Items( colnames ), i++,
	If( Contains( Column( colnames[i] ) << Get Name, "ILIMIT" ), 
        // Create a distribution graph for the column
		meanValue = Col Mean( colnames[i] );
		stdDevValue = Col Std Dev( colnames[i] );
		ppkValue = 2;
		uslValue = meanValue + ppkValue * 3 * stdDevValue;
		Distribution(
			Stack( 1 ),
			Continuous Distribution(
				Column( colnames[i] ),
				Horizontal Layout( 1 ),
				Vertical( 0 ),
				Outlier Box Plot( 0 ),
				Process Capability( LSL( . ), Target( . ), USL( uslValue ), Show as Graph Reference Lines )
			),
			SendToReport( Dispatch( {colnames[i]}, "1", ScaleBox, {Add Ref Line( uslValue, "Solid", "Blue", "USL", 1 )} ) )
		);
	)
);

Qu'est-ce que je fais de mal et pourquoi se comporte-t-il de cette façon ?

Automatisation et scriptsRe : Graphique de distribution avec capacité de processus ne fonctionnant pas dans le script

Vous trouverez ci-dessous une modification de votre code qui devrait fonctionner pour vous

// Open the data table
dt = Current Data Table();
colnames = dt << get column names( numeric, string );
i = 2;
For( i = 1, i <= N Items( colnames ), i++, 
	//If( Contains( Column( colnames[i] ) << Get Name, "eight" ), 
	If( Contains( colnames[i], "ILIMIT" ), 
        // Create a distribution graph for the column
		//meanValue = Col Mean( colnames[i] );
		meanValue = Col Mean( Column( dt, colnames[i] ) );
		//stdDevValue = Col Std Dev( colnames[i] );
		stdDevValue = Col Std Dev( Column( dt, colnames[i] ) );
		ppkValue = 2; // ???
		
		uslValue = .5; // this value is used below, but was not assigned
		
		Eval(
			Eval Expr(  // JMP does not evaluate items in a list as parsing
				        // therefore it has to be preprocessed
				Distribution(
					Stack( 1 ),
					Continuous Distribution(
						Column( colnames[i] ),
						Horizontal Layout( 1 ),
						Vertical( 0 ),
						Outlier Box Plot( 0 ),
						Process Capability( LSL( . ), Target( . ), USL( Expr( uslValue ) ), Show as Graph Reference Lines )
					),
					SendToReport(
						Dispatch( {Expr( colnames[i] )}, "1", ScaleBox, {Add Ref Line( Expr( uslValue ), "Solid", "Blue", "USL", 1 )} )
					)
				)
			)
		);
	)
);

Re : Graphique de distribution avec capacité de processus ne fonctionnant pas dans le script

JMP n'est pas en mesure d'ajouter correctement les lignes de référence (et vous ne semblez pas avoir de valeur pour la limite supérieure ?). Ci-dessous un exemple qui peut vous donner quelques idées

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Open the data table
colnames = dt << get column names(numeric, continuous, string);
dists = {};
For Each({colname}, colnames,
	meanValue = Col Mean(Column(dt, colname));
	stdDevValue = Col Std Dev(Column(dt, colname));
	ppkValue = 2;
	uslValue = 3*stddevValue + meanValue;
	dist = Eval(EvalExpr(dt << Distribution(
		Stack(1),
		Continuous Distribution(
			Column(Eval(colname)),
			Horizontal Layout(1),
			Vertical(0),
			Outlier Box Plot(0),
			Process Capability(
				LSL(.),
				Target(.),
				USL(Expr(uslValue)),
				Show as Graph Reference Lines
			)
		),
		SendToReport(
			Dispatch(
				{colnames[i]},
				"1",
				ScaleBox,
				{Add Ref Line(Expr(uslValue), "Solid", "Blue", "USL", 1)}
			)
		)
	)));
	Insert Into(dists, dist);
	
);