762515_de-DE

liliconcom

Teilmengenfenster von Variabilitätsdiagrammen nach Baumstruktur in Teilmengenfenster in JSL

Hallo zusammen,

Ich habe ein Problem mit meinem Skript, nachdem ich ein dynamisches Variabilitätsdiagramm mit ungefähr 30 Diagrammen erstellt habe, aber einen kleinen Teil davon in ein anderes Fenster unterteilen möchte, was mir aber nicht gelingt. Aus Unternehmensgründen kann ich den Code nicht veröffentlichen, habe aber ein Beispiel dessen verwendet, was ich mit JMP-Beispieldaten zu tun versuche, wie unten dargestellt.

dt = Open("C:\Program Files\SAS\JMP\17\Samples\Data\Quality Control\Braces.jmp");

vc = Variability Chart(
	Y( :"# defects"n ),
	Model( "Main Effect" ),
	X( :Date ),
	Variability Analysis(
		:"# defects"n,
		Show Range Bars( 0 ),
		Show Cell Means( 0 ),
		Std Dev Chart( 0 )
	),
	By( :Unit size )
);

subset_vc = New Window("Only some vc", vlis = V List Box());
frameboxes_to_subset = {1, 3, 5}; // Want to get when unit size = 4, 8, 12
vc_rpt = vc << Report;
show(N Items( (vc_rpt << XPath( "//FrameBox" )) ));
structure = vc_rpt << Show tree structure;
for(i = 1, i <= N Items(frameboxes_to_subset), i++,
	vlis << append(vc_rpt[FrameBox(frameboxes_to_subset[i])]);
);

Ich kann im Protokoll sehen, dass das ursprüngliche vc_rpt wie erwartet 6 Frameboxen hat, aber wenn ich versuche, sie basierend auf der in der „Baumstruktur anzeigen“ angezeigten Framebox-Nummer zu unterteilen, wird kein Diagramm angehängt. Ich habe auch versucht, es in eine zusätzliche V-Listenbox einzuschließen, aber auch das Hinzufügen zum neuen Fenster hat nicht funktioniert. Für jede Hilfe wäre ich sehr dankbar. Danke!

Automatisierung und SkriptingGrundlegende Datenanalyse und ModellierungDatenexploration und -visualisierungMassenanpassungWindowsBetreff: Teilmengenfenster von Variabilitätsdiagrammen durch Baumstruktur in Teilmengenfenster in JSL

Danke Jim,

Interessant, werde das nachlesen, da ich dachte, ein Fenster stelle eine „Seite“ eines Journals dar, sodass es nur eine geben würde. Danke für die Hilfe!

Betreff: Teilmengenfenster von Variabilitätsdiagrammen durch Baumstruktur in Teilmengenfenster in JSL

Ihr Fehler liegt darin, dass Sie denken, alle Bilder seien in einem Bericht enthalten. Stattdessen gibt es sechs Berichte mit jeweils einem Bild.

Daher muss Ihr Code so geändert werden, dass er einen angegebenen Bericht durchläuft und aus jedem Bericht die Framebox(1) erfasst.

dt = Open("C:\Program Files\SAS\JMP\17\Samples\Data\Quality Control\Braces.jmp");

vc = Variability Chart(
	Y( :"# defects"n ),
	Model( "Main Effect" ),
	X( :Date ),
	Variability Analysis(
		:"# defects"n,
		Show Range Bars( 0 ),
		Show Cell Means( 0 ),
		Std Dev Chart( 0 )
	),
	By( :Unit size )
);

subset_vc = New Window("Only some vc", vlis = V List Box());
frameboxes_to_subset = {1, 3, 5}; // Want to get when unit size = 4, 8, 12
vc_rpt = vc << Report;
//show(N Items( (vc_rpt << XPath( "//FrameBox" )) ));
//structure = vc_rpt << Show tree structure;
for(i = 1, i <= N Items(frameboxes_to_subset), i++,
	vlis << append(vc_rpt[frameboxes_to_subset[i]][FrameBox(1)]);
);

Ich denke auch, dass Sie vielleicht nicht nur die FrameBox() ziehen möchten, sondern stattdessen die PictureBox()

subset_vc = New Window("Only some vc", vlis = V List Box());
frameboxes_to_subset = {1, 3, 5}; // Want to get when unit size = 4, 8, 12
vc_rpt = vc << Report;
//show(N Items( (vc_rpt << XPath( "//FrameBox" )) ));
//structure = vc_rpt << Show tree structure;
for(i = 1, i <= N Items(frameboxes_to_subset), i++,
	vlis << append(vc_rpt[frameboxes_to_subset[i]][PictureBox(1)]);
);