750730_de-DE

liliconcom

Markierung von Abweichungen von Site zu Site

Hallo,

Gibt es eine Möglichkeit, Testparameter mit Abweichungen von Standort zu Standort zu kennzeichnen?

Ich bin mir bewusst, dass ich mir das Variabilitätsdiagramm ansehe, erkunde aber Möglichkeiten zur statistischen Ermittlung und Implementierung mithilfe von JSL, wodurch die Analyse schneller erfolgen würde.

Die Idee ist, eine Spalte zu erstellen, die angibt, ob der Testparameter von Standort zu Standort variiert. Irgendwelche Vorschläge?

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

Danke,

Erweiterte statistische ModellierungAutomatisierung und SkriptingDatenexploration und -visualisierungBetreff: Markieren von Abweichungen zwischen Sites

Haben Sie Response Screening ( https://www.youtube.com/watch?v=IoMYIGPuDKk ), https://www.jmp.com/support/help/en/17.2/index.shtml#page/jmp/response-screening.shtml# ausprobiert?

Betreff: Markieren von Abweichungen zwischen Sites

Ich bin nicht sicher, ob ich genau verstehe, was Sie wollen, aber Sie könnten die integrierte Oneway-Plattform verwenden und die Mittelwertvergleichsergebnisse extrahieren? So etwas wie das hier:

names default to here(1);
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
dt << New Column( "PM_L1_Modified", set formula( If( :SITE == 1, :PM_L1 + 1, :PM_L1 ) ) );
cols1 = dt << get column names( Continuous );

For( j = 1, j <= n items( cols1 ), j++, 
	ow = dt << Oneway(
		Y( cols1[j] ),
		X( :SITE ),
		All Pairs( 1 ),
		Comparison Circles( 0 ),
		Invisible
	);

	level1 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "Level" )]) << get();
	level2 = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "- Level" )]) << get();
	pval = (Report( ow )["Means Comparisons", "Comparisons for all pairs using Tukey-Kramer HSD", "Ordered Differences Report",
	String Col Box( "p-Value" )]) << get();

	ow << close window();
	p_count = 0;
	For( i = 1, i <= N Items( pval ), i++,
		If( pval[i] < 0.05,
			text = Substitute( "For __col__, sites __l1__ and __l2__ are statistically different",
				Expr( __col__ ), cols1[j],
				Expr( __l1__ ), level1[i],
				Expr( __l2__ ), level2[i]
			);
			Print( text );
			p_count++;
			// Do stuff here
		)
	);
	if( p_count == 0, print( char( cols1[j] ) || ": no statistically different sites" ) );
);

Dann würden Sie eine Ausgabe wie diese erhalten:

...
"PM_L1: no statistically different sites"
"P1: no statistically different sites"
"M1: no statistically different sites"
"For PM_L1_Modified, sites 1 and 5 are statistically different"
"For PM_L1_Modified, sites 1 and 2 are statistically different"
"For PM_L1_Modified, sites 1 and 4 are statistically different"
"For PM_L1_Modified, sites 1 and 3 are statistically different"

Ich musste eine neue Spalte erstellen, da keiner der Parameter in der Halbleiterfähigkeit eine SITE-Abhängigkeit zu haben scheint!

Sie können dann mit den Parametern und Sites, bei denen sich statistisch signifikante Unterschiede ergeben, etwas Interessantes tun.

Dies ist eine sehr einfache Lösung und könnte optimiert werden, oder es gibt möglicherweise eine bessere integrierte JMP-Methode, um diese Informationen abzurufen.

Betreff: Markieren von Abweichungen zwischen Sites

Das ist es, wonach ich suche. Danke @matth1