752017_de-DE

liliconcom

Öffnen und fügen Sie 4 JPEGs in ein 2x2-Fenster ein

Hallo,

Wie schreibe ich ein Skript, um 4 JPEGs in JMP zu öffnen und sie dann in ein 2x2-Fenster zu platzieren? Ich möchte die Größe des Fensters auf eine bestimmte Größe festlegen. Dann möchte ich das Fenster als JPEG speichern.

Jede Hilfe ist willkommen! Danke!

Automatisierung und SkriptingWindowsBetreff: Öffnen und fügen Sie 4 JPEGs in ein 2x2-Fenster ein

Hier ist ein einfaches Beispiel für eine Möglichkeit, mit der Frage umzugehen

Names Default To Here( 1 );

image1 = New Image( "$SAMPLE_IMAGES/windmap.png" );
image2 = New Image( "$SAMPLE_IMAGES/black rhino footprint.jpg" );
image3 = New Image( "$SAMPLE_IMAGES/tile.jpg" );
image4 = New Image( "$SAMPLE_IMAGES/pi.gif" );

nw = New Window( "Pictures",
	Outline Box( "The Pictures",
		Lineup Box( N Col( 2 ), image1, image2, image3, image4 )
	)
);

theWholePicture = nw[Outline Box( 1 )] << get picture;

theWholePicture << save image( "$TEMP/myPicture.jpg,", "jpg" );

nw << close window;

theSavedImage = New Image( "$TEMP/myPicture.jpg," );

theNW = New Window( "Final Picture", theSavedImage );

Sie können die Bildgrößen festlegen mit

img << Set Size( {600, 600} );

Im Scripting Index finden Sie die Nachrichten, die mit New Image verwendet werden können.

Betreff: Öffnen und fügen Sie 4 JPEGs in ein 2x2-Fenster ein

Ich würde mich für die Lineup-Box entscheiden, wie Jim sie gezeigt hat, da ich denke, dass dies die einfachste Option ist. Eine andere (kompliziertere) Option ist die Verwendung der Graph Box und das Hinzufügen von Bildern.

Names Default To Here(1);

image1 = New Image("$SAMPLE_IMAGES/windmap.png");
image2 = New Image("$SAMPLE_IMAGES/black rhino footprint.jpg");
image3 = New Image("$SAMPLE_IMAGES/tile.jpg");
image4 = New Image("$SAMPLE_IMAGES/pi.gif");

nw = New Window("View Image",
	gb = Graph Box(
		FrameSize(500, 500),
		X Scale(0, 100),
		Y Scale(0, 100),
		SuppressAxes(1)
	)
);

fb = nw[FrameBox(1)];

fb << Add Image(image(image1), bounds(top(0), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image2), bounds(top(0), Left(50), bottom(50), Right(100)));
fb << Add Image(image(image3), bounds(top(100), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image4), bounds(top(100), Left(50), bottom(50), Right(100)));

img = fb << get picture;
img << save image("$TEMP/pic.png", "png");
nw << close window;

Mindestens eine weitere Technik finden Sie in diesem Beitrag Zusammenfügen/Stitchen von Bildern