753188_zh-TW

liliconcom

列中的上一個和下一個非缺失值

我對 JMP 相當陌生，我遇到了一個讓我非常困擾的問題。我使用 JMP Pro 17。我透過建立一個公式列找到了訊號局部最大值（峰值），如果該距離處的訊號值是給定範圍內的最大值（Signal[row] == max(Signal[row-n, row） +n ]），但是，我的問題如下；我希望創建另一個公式列，給出每個峰值到最近峰值的距離。

換句話說，我希望，如果“巔峰？” == 1，求「Peak？」處的上一行和下一行的距離值== 1，求目前行的距離與那些行的距離差的絕對值，並得到這兩個值的最小值。

到目前為止，我已經建立了一個“輔助列”，如果該行包含本地訊號最大值，則給出該值的距離。換句話說，我有一列包含峰值訊號值處的距離值，以及所有非峰值行中的缺失值。但是，我找不到透過公式「前一個非缺失值」或「下一個非缺失值」來定義的方法。我將非常感謝任何建議，無論是關於如何為此制定公式，還是有更好的方法來解決尋找峰值之間最小距離的實際問題。

基礎資料分析與建模數據探索和視覺化回覆：列中的上一個和下一個非缺失值

我想到的第一個想法所以它看起來確實相當複雜

Names Default To Here(1);

dt = New Table("Untitled",
	Add Rows(12),
	Compress File When Saved(1),
	New Column("Peaks", Numeric, "Continuous", 
		Set Values([., 1, ., ., 2.5, ., ., ., ., 3.1, ., ., 2])
	)
);


dt << New Column("DistanceToPeak", Numeric, Continuous, Formula(
	As Constant(m = :Peaks << get values;
		peak_rows = Loc(m);
		peak_values = m[peak_rows];
	);
	
	If(!IsMissing(:Peaks),
		peak_distances = peak_rows - Row();
		
		previous_peak = Loc(peak_distances < 0);
		If(N Items(previous_peak) == 0,
			previous_distance = .;
		,
			previous_distance = Abs(m[Row()] - peak_values[Reverse(previous_peak)[1]]);
		);
		
		next_peak = Loc(peak_distances > 0);
		If(N Items(next_peak) == 0,
			next_distance = .;
		,
			next_distance = Abs(m[Row()] - peak_values[next_peak[1]]);
		);
		Min(previous_distance, next_distance);
	,
		.
	);
));

回覆：列中的上一個和下一個非缺失值

太感謝了！它工作得很漂亮。我會盡力閱讀並嘗試理解您的公式。

如果可以的話，我想向您或讀到這裡的其他人問一個額外的、相當相關的問題。

接下來，我要找出兩個通道中峰值之間的最小距離。即，我有距離、信號 1 和信號 2，我已經找到了每個信號的峰值，並且感謝 jthi 的出色幫助，我現在可以找到信號 1 和信號 2 的最小峰值間距。在訊號1 的峰值處找到到訊號2 最近的峰值的距離嗎？換句話說，如果使用上面jthi 回復中的附圖，請添加一列“Peaks2”，並使用公式，如果“Peaks”不缺失，則找到“Peaks”和“Peaks2”之間的差的絕對值的最小值「Peaks2」的上一個和下一個非缺失值？

回覆：列中的上一個和下一個非缺失值

類似的想法應該仍然有效

看更多...

Names Default To Here(1);

dt = New Table("Untitled",
	Add Rows(12),
	Compress File When Saved(1),
	New Column("Peak1", Numeric, "Continuous", 
		Set Values([., 1, ., ., 2.5, ., ., ., ., 3.1, ., ., 2])
	),
	New Column("Peak2", Numeric, "Continuous", 
		Set Values([0.5, 0.9, ., 2, ., 4, ., ., ., ., ., 5, .])
	)	
);


dt << New Column("Peak1ToPeak1", Numeric, Continuous, Formula(
	As Constant(m = :Peak1 << get values;
		peak_rows = Loc(m);
		peak_values = m[peak_rows];
	);
	
	If(!IsMissing(:Peak1),
		peak_distances = peak_rows - Row();
		
		previous_peak = Loc(peak_distances < 0);
		If(N Items(previous_peak) == 0,
			previous_distance = .;
		,
			previous_distance = Abs(m[Row()] - peak_values[Reverse(previous_peak)[1]]);
		);
		
		next_peak = Loc(peak_distances > 0);
		If(N Items(next_peak) == 0,
			next_distance = .;
		,
			next_distance = Abs(m[Row()] - peak_values[next_peak[1]]);
		);
		Min(previous_distance, next_distance);
	,
		.
	);
));

dt << New Column("Peak1ToPeak2", Numeric, Continuous, Formula(
	As Constant(m = :Peak2 << get values;
		peak_rows = Loc(m);
		peak_values = m[peak_rows];
	);
	
	If(!IsMissing(:Peak1),
		peak_distances = peak_rows - Row();
		
		previous_peak = Loc(peak_distances < 0);
		If(N Items(previous_peak) == 0,
			previous_distance = .;
		,
			previous_distance = Abs(:Peak1[Row()] - peak_values[Reverse(previous_peak)[1]]);
		);
		
		next_peak = Loc(peak_distances > 0);
		If(N Items(next_peak) == 0,
			next_distance = .;
		,
			next_distance = Abs(:Peak1[Row()] - peak_values[next_peak[1]]);
		);
		Min(previous_distance, next_distance);
	,
		.
	);
));

根據您將如何使用這些數據+您對程式設計的適應程度，我可能會考慮創建一些函數，因為這些函數可以使程式碼更容易理解（例如“查找較早的行”，“查找下一行”，“查找最近的行”）排”，...）。

回覆：列中的上一個和下一個非缺失值

再次感謝你！工作起來一樣漂亮。我開始了解你的程式碼。

感謝您的建議。正如我所提到的，我對 JMP 以及一般程式設計都很陌生。但我一定會記住這一點，尤其是當我獲得更多經驗時。再次感謝，祝您一切順利！