752017_zh-CN

liliconcom

打开 4 张 JPEG 照片并将其添加到 2x2 窗口中

你好，

如何编写脚本在 JMP 中打开 4 张 jpeg，然后将它们放在 2x2 窗口中？我想将窗口的大小指定为某个大小。然后我想将窗口保存为 jpeg。

任何帮助都非常感谢！谢谢！

自动化和脚本视窗回复：打开 4 张 JPEG 并将其添加到 2x2 窗口中

这是一个处理问题的简单示例

Names Default To Here( 1 );

image1 = New Image( "$SAMPLE_IMAGES/windmap.png" );
image2 = New Image( "$SAMPLE_IMAGES/black rhino footprint.jpg" );
image3 = New Image( "$SAMPLE_IMAGES/tile.jpg" );
image4 = New Image( "$SAMPLE_IMAGES/pi.gif" );

nw = New Window( "Pictures",
	Outline Box( "The Pictures",
		Lineup Box( N Col( 2 ), image1, image2, image3, image4 )
	)
);

theWholePicture = nw[Outline Box( 1 )] << get picture;

theWholePicture << save image( "$TEMP/myPicture.jpg,", "jpg" );

nw << close window;

theSavedImage = New Image( "$TEMP/myPicture.jpg," );

theNW = New Window( "Final Picture", theSavedImage );

您可以使用以下方式设置图像大小

img << Set Size( {600, 600} );

请参阅脚本索引，了解可与 New Image 一起使用的消息

回复：打开 4 张 JPEG 并将其添加到 2x2 窗口中

我会像 Jim 展示的那样使用 Lineup 框，因为我认为这是最简单的选项。另一个选项（更复杂）是使用 Graph Box 并向其中添加图像

Names Default To Here(1);

image1 = New Image("$SAMPLE_IMAGES/windmap.png");
image2 = New Image("$SAMPLE_IMAGES/black rhino footprint.jpg");
image3 = New Image("$SAMPLE_IMAGES/tile.jpg");
image4 = New Image("$SAMPLE_IMAGES/pi.gif");

nw = New Window("View Image",
	gb = Graph Box(
		FrameSize(500, 500),
		X Scale(0, 100),
		Y Scale(0, 100),
		SuppressAxes(1)
	)
);

fb = nw[FrameBox(1)];

fb << Add Image(image(image1), bounds(top(0), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image2), bounds(top(0), Left(50), bottom(50), Right(100)));
fb << Add Image(image(image3), bounds(top(100), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image4), bounds(top(100), Left(50), bottom(50), Right(100)));

img = fb << get picture;
img << save image("$TEMP/pic.png", "png");
nw << close window;

至少可以从这篇文章“合并/拼接图像”中找到另一种技术