762105_ja-JP

liliconcom

Fit Life by X で X パラメータに変数を渡す方法は?

やあみんな、

I need to dynamically pass variables to the X parameter in the fit life by x function. The first part of my code generates the analysis report as expected, but the second part only brings up the startup window without a report.

私のコードは次のようになります:

Names Default To Here(1);

dt = Open( "$sample_data/big class.jmp" );

x_var = "sex";
y_var = "weight";

obj1 = dt << Fit Life by X(
	Distribution( Weibull ),
	Nested Model Tests( Location and Scale ),
	Y( Eval(y_var) ),
	X( :sex ),
);

wait(2);

obj2 = dt << Fit Life by X(
	Distribution( Weibull ),
	Nested Model Tests( Location and Scale ),
	Y( :weight ),
	X( Eval(x_var) ),
);

この問題に遭遇した人、または変数を X パラメータに正しく渡す方法をご存知の方はいらっしゃいますか?

ありがとう！

自動化とスクリプト信頼性分析Re: Fit Life by X で X パラメータに変数を渡すにはどうすればいいですか?

以下をご覧ください。

「関係」が欠落しているため、コードは X に基づいて最善の推測を行おうとします。ただし、コードが X をチェックする場所では、この場合、X はまだ有効な列ではありません。したがって、完全な情報を提供することで、コードは罠に陥る必要はありません。

Names Default To Here(1);

dt = Open( "$sample_data/big class.jmp" );

x_var = "sex";
y_var = "weight";

obj1 = dt << Fit Life by X(
	Distribution( Weibull ),
	Relationship( Location and Scale ),
	Nested Model Tests( Location and Scale ),
	Y( Eval(y_var) ),
	X( :sex ),
);

wait(2);

obj2 = dt << Fit Life by X(
	Distribution( Weibull ),
	Relationship( Location and Scale ),
	Nested Model Tests( Location and Scale ),
	Y( :weight ),
	X( Eval(x_var) ),
);

Re: Fit Life by X で X パラメータに変数を渡すにはどうすればいいですか?

「通常の」強制は機能しないため、回避するにはもう少し作業が必要になるようです。

Names Default To Here(1);

dt = Open("$sample_data/big class.jmp");

x_var = "sex";
y_var = "weight";

myexpr = EvalExpr(dt << Fit Life by X(
	Distribution( Weibull ),
	Nested Model Tests( Location and Scale ),
	Y( :weight ),
	X(Expr(NameExpr(AsColumn(dt, x_var)))),
));
show(myexpr);
obj = Eval(myexpr);

Eval(Parse()) (evil parse) を使用するように勧める非常にまれなケースの 1 つですが、これは機能するようです。

Names Default To Here(1);

dt = Open("$sample_data/big class.jmp");

x_var = "sex";
y_var = "weight";

obj2 = Eval(Parse(Eval Insert("\[dt << Fit Life by X(
	Distribution(Weibull),
	Nested Model Tests(Location and Scale),
	Y(:weight),
	X(:^x_var^)
)]\")));

Re: Fit Life by X で X パラメータに変数を渡すにはどうすればいいですか?

この異常はバグのようです。ネストされたモデル テスト引数は、2 番目のケースでは認識されません。これを JMP テクニカル サポート ( support@jmp.com ) に報告して、不具合として入力して追跡できるようにしてください。

Re: Fit Life by X で X パラメータに変数を渡すにはどうすればいいですか?

おお、まさにその通りですね。ありがとうございます！

Re: Fit Life by X で X パラメータに変数を渡すにはどうすればいいですか?

これも別の回避策です。ありがとうございます!