750730_es-ES

liliconcom

Marcar variaciones de sitio a sitio

Hola,

¿Existe alguna forma de marcar los parámetros de prueba con variaciones de un sitio a otro?

Soy consciente de que estoy mirando el gráfico de variabilidad, pero estoy explorando formas de identificarlo estadísticamente e implementarlo usando jsl, lo que agilizaría el análisis.

La idea es crear una columna que indique si el parámetro de prueba tiene variaciones de un sitio a otro. ¿Alguna sugerencia?

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

Gracias,

Modelado estadístico avanzadoAutomatización y secuencias de comandosExploración y visualización de datosRe: Marcar variaciones de sitio a sitio

¿Ha probado la detección de respuestas ( https://www.youtube.com/watch?v=IoMYIGPuDKk ), https://www.jmp.com/support/help/en/17.2/index.shtml#page/jmp/response ? -screening.shtml# ?

Re: Marcar variaciones de sitio a sitio

No estoy seguro de entender exactamente lo que quiere, pero ¿podría utilizar la plataforma Oneway incorporada y extraer los resultados de la comparación de medias? Algo como esto:

names default to here(1);
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
dt << New Column( "PM_L1_Modified", set formula( If( :SITE == 1, :PM_L1 + 1, :PM_L1 ) ) );
cols1 = dt << get column names( Continuous );

For( j = 1, j <= n items( cols1 ), j++, 
	ow = dt << Oneway(
		Y( cols1[j] ),
		X( :SITE ),
		All Pairs( 1 ),
		Comparison Circles( 0 ),
		Invisible
	);

	level1 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "Level" )]) << get();
	level2 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "- Level" )]) << get();
	pval = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "p-Value" )]) << get();

	ow << close window();
	p_count = 0;
	For( i = 1, i <= N Items( pval ), i++,
		If( pval[i] < 0.05,
			text = Substitute( "For __col__, sites __l1__ and __l2__ are statistically different",
				Expr( __col__ ), cols1[j],
				Expr( __l1__ ), level1[i],
				Expr( __l2__ ), level2[i]
			);
			Print( text );
			p_count++;
			// Do stuff here
		)
	);
	if( p_count == 0, print( char( cols1[j] ) || ": no statistically different sites" ) );
);

Entonces obtendrías un resultado como este:

...
"PM_L1: no statistically different sites"
"P1: no statistically different sites"
"M1: no statistically different sites"
"For PM_L1_Modified, sites 1 and 5 are statistically different"
"For PM_L1_Modified, sites 1 and 2 are statistically different"
"For PM_L1_Modified, sites 1 and 4 are statistically different"
"For PM_L1_Modified, sites 1 and 3 are statistically different"

¡Tuve que crear una nueva columna porque ninguno de los parámetros en Semiconductor Capability parece tener una dependencia del SITIO!

Luego puede hacer algo interesante con los parámetros y los sitios que tienen diferencias estadísticamente significativas.

Esta es una solución muy simple y podría optimizarse, o puede haber una mejor forma integrada de JMP para obtener esta información.

Re: Marcar variaciones de un sitio a otro

Esto es lo que estoy buscando. Gracias @matth1