761985_fr-FR

liliconcom

Comment extraire uniquement le prob > |t| du rapport de test ?

Probablement une question très simple, mais existe-t-il un moyen simple d'extraire uniquement le prob > |t| du rapport de test ? De cette ligne qui extrait le rapport complet.:

dt1 = rpt[Boîte de contour( "t Test" )][Boîte de table( 1 )];

Script complet avec un plus petit nombre de X et de Y :

// Entrer analyse et column switchers
Oneway(
	Y(:Name("553")),
	X(:Name("1")),
	t Test(1),
	Column Switcher(:Name("1"), {:Name("1"), :Name("2"), :Name("3")}), 
	Column Switcher(:Name("553"), {:Name("553"), :Name("554")}));

//Report
rpt = Current Report();
colswitcher_obj = rpt[ColumnSwitcherCOntextOutlinebox( 1 )] << get scriptable object;
colswitcher_obj2 = rpt[ColumnSwitcherCOntextOutlinebox( 2 )] << get scriptable object;
colswitch_list = colswitcher_obj << get list;
colswitch_list2 = colswitcher_obj2 << get list;

// Loop column switcher 1
For(j = 1, j <= N Items(colswitch_list2), j++, 

	// Loop column switcher 2
	For(k = 1, k <= N Items(colswitch_list), k++, 

	// Changer le test ici
	dt1 = rpt[Outline Box( "t Test" )][Table Box( 1 )];

	// Concatenate table
	If(j == 1 & k == 1,
		main_tb = dt1;
		main_tb << Set Name( "All" );
	,
		Try( main_tb << Concatenate( dt1, Append to First Table ) );
		Close( dt1, No Save );
	);

        colSwitcher_obj << Next;
	wait(0);
	);

colSwitcher_obj2 << Next;
wait(0);
);

Automatisation et scriptsRe : Comment extraire uniquement le prob > |t| du rapport de test ?

Ce n'est peut-être pas une méthode très robuste mais donne une idée possible

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

ow = dt << Oneway(
	Y(:height),
	X(:sex),
	t Test(1),
);

tb = Report(ow)[OutlineBox("t Test"), Table Box(1)];
vals = tb[ColStackBox(2), NumberColBox(2)] << get;
prob = vals[1];

Une très bonne option consiste généralement à transformer la zone de table en table de données en utilisant << Make Into Data Table , puis en en extrayant la valeur. Une fois que vous avez la valeur, pensez à fermer le tableau.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

ow = dt << Oneway(
	Y(:height),
	X(:sex),
	t Test(1),
);

dt_ttest = Report(ow)[OutlineBox("t Test"), Table Box(1)] << Make Into Data Table(Invisible(1));
val = dt_ttest[3, 6];
Close(dt_ttest, no save);

Les deux peuvent être rendus plus robustes en vérifiant où Prob > |t| est.