84969_it-IT

liliconcom

Aggiunta dei limiti delle specifiche nel grafico del misuratore degli attributi di variabilità

Ho una tabella con 100 dispositivi e 300 elementi di prova testati. Ho colonne specifiche che contengono separatamente LSL, USL. Voglio tracciare il grafico del misuratore degli attributi di variabilità con i limiti delle specifiche al suo interno. Per favore mostrami come farlo o se c'è qualche discussione esistente in questo argomento, per favore indicamelo. Grazie.

Tabella dati di esempio:

Dispositivo	Nome della prova	Misurazione	LSL	USL
1	Prova 1	230	200	240
1	Prova2	20	15	25
1	Prova3	30	25	35
2	Prova 1	234	200	240
2	Prova2	22	15	25
2	Prova3	29	25	35
3	Prova 1	229	200	240
3	Prova2	21	15	25
4	Prova 1	230	200	240
4	Prova2	21	15	25

Modellazione statistica avanzataAccesso ai datiEsplorazione e visualizzazione dei datiPersonalizzazione di massaRi: Aggiunta dei limiti delle specifiche nel grafico del misuratore degli attributi di variabilità

Grazie, txnelson, ha funzionato.

Grazie Uday per il suggerimento.

Ri: Aggiunta dei limiti delle specifiche nel grafico del misuratore degli attributi di variabilità

Il problema principale con ciò che desideri è che i tuoi dati non sono nella forma corretta per l'esecuzione della piattaforma del grafico degli attributi di variabilità. Lo script seguente trasformerà una tabella dati con le colonne specificate in una tabella dati che può essere utilizzata per generare i grafici desiderati.

Names Default To Here( 1 );
dt = Current Data Table();

// Make a list of the Tests
Summarize( dt, testList = by( :Test Name ) );

dtSplit = dt << Split(
	Split By( :Test Name ),
	Split( :Measurement, :LSL, :USL ),
	Group( :Device ),
	Sort by Column Property
);

// Rename the test columns and set the Spec Limits
For( i = 2, i <= N Items( testList ) + 1, i++,
 
	// Assign the new names
	Column( dtSplit, i ) << set name( Substr( Column( dtSplit, i ) << get Name, 13 ) );
	
	// Set the Spec Limits
	Eval(
		Substitute(
				Expr(
					Column( dtSplit, i ) << set property(
						"Spec Limits ",
						{LSL( __LSL__ ), USL( __USL__ ), Show Limits( 1 )}
					)
				),
			Expr( __LSL__ ), Col Mean( As Column( dtSplit, i + N Items( (testList) ) ) ),
			Expr( __USL__ ),
				Col Mean( As Column( dtSplit, i + 2 * N Items( (testList) ) ) )
		)
	);
);

// Delete unwanted limits columns
dtSplit << delete columns( Index( N Items( testList ) + 2, N Cols( dtSplit ) ) );

Ri: Aggiunta dei limiti delle specifiche nel grafico del misuratore degli attributi di variabilità

@Vmuthu,
https://community.jmp.com/t5/Discussions/Adding-Control-spec-limits/mp/7037#M7031

Hai controllato se nella community sono presenti domande simili?