752017_it-IT

liliconcom

Apri e aggiungi 4 JPEG in una finestra 2x2

CIAO,

Come posso scrivere uno script per aprire 4 jpeg in JMP e quindi inserirli in una finestra 2x2? Vorrei specificare che la dimensione della finestra sia una certa dimensione. Quindi vorrei salvare la finestra in un jpeg.

Qualsiasi aiuto è apprezzato! Grazie!

Automazione e scriptingfinestreRi: Apri e aggiungi 4 JPEG in una finestra 2x2

Ecco un semplice esempio di un modo per gestire la domanda

Names Default To Here( 1 );

image1 = New Image( "$SAMPLE_IMAGES/windmap.png" );
image2 = New Image( "$SAMPLE_IMAGES/black rhino footprint.jpg" );
image3 = New Image( "$SAMPLE_IMAGES/tile.jpg" );
image4 = New Image( "$SAMPLE_IMAGES/pi.gif" );

nw = New Window( "Pictures",
	Outline Box( "The Pictures",
		Lineup Box( N Col( 2 ), image1, image2, image3, image4 )
	)
);

theWholePicture = nw[Outline Box( 1 )] << get picture;

theWholePicture << save image( "$TEMP/myPicture.jpg,", "jpg" );

nw << close window;

theSavedImage = New Image( "$TEMP/myPicture.jpg," );

theNW = New Window( "Final Picture", theSavedImage );

È possibile impostare le dimensioni delle immagini utilizzando

img << Set Size( {600, 600} );

Vedere l'Indice degli script per i messaggi che possono essere utilizzati con Nuova immagine

Ri: Apri e aggiungi 4 JPEG in una finestra 2x2

Sceglierei la casella Lineup come ha mostrato Jim poiché penso che sia l'opzione più semplice. Un'altra opzione (più complicata) è utilizzare la casella grafico e aggiungervi immagini

Names Default To Here(1);

image1 = New Image("$SAMPLE_IMAGES/windmap.png");
image2 = New Image("$SAMPLE_IMAGES/black rhino footprint.jpg");
image3 = New Image("$SAMPLE_IMAGES/tile.jpg");
image4 = New Image("$SAMPLE_IMAGES/pi.gif");

nw = New Window("View Image",
	gb = Graph Box(
		FrameSize(500, 500),
		X Scale(0, 100),
		Y Scale(0, 100),
		SuppressAxes(1)
	)
);

fb = nw[FrameBox(1)];

fb << Add Image(image(image1), bounds(top(0), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image2), bounds(top(0), Left(50), bottom(50), Right(100)));
fb << Add Image(image(image3), bounds(top(100), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image4), bounds(top(100), Left(50), bottom(50), Right(100)));

img = fb << get picture;
img << save image("$TEMP/pic.png", "png");
nw << close window;

Almeno un'altra tecnica può essere trovata da questo post Unione/unione di immagini