750659_zh-TW

liliconcom

JMP Clinical _ 基於 CTCAE 等級的不良事件偵測

是什麼激發了這個願望清單請求？

在臨床數據監測時，臨床醫生會收集許多實驗室結果。檢查不良事件 (AE) 是否已根據基於實驗室值的 CTCAE 等級正確報告，交叉檢查 AE 和實驗室是一項非常耗時的任務。相反，有些情況下報告了 AE，但相關實驗室值要么未報告，要么正常。因此，擁有一份可以在臨床數據監測過程中交叉檢查這些事情的報告將非常有幫助。

請描述您希望看到的新的或改進的功能或解決方案。

與上面相同

如果提供此新功能，對您和/或其他使用者有何價值？

節省清洗資料監控時間，確保資料完整性

這是外部客戶的請求嗎？

不，這是我的行業經驗的需要

是否有具有我們應該注意的此功能或解決方案的競爭軟體包？

我不知道。當我在製藥公司時，這是一項非常SAS編程、高度手工審查的任務。

這是否會影響客戶的續約、擴展或採用？

內容組織回覆：JMP Clinical _ 基於 CTCAE 等級的不良事件偵測

@andreacoombs1 ，我之前已經看到過這個請求。我們創建了一個粗略的腳本/JMP 臨床報告來執行類似的操作。我認為 BMS 也要求提供這份報告。

 /*
 Authors:
	Andrea Coombs and Chris Kirchberg, JMP Statistical Discovery, LLC
 
 Subject:
	CTC Grade Adjudication Report based on DM, AE and LB domain data
	ADaM version has yet to be confirmed
 
 Summary:

 
 Original Date of Creation:
	May 5th, 2023
 
 Original JMP Clinical Target Version:
	17.2
 
  Updated:
	May 5th, 2023

Current Report Version:
	1.1
 
 Current JMP Clinical Target Version:
	17.2
*/

Names Default To Here( 1 );

/*
	Define the report to the report selector with the following attributes:
	label, reportSelectorTab, drillDown, cdiscClass, icon and documentation
*/
processNS:label = "CTC Grade Adjudication";
processNS:reportSelectorTab = 1;
processNS:drillDown = 0;
processNS:cdiscClass = locale:get( "OtherEvents_Text" );
processNS:icon = "/install/clinical/documentation/icons/clinical/bar_chart_16p.png"; //Location/path for custom icon
processNS:documentation = jg:getReportHelpPath(); //Place holder for location of documentation/Help

//This will be called at report selection time to see if the report is supported
//The objRefNS object does not exist yet
//Definging required domains and variables
processNS:requirements = ["AE" => {{"USUBJID", "AEBODSYS", "AETOXGR", "AESTDY", "AEENDY", "AETERM"}, {"_ALL_"}}, "LB" => {{"USUBJID", "LBTEST",
"LBSTRESN", "LBDY"}, {"_ALL_"}}];

//Function to run report when adding report to review template with main code inside
processNS:runReport = Function( {},
	{Default Local}, 
	
	//Required to use loadData,....
	Include( Convert File Path( "$CLINICAL_HOME/JSLFiles/DataPrep.JSL", absolute, windows ) );

	//Get/load AE and LBdomain and set a reference to it.
	
	objRefNS:aeDT = loadData( "AE" );
	objRefNS:lbDT = loadData( "LB" );	

// Clear row selection
	objRefNS:aeDT << Clear Select;

// Subset data table
	// → Data Table( "Subset of ae" )
	objRefNS:subAEDT = objRefNS:aeDT << Select Where( :AEBODSYS == "BLOOD AND LYMPHATIC SYSTEM DISORDERS" | :AEBODSYS == "INVESTIGATIONS" ) <<
	Subset( Invisible, Selected Rows( 1 ), Selected columns only( 0 ) );


// Close Data Table: ae
	Close( objRefNS:aeDT, NoSave );

// Subset data table
	// → Data Table( "Subset of lb" )
	objRefNS:subLBDT = objRefNS:lbDT << Select Where( :LBTEST == "Hemoglobin" | :LBTEST == "Platelet" ) << Subset(
		Invisible,
		Selected Rows( 1 ),
		Selected columns only( 0 )
	);

// Close Data Table: lbx
	Close( objRefNS:lbDT, NoSave );
	
// Split data table
	// → Data Table( "Split LB" )
	objRefNS:splitLBDT = objRefNS:subLBDT << Split(
		Split By( :LBTEST ),
		Split( :LBSTRESN ),
		Group( :USUBJID, :LBDY ),
		Output Table( "Split LB" ),
		Remaining Columns( Drop All ),
		Sort by Column Property,
		Invisible
	);
// Close Data Table: Subset of lb
	Close( objRefNS:subLBDT, NoSave );

// New column: CTC Grade
	objRefNS:splitLBDT << New Column( "CTC Grade",
		Character,
		"Nominal",
		Formula(
			If( !Is Missing( :Hemoglobin ) & !Is Missing( :Platelet ),
				If(
					:Hemoglobin > 17 | :Platelet > 600, 3,
					15 < :Hemoglobin <= 17 | 400 < :Platelet <= 600, 2,
					1
				),
				If( !Is Missing( :Hemoglobin ),
					If(
						:Hemoglobin > 17, 3,
						15 < :Hemoglobin <= 17, 2,
						1
					),
					If(
						:Platelet > 600, 3,
						400 < :Platelet <= 600, 2,
						1
					)
				)
			)
		)
	);


// Change column name: AETOXGR → CTC Grade
	objRefNS:subAEDT:AETOXGR << Set Name( "CTC Grade" );


// Concatenate tables
	// → Data Table( "CTC Grade Judication" )
	objRefNS:ctcGrdAdDT = objRefNS:subAEDT << Concatenate( Invisible, objRefNS:splitLBDT, Output Table( "CTC Grade Adjudication" ) );

// Close Data Table: split of subset of lb
	Close( objRefNS:splitLBDT, NoSave );
	
// Close Data Table: subset of ae
	Close( objRefNS:subAEDT, NoSave );
	
//Link demography data to CTC Grade Adjudication table
	report:linkAnalysisTableToADSLTable( objRefNS:ctcGrdAdDT );

	processNS:setReportOutput(
		objRefNS:resultsContainer = V List Box(
				
			objRefNS:outBox1 = Outline Box( "Results", 
			// Report snapshot: CTC Grade Adjudication - Graph Builder
				objRefNS:gb1 = objRefNS:ctcGrdAdDT << Graph Builder(
					Size( 518, 714 ),
					Show Control Panel( 0 ),
					Variables(
						X( :AESTDY ),
						X( :AEENDY, Position( 1 ) ),
						X( :LBDY, Position( 1 ) ),
						Y( :AETERM ),
						Y( :Hemoglobin ),
						Y( :Platelet ),
						Color( :CTC Grade )
					),
					Elements( Position( 1, 1 ), Points( X( 1 ), X( 2 ), Y, Legend( 23 ) ) ),
					Elements( Position( 1, 2 ), Line( X( 3 ), Y, Legend( 27 ) ), Points( X( 3 ), Y, Legend( 29 ) ) ),
					Elements( Position( 1, 3 ), Line( X( 3 ), Y, Legend( 26 ) ), Points( X( 3 ), Y, Legend( 28 ) ) ), 
/*					Local Data Filter(
						Add Filter( columns( :USUBJID ), Where( :USUBJID == "21031" ), Display( :USUBJID, N Items( 15 ), Find( Set Text( "" ) ) ) )
					),*/
					SendToReport(
						Dispatch(
							{},
							"400",
							ScaleBox,
							{Legend Model(
								23,
								Properties( 0, {Line Color( 4 )}, Item ID( "1", 1 ) ),
								Properties( 1, {Line Color( 9 )}, Item ID( "2", 1 ) ),
								Properties( 2, {Marker( "Filled Right Triangle" )}, Item ID( "AESTDY", 1 ) ),
								Properties( 3, {Marker( "Filled Left Triangle" )}, Item ID( "AEENDY", 1 ) ),
								Properties( -1, {Line Color( 3 )}, Item ID( "3", 1 ) )
							), Legend Model(
								27,
								Properties( 0, {Line Color( 32 )}, Item ID( "1", 1 ) ),
								Properties( 1, {Line Color( 32 )}, Item ID( "2", 1 ) ),
								Properties( -1, {Line Color( 32 )}, Item ID( "3", 1 ) )
							), Legend Model(
								29,
								Base( 0, 0, 0, Item ID( "1", 1 ) ),
								Base( 1, 0, 1, Item ID( "2", 1 ) ),
								Properties( 0, {Line Color( 4 )}, Item ID( "1", 1 ) ),
								Properties( 1, {Line Color( 9 )}, Item ID( "2", 1 ) ),
								Base( -1, 0, 2, Item ID( "3", 1 ) ),
								Properties( -1, {Line Color( 3 )}, Item ID( "3", 1 ) )
							), Legend Model(
								26,
								Base( 0, 0, 0, Item ID( "1", 1 ) ),
								Base( 1, 0, 1, Item ID( "2", 1 ) ),
								Properties( 0, {Line Color( 32 )}, Item ID( "1", 1 ) ),
								Properties( 1, {Line Color( 32 )}, Item ID( "2", 1 ) ),
								Base( -1, 0, 2, Item ID( "3", 1 ) ),
								Properties( -1, {Line Color( 32 )}, Item ID( "3", 1 ) )
							), Legend Model(
								28,
								Base( 0, 0, 0, Item ID( "1", 1 ) ),
								Base( 1, 0, 1, Item ID( "2", 1 ) ),
								Properties( 0, {Line Color( 4 )}, Item ID( "1", 1 ) ),
								Properties( 1, {Line Color( 9 )}, Item ID( "2", 1 ) ),
								Base( -1, 0, 2, Item ID( "3", 1 ) ),
								Properties( -1, {Line Color( 3 )}, Item ID( "3", 1 ) )
							)}
						),
						Dispatch(
							{},
							"400",
							LegendBox,
							{Legend Position( {23, [0, 1, 2, 3], 27, [-1, -1], 29, [-1, -1], 26, [-1, -1], 28, [-1, -1]} )}
						)
					)
				)
			)
		)
	);
	//Display data tables created or used in this report
	processNS:addDataTableReference( "CTC Grade Adjudication Table", "objRefNS:ctcGrdAdDT" );

);

// return code
0;

回覆：JMP Clinical _ 基於 CTCAE 等級的不良事件偵測

哦， @Chris_Kirchberg之前已經請求並開發了這份報告。聽起來不錯。希望這份報告能夠盡快整合。感謝您分享 JSL！

回覆：JMP Clinical _ 基於 CTCAE 等級的不良事件偵測

此功能非常有用，因為它簡化了臨床數據監測流程，這在臨床醫生處理大量實驗室結果時至關重要。確保根據基於實驗室值的 CTCAE 等級準確報告不良事件 (AE) 至關重要，但非常耗時。有時，報告的 AE 沒有相應的實驗室值或正常值，這增加了複雜性。引入可交叉檢查 AE 和實驗室值的報告將節省大量時間並提高臨床試驗的準確性和可靠性。此外，我們的許多客戶目前都採用自訂編碼來管理這些問題，因此開箱即用的解決方案將是有利的。

回覆：JMP Clinical _ 基於 CTCAE 等級的不良事件偵測 - 狀態變更為：已確認回覆：JMP Clinical _ 基於 CTCAE 等級的不良事件偵測

謝謝你的主意！我認為這是一個有趣的想法，可以添加到臨床中。我需要做一些研究，看看確定應該使用哪些 AE 和實驗室測試並將其配對來實現這一通用性是否可行。