752017_ja-JP

liliconcom

4つのJPEGを開いて2x2ウィンドウに追加します

こんにちは、

JMP で 4 つの jpeg を開いて 2x2 ウィンドウに配置するスクリプトを作成するにはどうすればよいでしょうか。ウィンドウのサイズを特定のサイズに指定し、ウィンドウを jpeg に保存したいと思います。

どのような助けでも大歓迎です！ ありがとう！

自動化とスクリプトウィンドウズRe: 4 つの JPEG を開いて 2x2 ウィンドウに追加する

これは質問に対処する方法の1つの簡単な例です

Names Default To Here( 1 );

image1 = New Image( "$SAMPLE_IMAGES/windmap.png" );
image2 = New Image( "$SAMPLE_IMAGES/black rhino footprint.jpg" );
image3 = New Image( "$SAMPLE_IMAGES/tile.jpg" );
image4 = New Image( "$SAMPLE_IMAGES/pi.gif" );

nw = New Window( "Pictures",
	Outline Box( "The Pictures",
		Lineup Box( N Col( 2 ), image1, image2, image3, image4 )
	)
);

theWholePicture = nw[Outline Box( 1 )] << get picture;

theWholePicture << save image( "$TEMP/myPicture.jpg,", "jpg" );

nw << close window;

theSavedImage = New Image( "$TEMP/myPicture.jpg," );

theNW = New Window( "Final Picture", theSavedImage );

画像のサイズは以下を使用して設定できます。

img << Set Size( {600, 600} );

新しいイメージで使用できるメッセージについては、スクリプトインデックスを参照してください。

Re: 4 つの JPEG を開いて 2x2 ウィンドウに追加する

私はジムが示したように、ラインアップボックスを選択します。これが最もシンプルなオプションだと思います。もう1つのオプション（より複雑）は、グラフボックスを使用して画像を追加することです。

Names Default To Here(1);

image1 = New Image("$SAMPLE_IMAGES/windmap.png");
image2 = New Image("$SAMPLE_IMAGES/black rhino footprint.jpg");
image3 = New Image("$SAMPLE_IMAGES/tile.jpg");
image4 = New Image("$SAMPLE_IMAGES/pi.gif");

nw = New Window("View Image",
	gb = Graph Box(
		FrameSize(500, 500),
		X Scale(0, 100),
		Y Scale(0, 100),
		SuppressAxes(1)
	)
);

fb = nw[FrameBox(1)];

fb << Add Image(image(image1), bounds(top(0), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image2), bounds(top(0), Left(50), bottom(50), Right(100)));
fb << Add Image(image(image3), bounds(top(100), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image4), bounds(top(100), Left(50), bottom(50), Right(100)));

img = fb << get picture;
img << save image("$TEMP/pic.png", "png");
nw << close window;

この投稿から、少なくとももう1つのテクニックが見つかります。画像の結合/ステッチ