750730_zh-TW

liliconcom

標記站點到站點的變化

你好，

有沒有辦法標記測試參數與站點之間的差異？

我知道要查看變異性圖表，但我正在探索使用 jsl 進行統計識別和實施的方法，這將使分析更快。

我們的想法是建立一個列來指示測試參數是否存在站點間差異。有什麼建議麼？

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

謝謝，

進階統計建模自動化和腳本編寫數據探索和視覺化回覆：標記站點到站點的變化

您是否嘗試過反應篩檢（ https://www.youtube.com/watch?v=IoMYIGPUDKk），https://www.jmp.com/support/help/en/17.2/index.shtml#page/jmp /response -篩選.shtml# ？

回覆：標記站點到站點的變化

不確定我是否完全理解您想要的內容，但您可以使用內建的 Oneway 平台並提取平均值比較結果嗎？像這樣的東西：

names default to here(1);
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
dt << New Column( "PM_L1_Modified", set formula( If( :SITE == 1, :PM_L1 + 1, :PM_L1 ) ) );
cols1 = dt << get column names( Continuous );

For( j = 1, j <= n items( cols1 ), j++, 
	ow = dt << Oneway(
		Y( cols1[j] ),
		X( :SITE ),
		All Pairs( 1 ),
		Comparison Circles( 0 ),
		Invisible
	);

	level1 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "Level" )]) << get();
	level2 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "- Level" )]) << get();
	pval = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "p-Value" )]) << get();

	ow << close window();
	p_count = 0;
	For( i = 1, i <= N Items( pval ), i++,
		If( pval[i] < 0.05,
			text = Substitute( "For __col__, sites __l1__ and __l2__ are statistically different",
				Expr( __col__ ), cols1[j],
				Expr( __l1__ ), level1[i],
				Expr( __l2__ ), level2[i]
			);
			Print( text );
			p_count++;
			// Do stuff here
		)
	);
	if( p_count == 0, print( char( cols1[j] ) || ": no statistically different sites" ) );
);

然後你會得到這樣的輸出：

...
"PM_L1: no statistically different sites"
"P1: no statistically different sites"
"M1: no statistically different sites"
"For PM_L1_Modified, sites 1 and 5 are statistically different"
"For PM_L1_Modified, sites 1 and 2 are statistically different"
"For PM_L1_Modified, sites 1 and 4 are statistically different"
"For PM_L1_Modified, sites 1 and 3 are statistically different"

我必須建立一個新列，因為半導體能力中的所有參數似乎都不具有站點依賴性！

然後，您可以對發現具有統計顯著差異的參數和網站執行一些有趣的操作。

這是一個非常簡單的解決方案，可以進行最佳化，或者可能有更好的 JMP 內建方法來獲取此資訊。

回覆：標記站點到站點的變化

這就是我正在尋找的。謝謝@matth1