762105_de-DE

liliconcom

Wie übergebe ich Variablen an den X-Parameter in Fit Life by X?

Hallo allerseits,

I need to dynamically pass variables to the X parameter in the fit life by x function. The first part of my code generates the analysis report as expected, but the second part only brings up the startup window without a report.

So sieht mein Code aus:

Names Default To Here(1);

dt = Open( "$sample_data/big class.jmp" );

x_var = "sex";
y_var = "weight";

obj1 = dt << Fit Life by X(
	Distribution( Weibull ),
	Nested Model Tests( Location and Scale ),
	Y( Eval(y_var) ),
	X( :sex ),
);

wait(2);

obj2 = dt << Fit Life by X(
	Distribution( Weibull ),
	Nested Model Tests( Location and Scale ),
	Y( :weight ),
	X( Eval(x_var) ),
);

Ist jemandem dieses Problem begegnet oder weiß jemand, wie die Variablen korrekt an den X-Parameter übergeben werden?

Danke!

Automatisierung und SkriptingZuverlässigkeitsanalyseBetreff: Wie übergebe ich Variablen an den X-Parameter in Fit Life by X?

Bitte beachten Sie Folgendes.

Da „Beziehung“ fehlt, versucht der Code, die beste Vermutung auf der Grundlage von X anzustellen. Aber an der Stelle, an der der Code X prüft, ist X in diesem Fall noch keine gültige Spalte. Wenn der Code also vollständige Informationen liefert, müssen Sie nicht in die Falle tappen.

Names Default To Here(1);

dt = Open( "$sample_data/big class.jmp" );

x_var = "sex";
y_var = "weight";

obj1 = dt << Fit Life by X(
	Distribution( Weibull ),
	Relationship( Location and Scale ),
	Nested Model Tests( Location and Scale ),
	Y( Eval(y_var) ),
	X( :sex ),
);

wait(2);

obj2 = dt << Fit Life by X(
	Distribution( Weibull ),
	Relationship( Location and Scale ),
	Nested Model Tests( Location and Scale ),
	Y( :weight ),
	X( Eval(x_var) ),
);

Betreff: Wie übergebe ich Variablen an den X-Parameter in Fit Life by X?

Dies scheint etwas mehr Arbeit zu erfordern, um es zu umgehen, da das "normale" Erzwingen nicht funktioniert

Names Default To Here(1);

dt = Open("$sample_data/big class.jmp");

x_var = "sex";
y_var = "weight";

myexpr = EvalExpr(dt << Fit Life by X(
	Distribution( Weibull ),
	Nested Model Tests( Location and Scale ),
	Y( :weight ),
	X(Expr(NameExpr(AsColumn(dt, x_var)))),
));
show(myexpr);
obj = Eval(myexpr);

Einer der extrem seltenen Fälle, in denen ich sagen würde, man solle Eval(Parse()) (evil parse) verwenden, aber das scheint zu funktionieren

Names Default To Here(1);

dt = Open("$sample_data/big class.jmp");

x_var = "sex";
y_var = "weight";

obj2 = Eval(Parse(Eval Insert("\[dt << Fit Life by X(
	Distribution(Weibull),
	Nested Model Tests(Location and Scale),
	Y(:weight),
	X(:^x_var^)
)]\")));

Betreff: Wie übergebe ich Variablen an den X-Parameter in Fit Life by X?

Diese Anomalie scheint ein Fehler zu sein. Das Argument Nested Model Tests wird im zweiten Fall nicht erkannt. Bitte melden Sie dies dem technischen Support von JMP ( support@jmp.com ), damit es als Defekt erfasst und verfolgt werden kann.

Betreff: Wie übergebe ich Variablen an den X-Parameter in Fit Life by X?

Oh, das ist genau die richtige Antwort. Vielen Dank!

Betreff: Wie übergebe ich Variablen an den X-Parameter in Fit Life by X?

Dies ist auch ein weiterer Workaround. Danke!