750730_zh-CN

liliconcom

标记站点间差异

你好，

有没有办法标记站点间差异的测试参数？

我知道要看变异性图表，但我正在探索统计识别和使用 jsl 实现的方法，这将使分析速度更快。

我们的想法是创建一个列来指示测试参数是否存在站点间差异。有什么建议吗？

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

谢谢，

高级统计建模自动化和脚本数据探索与可视化回复：标记站点间差异

您是否尝试过响应筛选（ https://www.youtube.com/watch?v=IoMYIGPuDKk），https://www.jmp.com/support/help/en/17.2/index.shtml#page/jmp/response-screening.shtml# ？

回复：标记站点间差异

不确定我是否完全理解了您的意思，但是您可以使用内置的 Oneway 平台并提取均值比较结果吗？像这样：

names default to here(1);
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
dt << New Column( "PM_L1_Modified", set formula( If( :SITE == 1, :PM_L1 + 1, :PM_L1 ) ) );
cols1 = dt << get column names( Continuous );

For( j = 1, j <= n items( cols1 ), j++, 
	ow = dt << Oneway(
		Y( cols1[j] ),
		X( :SITE ),
		All Pairs( 1 ),
		Comparison Circles( 0 ),
		Invisible
	);

	level1 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "Level" )]) << get();
	level2 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "- Level" )]) << get();
	pval = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "p-Value" )]) << get();

	ow << close window();
	p_count = 0;
	For( i = 1, i <= N Items( pval ), i++,
		If( pval[i] < 0.05,
			text = Substitute( "For __col__, sites __l1__ and __l2__ are statistically different",
				Expr( __col__ ), cols1[j],
				Expr( __l1__ ), level1[i],
				Expr( __l2__ ), level2[i]
			);
			Print( text );
			p_count++;
			// Do stuff here
		)
	);
	if( p_count == 0, print( char( cols1[j] ) || ": no statistically different sites" ) );
);

然后你会得到如下输出：

...
"PM_L1: no statistically different sites"
"P1: no statistically different sites"
"M1: no statistically different sites"
"For PM_L1_Modified, sites 1 and 5 are statistically different"
"For PM_L1_Modified, sites 1 and 2 are statistically different"
"For PM_L1_Modified, sites 1 and 4 are statistically different"
"For PM_L1_Modified, sites 1 and 3 are statistically different"

我必须创建一个新列，因为半导体能力中的任何参数似乎都没有 SITE 依赖性！

然后，您可以对参数和发现具有统计显著差异的站点做一些有趣的事情。

这是一个非常简单的解决方案，可以进行优化，或者可能有更好的 JMP 内置方法来获取此信息。

回复：标记站点间差异

这就是我要找的。谢谢@matth1