762515_es-ES

liliconcom

Ventana de subconjunto de gráficos de variabilidad por estructura de árbol en ventana de subconjunto en JSL

Hola a todos,

Tengo un problema con mi secuencia de comandos después de crear un gráfico de variabilidad dinámica de aproximadamente 30 gráficos, pero quiero subconjunto una pequeña cantidad en otra ventana pero no puedo hacerlo. Por política de la empresa, no puedo publicar el código, pero he usado un ejemplo de lo que estoy tratando de hacer usando JMP Sample Data como se ve a continuación.

dt = Open("C:\Program Files\SAS\JMP\17\Samples\Data\Quality Control\Braces.jmp");

vc = Variability Chart(
	Y( :"# defects"n ),
	Model( "Main Effect" ),
	X( :Date ),
	Variability Analysis(
		:"# defects"n,
		Show Range Bars( 0 ),
		Show Cell Means( 0 ),
		Std Dev Chart( 0 )
	),
	By( :Unit size )
);

subset_vc = New Window("Only some vc", vlis = V List Box());
frameboxes_to_subset = {1, 3, 5}; // Want to get when unit size = 4, 8, 12
vc_rpt = vc << Report;
show(N Items( (vc_rpt << XPath( "//FrameBox" )) ));
structure = vc_rpt << Show tree structure;
for(i = 1, i <= N Items(frameboxes_to_subset), i++,
	vlis << append(vc_rpt[FrameBox(frameboxes_to_subset[i])]);
);

Puedo ver en el registro que el vc_rpt original tiene 6 Frameboxes como se esperaba, pero cuando intento crear subconjuntos según el número de Framebox que se ve en "mostrar estructura de árbol", no se agrega ningún gráfico. También intenté envolverlo en un cuadro de lista V adicional y, de manera similar, nada funcionó para agregarlo a la nueva ventana. Cualquier ayuda sería muy apreciada. ¡Gracias!

Automatización y secuencias de comandosAnálisis y modelado de datos básicosExploración y visualización de datosLa personalización en masaventanasRe: Ventana de subconjunto de gráficos de variabilidad por estructura de árbol en ventana de subconjunto en JSL

Gracias Jim,

Interesante, leeré sobre eso porque pensé que una ventana representaba una "página" de un diario de modo que solo habría una. ¡Agradezco la ayuda!

Re: Ventana de subconjunto de gráficos de variabilidad por estructura de árbol en ventana de subconjunto en JSL

Tu error está en pensar que todas las imágenes están en un solo informe. En cambio, hay 6 informes, cada uno con una imagen.

Por lo tanto, su código debe cambiarse para recorrer un informe específico y tomar el cuadro de marco (1) de cada informe.

dt = Open("C:\Program Files\SAS\JMP\17\Samples\Data\Quality Control\Braces.jmp");

vc = Variability Chart(
	Y( :"# defects"n ),
	Model( "Main Effect" ),
	X( :Date ),
	Variability Analysis(
		:"# defects"n,
		Show Range Bars( 0 ),
		Show Cell Means( 0 ),
		Std Dev Chart( 0 )
	),
	By( :Unit size )
);

subset_vc = New Window("Only some vc", vlis = V List Box());
frameboxes_to_subset = {1, 3, 5}; // Want to get when unit size = 4, 8, 12
vc_rpt = vc << Report;
//show(N Items( (vc_rpt << XPath( "//FrameBox" )) ));
//structure = vc_rpt << Show tree structure;
for(i = 1, i <= N Items(frameboxes_to_subset), i++,
	vlis << append(vc_rpt[frameboxes_to_subset[i]][FrameBox(1)]);
);

También estoy pensando que es posible que no desees extraer solo FrameBox(), sino extraer PictureBox().

subset_vc = New Window("Only some vc", vlis = V List Box());
frameboxes_to_subset = {1, 3, 5}; // Want to get when unit size = 4, 8, 12
vc_rpt = vc << Report;
//show(N Items( (vc_rpt << XPath( "//FrameBox" )) ));
//structure = vc_rpt << Show tree structure;
for(i = 1, i <= N Items(frameboxes_to_subset), i++,
	vlis << append(vc_rpt[frameboxes_to_subset[i]][PictureBox(1)]);
);