752017_ko-KR

liliconcom

4개의 JPEG를 열고 2x2 창에 추가

안녕,

JMP에서 JPEG 4개를 열고 2x2 창에 배치하는 스크립트를 어떻게 작성합니까? 창의 크기를 특정 크기로 지정하고 싶습니다. 그런 다음 창을 JPEG로 저장하고 싶습니다.

어떤 도움이라도 감사합니다! 감사해요!

자동화 및 스크립팅윈도우Re: JPEG 4개를 열고 2x2 창에 추가하세요.

다음은 질문을 처리하는 한 가지 방법의 간단한 예입니다.

Names Default To Here( 1 );

image1 = New Image( "$SAMPLE_IMAGES/windmap.png" );
image2 = New Image( "$SAMPLE_IMAGES/black rhino footprint.jpg" );
image3 = New Image( "$SAMPLE_IMAGES/tile.jpg" );
image4 = New Image( "$SAMPLE_IMAGES/pi.gif" );

nw = New Window( "Pictures",
	Outline Box( "The Pictures",
		Lineup Box( N Col( 2 ), image1, image2, image3, image4 )
	)
);

theWholePicture = nw[Outline Box( 1 )] << get picture;

theWholePicture << save image( "$TEMP/myPicture.jpg,", "jpg" );

nw << close window;

theSavedImage = New Image( "$TEMP/myPicture.jpg," );

theNW = New Window( "Final Picture", theSavedImage );

다음을 사용하여 이미지 크기를 설정할 수 있습니다.

img << Set Size( {600, 600} );

새 이미지와 함께 사용할 수 있는 메시지는 스크립팅 인덱스를 참조하세요.

Re: JPEG 4개를 열고 2x2 창에 추가하세요.

나는 Jim이 보여준 것처럼 라인업 상자를 사용하겠습니다. 그것이 가장 간단한 옵션이라고 생각하기 때문입니다. (더 복잡한) 또 다른 옵션은 그래프 상자를 사용하여 이미지를 추가하는 것입니다.

Names Default To Here(1);

image1 = New Image("$SAMPLE_IMAGES/windmap.png");
image2 = New Image("$SAMPLE_IMAGES/black rhino footprint.jpg");
image3 = New Image("$SAMPLE_IMAGES/tile.jpg");
image4 = New Image("$SAMPLE_IMAGES/pi.gif");

nw = New Window("View Image",
	gb = Graph Box(
		FrameSize(500, 500),
		X Scale(0, 100),
		Y Scale(0, 100),
		SuppressAxes(1)
	)
);

fb = nw[FrameBox(1)];

fb << Add Image(image(image1), bounds(top(0), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image2), bounds(top(0), Left(50), bottom(50), Right(100)));
fb << Add Image(image(image3), bounds(top(100), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image4), bounds(top(100), Left(50), bottom(50), Right(100)));

img = fb << get picture;
img << save image("$TEMP/pic.png", "png");
nw << close window;

이 게시물에서 이미지 병합/연결 에서 최소한 하나 이상의 기술을 찾을 수 있습니다.