752017_zh-TW

liliconcom

開啟 4 張 JPEG 並將其新增至 2x2 視窗中

你好，

如何編寫腳本在 JMP 中開啟 4 個 jpeg，然後將它們放入 2x2 視窗中？我想將視窗的大小指定為一定大小。然後我想將視窗儲存為jpeg。

任何幫助都是appriced！謝謝！

自動化和腳本編寫視窗回覆：開啟 4 張 JPEG 並將其新增至 2x2 視窗中

這是處理該問題的一種方法的簡單範例

Names Default To Here( 1 );

image1 = New Image( "$SAMPLE_IMAGES/windmap.png" );
image2 = New Image( "$SAMPLE_IMAGES/black rhino footprint.jpg" );
image3 = New Image( "$SAMPLE_IMAGES/tile.jpg" );
image4 = New Image( "$SAMPLE_IMAGES/pi.gif" );

nw = New Window( "Pictures",
	Outline Box( "The Pictures",
		Lineup Box( N Col( 2 ), image1, image2, image3, image4 )
	)
);

theWholePicture = nw[Outline Box( 1 )] << get picture;

theWholePicture << save image( "$TEMP/myPicture.jpg,", "jpg" );

nw << close window;

theSavedImage = New Image( "$TEMP/myPicture.jpg," );

theNW = New Window( "Final Picture", theSavedImage );

您可以使用以下方法設定圖片大小

img << Set Size( {600, 600} );

請參閱腳本索引以獲取可與新圖像一起使用的消息

回覆：開啟 4 張 JPEG 並將其新增至 2x2 視窗中

我會像吉姆一樣選擇陣容框，因為我認為這是最簡單的選擇。另一種選擇（更複雜）是使用圖形框並向其中添加圖像

Names Default To Here(1);

image1 = New Image("$SAMPLE_IMAGES/windmap.png");
image2 = New Image("$SAMPLE_IMAGES/black rhino footprint.jpg");
image3 = New Image("$SAMPLE_IMAGES/tile.jpg");
image4 = New Image("$SAMPLE_IMAGES/pi.gif");

nw = New Window("View Image",
	gb = Graph Box(
		FrameSize(500, 500),
		X Scale(0, 100),
		Y Scale(0, 100),
		SuppressAxes(1)
	)
);

fb = nw[FrameBox(1)];

fb << Add Image(image(image1), bounds(top(0), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image2), bounds(top(0), Left(50), bottom(50), Right(100)));
fb << Add Image(image(image3), bounds(top(100), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image4), bounds(top(100), Left(50), bottom(50), Right(100)));

img = fb << get picture;
img << save image("$TEMP/pic.png", "png");
nw << close window;

從這篇文章中至少可以找到另一種技術合併/縫合圖像