752017_es-ES

liliconcom

Abra y agregue 4 archivos JPEG en una ventana de 2x2

Hola,

¿Cómo escribo un script para abrir 4 archivos JPEG en JMP y luego los coloco en una ventana de 2x2? Me gustaría especificar que el tamaño de la ventana sea de un tamaño determinado. Luego me gustaría guardar la ventana en un formato jpeg.

¡Se agradece cualquier ayuda! ¡Gracias!

Automatización y secuencias de comandosventanasRe: Abrir y agregar 4 archivos JPEG en una ventana de 2x2

Aquí hay un ejemplo simple de una forma de manejar la pregunta.

Names Default To Here( 1 );

image1 = New Image( "$SAMPLE_IMAGES/windmap.png" );
image2 = New Image( "$SAMPLE_IMAGES/black rhino footprint.jpg" );
image3 = New Image( "$SAMPLE_IMAGES/tile.jpg" );
image4 = New Image( "$SAMPLE_IMAGES/pi.gif" );

nw = New Window( "Pictures",
	Outline Box( "The Pictures",
		Lineup Box( N Col( 2 ), image1, image2, image3, image4 )
	)
);

theWholePicture = nw[Outline Box( 1 )] << get picture;

theWholePicture << save image( "$TEMP/myPicture.jpg,", "jpg" );

nw << close window;

theSavedImage = New Image( "$TEMP/myPicture.jpg," );

theNW = New Window( "Final Picture", theSavedImage );

Puede configurar los tamaños de las imágenes utilizando

img << Set Size( {600, 600} );

Consulte el índice de secuencias de comandos para conocer los mensajes que se pueden utilizar con Nueva imagen.

Re: Abrir y agregar 4 archivos JPEG en una ventana de 2x2

Yo elegiría el cuadro Alineación como lo mostró Jim, ya que creo que es la opción más simple. Otra opción (más complicada) es usar Graph Box y agregarle imágenes.

Names Default To Here(1);

image1 = New Image("$SAMPLE_IMAGES/windmap.png");
image2 = New Image("$SAMPLE_IMAGES/black rhino footprint.jpg");
image3 = New Image("$SAMPLE_IMAGES/tile.jpg");
image4 = New Image("$SAMPLE_IMAGES/pi.gif");

nw = New Window("View Image",
	gb = Graph Box(
		FrameSize(500, 500),
		X Scale(0, 100),
		Y Scale(0, 100),
		SuppressAxes(1)
	)
);

fb = nw[FrameBox(1)];

fb << Add Image(image(image1), bounds(top(0), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image2), bounds(top(0), Left(50), bottom(50), Right(100)));
fb << Add Image(image(image3), bounds(top(100), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image4), bounds(top(100), Left(50), bottom(50), Right(100)));

img = fb << get picture;
img << save image("$TEMP/pic.png", "png");
nw << close window;

Se puede encontrar al menos una técnica más en esta publicación Fusionar/unir imágenes