762845_ko-KR

liliconcom

산점도 행렬의 여러 Y에 참조선을 어떻게 추가합니까?

산점도 행렬의 여러 Y에 참조선을 추가하는 방법에 대한 질문이 있습니다.

참조선 값을 얻는 데 성공했습니다.

그런데 어떻게 추가해야 할지 모르겠어요.

모든 "Y"에 ScaleBox를 추가하고 싶습니다.

예를 들어,

//sel_colnames = {"SPK_VOS_TrimCode_Dec", "SPK_RCV_VOS_TrimCode_Dec", "SPK_RCV_VOS_Post_0p5W"};

upper_limit = {10, 1, 15, 0.75};
lower_limit = {-10, 0.5, -15, -0.75};

아래 차트에 upper_limit 및 lower_limit를 추가하고 싶습니다.

또한 각 "Y"에 대한 Y축 배율을 조정하고 싶습니다.

//다중 "Y"에 대한 JSL - 이에 대한 조언을 부탁드립니다.

Names Default To Here(1);


dt adress = pick file({"All Files|*"});
dt = Open(
	dt adress,
	columns(
	),
	Import Settings(
		End Of Line( CRLF, CR, LF ),
		End Of Field( Comma, CSV( 1 ) ),
		Strip Quotes( 0 ),
		Use Apostrophe as Quotation Mark( 0 ),
		Use Regional Settings( 0 ),
		Scan Whole File( 1 ),
		Treat empty columns as numeric( 0 ),
		CompressNumericColumns( 0 ),
		CompressCharacterColumns( 0 ),
		CompressAllowListCheck( 0 ),
		Labels( 0 ),
		Column Names Start( 1 ),
		Data Starts( 47 ),
		Lines To Read( "All" ),
		Year Rule( "20xx" )
	)
);


//Delete unnecessary columns
dt=Current Data Table ();
dt << Delete Columns( :"Column 2"n, :"Column 3"n, :"Column 4"n, :"Column 5"n);
dt << delete row( 6 );


// Split dt -> dt(value of test item) & dt_item(upper&lower limit of test item)
dt << select rows({1,2,3,4,5}) ;
dt_item = subset( dt );
dt << delete rows( {2,3,4,5} );


// Replace column names with Test Name (*dt)
For( c = 1, c < N Col( dt ), c ++,
 Column( dt, c ) << Set Name( Column( dt, c )[1] );
);
// Replace column names with Test Name (*dt_item)
For( c = 1, c < N Col( dt_item ), c ++,
 Column( dt_item, c ) << Set Name( Column( dt_item, c )[1] );
);

dt << delete rows( {1} );
dt_item << delete rows( {1} );


//Change Data Type to Numeric&Continuous (*dt)
colList = dt << get column names(charater);

For(i=1,i<=n items(colList), i++,
column(dt, colList[i]) << Data Type( Numeric ) << Set Modeling Type( Continuous );
);
//Change Data Type to Numeric&Continuous (*dt_item)
colList = dt_item << get column names(charater);

For(i=1,i<=n items(colList), i++,
column(dt_item, colList[i]) << Data Type( Numeric ) << Set Modeling Type( Continuous );
);


///Data processing done.



//Select Test Item for Scatterplot Matrix
colDlg = Column Dialog(
	Title( "Test Item Selct" ),
	ycol = Col List( "Test Item", Min Col( 1 ), Max Col(15) ), //
);


//Read Test Item's Test Number, Upper & Lower Limit 
n = N Items( colDlg["ycol"] );

dt_item << Select Columns( colDlg["ycol"]);

sel_colnames = dt_item << Get Selected Columns(string); 
show(sel_colnames);


//Read Test Item's Test Number, Upper & Lower Limit
rowNum = 1;
col = Column( dt_item(), colDlg["ycol"]);
test_no = col[ rowNum ];
//Read UL 
rowNum = 3;
upper_limit = col[ rowNum ];
//Read LL
rowNum = 2;
lower_limit = col[ rowNum ];


//Read Test Item's Test Number, Upper & Lower Limit
test_no = {};
upper_limit = {};
lower_limit = {};

for(cnt=1, cnt <= n, cnt++,
col = Column( dt_item(), sel_colnames[cnt]);
show (col);
rowNum = 1;
test_no[cnt] = col[ rowNum ];
//Read UL 
rowNum = 3;
upper_limit[cnt] = col[ rowNum ];
//Read LL
rowNum = 2;
lower_limit[cnt] = col[ rowNum ];
);
show(test_no);	show(upper_limit);	show(lower_limit);


//Scatterplot Matrix
stm = dt << Scatterplot Matrix(Y(colDlg["ycol"]), X( :Test Name),
	Fit Line( 0 ),
	SendToReport(
		Dispatch(
			{},
			"1100",
		),
		Dispatch( {}, "Test Name", TextEditBox, {Set Text( "Site #" )}),
		Dispatch( {}, "Scatterplot Matrix Plot", FrameBox, {Frame Size( 500, 200 )} ),
	)
);

//Close Data Tables without the report.
stm << Journal;

close(dt,"nosave");
close(dt_item,"nosave");

자동화 및 스크립팅Re: 산점도 행렬의 여러 Y에 참조선을 어떻게 추가합니까?

정말 감사합니다!!

Re: 산점도 행렬의 여러 Y에 참조선을 어떻게 추가합니까?

현재 모든 축 상자에 대한 모든 제한을 설정하고 있으므로 최소한 abs에서 abs[x]로 설정해야 합니다.

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

cols = {"height", "weight"};

lsls = {55, 80};
usls = {70, 160};

spm = dt << Scatterplot Matrix(
	Y(Eval(cols)),
	X(:age),
	Fit Line(0)
);

abs = Report(spm) << XPath("//AxisBox");
Remove From(abs, N Items(abs)); // Drop x-axis

For (x=1, x <= N Items(abs), x++,
	Eval(EvalExpr(
		abs[x] << Add Ref Line(Expr(lsls[x]), "Dashed", blue, Expr(Char(lsls[x])), 1);
		abs[x] << Add Ref Line(Expr(usls[x]), "Dashed", blue, Expr(Char(usls[x])), 1);
	))
);

Re: 산점도 행렬의 여러 Y에 참조선을 어떻게 추가합니까?

당신의 답변에 감사드립니다.

이 예제는 JMP 버전 15에서 작동하지 않습니다.

"For Each" 구문을 어떻게 바꿀 수 있나요?

죄송합니다. "For Each"가 어떻게 작동하는지 모르겠습니다.

------------

방금 For Each 구문을 for 구문으로 바꿨습니다.

거의 작동하지만 모든 'Y'에는 동일한 참조 라인이 있습니다. (*한계[1] 값..)

어떻게 해결할 수 있나요?

각각을 위해 -> 각각을 위해

abs = Report(stm) << XPath("//AxisBox"); //Display Option. 
Remove From(abs, N Items(abs)); // Drop x-axis

//Show (N Items(abs));

For (x=1, x <= N Items(abs), x++ ,
	Eval(EvalExpr(
		abs << Add Ref Line(Expr(lower_limit[x]), "Dashed", blue, "LSL", 1);
		abs << Add Ref Line(Expr(upper_limit[x]), "Dashed", blue, "USL", 1);
	))
);

*결과

감사해요

Re: 산점도 행렬의 여러 Y에 참조선을 어떻게 추가합니까?

다음은 간단한 예입니다.

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

cols = {"height", "weight"};

lsls = {55, 80};
usls = {70, 160};

spm = dt << Scatterplot Matrix(
	Y(Eval(cols)),
	X(:age),
	Fit Line(0)
);

abs = Report(spm) << XPath("//AxisBox");
Remove From(abs, N Items(abs)); // Drop x-axis

For Each({ab, idx}, abs,
	Eval(EvalExpr(
		ab << Add Ref Line(Expr(lsls[idx]), "Dashed", blue, "LSL", 1);
		ab << Add Ref Line(Expr(usls[idx]), "Dashed", blue, "USL", 1);
	))
);

연관 배열을 사용하여 제한을 저장하면 코드가 좀 더 깔끔해질 수 있습니다.