762515_it-IT

liliconcom

Finestra sottoinsieme del grafico della variabilità per struttura ad albero nella finestra sottoinsieme in JSL

Ciao a tutti,

Sto riscontrando un problema con il mio script dopo aver creato un grafico di variabilità dinamica di circa 30 grafici, ma desidero sottoinsiemi di una piccola quantità in un'altra finestra ma non riesco a farlo. Per politica aziendale non posso pubblicare il codice ma ho utilizzato un esempio di ciò che sto cercando di fare utilizzando i dati di esempio JMP come mostrato di seguito.

dt = Open("C:\Program Files\SAS\JMP\17\Samples\Data\Quality Control\Braces.jmp");

vc = Variability Chart(
	Y( :"# defects"n ),
	Model( "Main Effect" ),
	X( :Date ),
	Variability Analysis(
		:"# defects"n,
		Show Range Bars( 0 ),
		Show Cell Means( 0 ),
		Std Dev Chart( 0 )
	),
	By( :Unit size )
);

subset_vc = New Window("Only some vc", vlis = V List Box());
frameboxes_to_subset = {1, 3, 5}; // Want to get when unit size = 4, 8, 12
vc_rpt = vc << Report;
show(N Items( (vc_rpt << XPath( "//FrameBox" )) ));
structure = vc_rpt << Show tree structure;
for(i = 1, i <= N Items(frameboxes_to_subset), i++,
	vlis << append(vc_rpt[FrameBox(frameboxes_to_subset[i])]);
);

Nel registro riesco a vedere che vc_rpt originale ha 6 Framebox come previsto, ma quando provo a sottoinsiemi in base al numero di Framebox visualizzato nella "mostra struttura ad albero", non viene aggiunto alcun grafico. Ho anche provato a inserirlo in una V List Box aggiuntiva e allo stesso modo non ha funzionato nulla da aggiungere alla nuova finestra. Qualsiasi aiuto sarebbe molto apprezzato. Grazie!

Automazione e scriptingAnalisi e modellazione dei dati di baseEsplorazione e visualizzazione dei datiPersonalizzazione di massafinestreRi: Finestra sottoinsieme del grafico della variabilità per struttura ad albero nella finestra sottoinsieme in JSL

Grazie Jim,

Interessante, lo leggerò perché pensavo che una finestra rappresentasse una "pagina" di un diario in modo tale che ce ne sarebbe stata solo una. Apprezzo l'aiuto!

Ri: Finestra sottoinsieme del grafico della variabilità per struttura ad albero nella finestra sottoinsieme in JSL

Il tuo errore è pensare che tutte le immagini siano in un unico report. Sono invece presenti 6 report, ciascuno con un'immagine.

Pertanto il codice deve essere modificato per eseguire il looping di un report specificato e acquisire framebox(1) da ciascun report.

dt = Open("C:\Program Files\SAS\JMP\17\Samples\Data\Quality Control\Braces.jmp");

vc = Variability Chart(
	Y( :"# defects"n ),
	Model( "Main Effect" ),
	X( :Date ),
	Variability Analysis(
		:"# defects"n,
		Show Range Bars( 0 ),
		Show Cell Means( 0 ),
		Std Dev Chart( 0 )
	),
	By( :Unit size )
);

subset_vc = New Window("Only some vc", vlis = V List Box());
frameboxes_to_subset = {1, 3, 5}; // Want to get when unit size = 4, 8, 12
vc_rpt = vc << Report;
//show(N Items( (vc_rpt << XPath( "//FrameBox" )) ));
//structure = vc_rpt << Show tree structure;
for(i = 1, i <= N Items(frameboxes_to_subset), i++,
	vlis << append(vc_rpt[frameboxes_to_subset[i]][FrameBox(1)]);
);

Sto anche pensando che potresti non voler tirare solo FrameBox(), ma invece tirare PictureBox()

subset_vc = New Window("Only some vc", vlis = V List Box());
frameboxes_to_subset = {1, 3, 5}; // Want to get when unit size = 4, 8, 12
vc_rpt = vc << Report;
//show(N Items( (vc_rpt << XPath( "//FrameBox" )) ));
//structure = vc_rpt << Show tree structure;
for(i = 1, i <= N Items(frameboxes_to_subset), i++,
	vlis << append(vc_rpt[frameboxes_to_subset[i]][PictureBox(1)]);
);