750730_ja-JP

liliconcom

サイト間の差異をフラグ付けする

こんにちは、

サイトごとに異なるテストパラメータにフラグを設定する方法はありますか?

変動チャートを見ることは認識していますが、統計的に識別し、jsl を使用して実装して分析を高速化する方法を検討しています。

テストパラメータにサイト間での変動があるかどうかを示す列を作成することが考えられます。何か提案はありますか?

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

ありがとう、

高度な統計モデリング自動化とスクリプトデータの探索と視覚化Re: サイト間の差異のフラグ付け

レスポンス スクリーニング ( https://www.youtube.com/watch?v=IoMYIGPuDKk )、 https://www.jmp.com/support/help/en/17.2/index.shtml#page/jmp/response-screening.shtml#を試しましたか?

Re: サイト間の差異のフラグ付け

正確に何を望んでいるのか分かりませんが、組み込みの Oneway プラットフォームを使用して、平均比較結果を抽出できますか? 次のようになります:

names default to here(1);
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
dt << New Column( "PM_L1_Modified", set formula( If( :SITE == 1, :PM_L1 + 1, :PM_L1 ) ) );
cols1 = dt << get column names( Continuous );

For( j = 1, j <= n items( cols1 ), j++, 
	ow = dt << Oneway(
		Y( cols1[j] ),
		X( :SITE ),
		All Pairs( 1 ),
		Comparison Circles( 0 ),
		Invisible
	);

	level1 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "Level" )]) << get();
	level2 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "- Level" )]) << get();
	pval = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "p-Value" )]) << get();

	ow << close window();
	p_count = 0;
	For( i = 1, i <= N Items( pval ), i++,
		If( pval[i] < 0.05,
			text = Substitute( "For __col__, sites __l1__ and __l2__ are statistically different",
				Expr( __col__ ), cols1[j],
				Expr( __l1__ ), level1[i],
				Expr( __l2__ ), level2[i]
			);
			Print( text );
			p_count++;
			// Do stuff here
		)
	);
	if( p_count == 0, print( char( cols1[j] ) || ": no statistically different sites" ) );
);

すると、次のような出力が得られます。

...
"PM_L1: no statistically different sites"
"P1: no statistically different sites"
"M1: no statistically different sites"
"For PM_L1_Modified, sites 1 and 5 are statistically different"
"For PM_L1_Modified, sites 1 and 2 are statistically different"
"For PM_L1_Modified, sites 1 and 4 are statistically different"
"For PM_L1_Modified, sites 1 and 3 are statistically different"

Semiconductor Capability のどのパラメータも SITE に依存していないようなので、新しい列を作成する必要がありました。

その後、統計的に有意な差があることが判明したパラメータとサイトを使用して、興味深い操作を行うことができます。

これは非常にシンプルな解決策であり、最適化できる可能性があります。あるいは、この情報を取得するためのより優れた JMP 組み込みの方法があるかもしれません。

Re: サイト間の差異のフラグ付け

これこそ私が探していたものです。ありがとう@matth1