752017_fr-FR

liliconcom

Ouvrez et ajoutez 4 JPEG dans une fenêtre 2x2

Salut,

Comment écrire un script pour ouvrir 4 jpeg dans JMP puis les placer dans une fenêtre 2x2 ? Je voudrais spécifier la taille de la fenêtre pour qu'elle soit d'une certaine taille. Ensuite, je voudrais enregistrer la fenêtre au format JPEG.

Toute aide est appréciée ! Merci!

Automatisation et scriptsles fenêtresRe : Ouvrir et ajouter 4 JPEG dans une fenêtre 2x2

Voici un exemple simple d'une façon de traiter la question

Names Default To Here( 1 );

image1 = New Image( "$SAMPLE_IMAGES/windmap.png" );
image2 = New Image( "$SAMPLE_IMAGES/black rhino footprint.jpg" );
image3 = New Image( "$SAMPLE_IMAGES/tile.jpg" );
image4 = New Image( "$SAMPLE_IMAGES/pi.gif" );

nw = New Window( "Pictures",
	Outline Box( "The Pictures",
		Lineup Box( N Col( 2 ), image1, image2, image3, image4 )
	)
);

theWholePicture = nw[Outline Box( 1 )] << get picture;

theWholePicture << save image( "$TEMP/myPicture.jpg,", "jpg" );

nw << close window;

theSavedImage = New Image( "$TEMP/myPicture.jpg," );

theNW = New Window( "Final Picture", theSavedImage );

Vous pouvez définir la taille des images en utilisant

img << Set Size( {600, 600} );

Voir l'index des scripts pour les messages pouvant être utilisés avec New Image.

Re : Ouvrir et ajouter 4 JPEG dans une fenêtre 2x2

J'opterais pour la boîte Lineup comme Jim l'a montré car je pense que c'est l'option la plus simple. Une autre option (plus compliquée) consiste à utiliser Graph Box et à y ajouter des images.

Names Default To Here(1);

image1 = New Image("$SAMPLE_IMAGES/windmap.png");
image2 = New Image("$SAMPLE_IMAGES/black rhino footprint.jpg");
image3 = New Image("$SAMPLE_IMAGES/tile.jpg");
image4 = New Image("$SAMPLE_IMAGES/pi.gif");

nw = New Window("View Image",
	gb = Graph Box(
		FrameSize(500, 500),
		X Scale(0, 100),
		Y Scale(0, 100),
		SuppressAxes(1)
	)
);

fb = nw[FrameBox(1)];

fb << Add Image(image(image1), bounds(top(0), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image2), bounds(top(0), Left(50), bottom(50), Right(100)));
fb << Add Image(image(image3), bounds(top(100), Left(0), bottom(50), Right(50)));
fb << Add Image(image(image4), bounds(top(100), Left(50), bottom(50), Right(100)));

img = fb << get picture;
img << save image("$TEMP/pic.png", "png");
nw << close window;

Au moins une autre technique peut être trouvée dans cet article. Fusion/assemblage d'images