How to resize the Graph Builder Panel size when using the Page/arrange in row organization

shampton82

Hey everyone,

I was hoping someone could help me figure out the code to resize the panel size in graph builder.

 

This is from the big class data set:

 

If I wanted to set the size to be much bigger using JSL (the auto fit window is turned off) to something like this:

 

how would I accomplish that?

 

The reason I need this functionality is that currently if you use a filter for the "Page" column then the graphs get smaller and smaller the more levels you have.  When you have a ton of levels it can get so small you can't even see the handle to resize the Panels.  So I have to select some levels, resize, select some more levels, resize, etc.....Very annoying and removes some of the awesomeness of this new Graph Builder ability.  On the flip side, if you have a ton of levels sized right as you remove levels in the filter the charts get bigger and bigger.

 

So I want to be able to have an input box through JSL where I can change the sizing easily and quickly.

 

Hope this make sense and thanks for any ideas!

 

Steve

 

 

jthi

It has to be triggered somehow, most likely by some control or handler (in that example, you can for example call the same function before filter handler is applied with something like f(0))

View more...

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("",
	gb = dt << Graph Builder(
		Size(569, 357),
		Show Control Panel(0),
		Replicate Linked Page Axes(0),
		Fit to Window("Off"),
		Variables(X(:height), Y(:weight), Page(:age, Levels per Row(3))),
		Elements(Points(X, Y, Legend(91)), Smoother(X, Y, Legend(92)))
	)
);

ldf = gb << Local Data Filter(
	Add Filter(
		columns(:age),
		Where(:age == {12, 13, 14, 15, 16, 17}),
		Display(:age, N Items(6))
	)
);


change_frame_size = Function({a}, 
	fbs = Report(gb) << XPath("//FrameBox");
	fbs << Frame Size(500, 500);
);

change_frame_size(0);

rs = ldf << Make Filter Change Handler(change_frame_size);

Below is the most simple case where it is triggered by button press

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("",
	V List Box(
		Button Box("Update Frames",
			(Report(window:gb) << XPath("//FrameBox")) << Frame Size(300, 300);
		),
		window:gb = dt << Graph Builder(
			Size(569, 357),
			Show Control Panel(0),
			Replicate Linked Page Axes(0),
			Fit to Window("Off"),
			Variables(X(:height), Y(:weight), Page(:age, Levels per Row(3))),
			Elements(Points(X, Y, Legend(91)), Smoother(X, Y, Legend(92))),
			Local Data Filter(
				Add Filter(
					columns(:age),
					Where(:age == {12, 13, 14, 15, 16, 17}),
					Display(:age, N Items(6))
				)
			)
		)
	)
);