如何將NumberEditBox中的使用者輸入限制為7位數？ECN = 0,
Text Box( "System ECN:" ),
S1 = Number Edit Box(ECN, <<SET property=""></SET>
The user shouldn't be able to enter more than 7 digits. For example: 1234567... the user shouldn't be able to enter 8.
How did achieve this?
Any help is appreciated.
<LINGO-LABS id="lingo-labs-750800" slang="en-US" mode="CREATE"><LINGO-LABEL>數據探索和視覺化</LINGO-LABEL><LINGO-LABEL>視窗</LINGO-LABEL></LINGO-LABS>回覆：如何將 NumberEditBox 中的使用者輸入限制為 7 位數字？此版本要求使用者提交號碼的變更。
Names Default to Here( 1 );
last = eon = 0;
New Window( "Only Seven",
Outline Box( "Enter EON",
Line Up Box( N Col( 2 ),
Text Box( "System EON:" ),
neb = Number Edit Box( eon,
<< Set Integer Only( 1 ),
<< Set Minimum( 0 ),
<< Set Tip( "Enter an integer number with no more than 7 digits"),
<< Set Function( // called when user commits data entry
Function( { self },
new = self << Get;
If( Length( Char( new ) ) > 7,
self << Set( last ),
last = new
);
);
)
)
)
)
);回覆：如何將 NumberEditBox 中的使用者輸入限制為 7 位數字？嗨@PunitPanjwani
這是腳本索引中 set numberchanged() 和 getnumberchanged() 範例的修改版本。我認為這會讓你非常接近你的目標：
Names Default To Here( 1 );
New Window( "Example",
numBox = Number Edit Box(
.,
10,
<< set number changed(
Function( { thisBox, value }, /* put my value into my sibling's display */
if( length( char( value ) ) > 7,
// > 7 digits
thisBox << set( . );
( thisBox << sib ) << settext( "Too many digits" ),
// <= 7 digits
( thisBox << sib ) << settext( char( value ) )
)
)
)
),
Text Box( "" )/* here's the sibling box, waiting to show a message */
);
numBox << get number changed()
回覆：如何將 NumberEditBox 中的使用者輸入限制為 7 位數字？您在哪裡找到此訊息：
<< Set Max Length(7) // Limit the number of digits to 7
我在數位編輯框的協議中沒有看到它。
回覆：如何將 NumberEditBox 中的使用者輸入限制為 7 位數字？謝謝馬克！
我修改了程式碼如下所示，但仍然沒有成功。你認為JMP軟體中它很重要嗎？
Names Default to Here( 1 );
last = eon = 0;
New Window( "Only Seven",
Outline Box( "Enter EON",
Line Up Box( N Col( 2 ),
Text Box( "System EON:" ),
neb = Number Edit Box( eon,
<< Set Integer Only( 1 ),
<< Set Minimum( 0 ),
<< Set Tip( "Enter an integer number with no more than 7 digits")
<< Set Number Changed(
Function( { self, number },
If( Length( Char( number ) ) > 7,
self << Set( last ),
last = number
);
);
),
<< Set Max Length(7) // Limit the number of digits to 7
)
)
)
)回覆：如何將 NumberEditBox 中的使用者輸入限制為 7 位數字？你可以從這個方向開始。
Names Default to Here( 1 );
last = eon = 0;
New Window( "Only Seven",
Outline Box( "Enter EON",
Line Up Box( N Col( 2 ),
Text Box( "System EON:" ),
neb = Number Edit Box( eon,
<< Set Integer Only( 1 ),
<< Set Minimum( 0 ),
<< Set Tip( "Enter an integer number with no more than 7 digits")
<< Set Number Changed(
Function( { self, number },
If( Length( Char( number ) ) > 7,
self << Set( last ),
last = number
);
);
)
)
)
)
)回覆：如何將 NumberEditBox 中的使用者輸入限制為 7 位數字？有不同的方法可以做到這一點，這取決於您希望 UI 的行為方式：
- 如果使用者插入太多數字，則會拋出錯誤訊息
- 如果使用者插入的數字太多，請將值設定為允許的最大數字
- 如果使用者插入太多數字，請將值設為空值（缺失值）
- 如果使用者插入太多數字，請將值設為最後一個「有效」值
- ……
然後，您必須決定何時應更新該值：提交時還是每次數字變更時？
以下是一些選項，可以根據需要進行組合
看更多...
Names Default To Here(1);
nw = New Window("Example",
Lineup Box(N Col(2),
Text Box("Set to max value on COMMIT:"),
Number Edit Box(
.
, 10
, << Set Maximum(9999999)
, << Set Exclude Maximum(0)
, << Set Integer Only(1)
),
Text Box("Set to last COMMITTED value on COMMIT:"),
cb = Context Box(
box:last_val = .;
Number Edit Box(
.
, 10
, << Set Function(function({this},
If((this << get) >= 10000000,
this << set(box:last_val)
,
box:last_val = this << get;
)
))
)
),
Text Box("Throw on COMMIT"),
cb = Context Box(
box:last_val = .;
Number Edit Box(
.
, 10
, << Set Function(function({this},
If((this << get) >= 10000000,
this << set(box:last_val);
Throw("No values longer than 7 digits allowed");
,
box:last_val = this << get;
)
))
)
),
Text Box("Set to last changed value on change and break focus:"),
cb = Context Box(
box:last_val = .;
Number Edit Box(
.
, 10
, << Set Number Changed(function({this, val},
If((val) >= 10000000,
this << set(box:last_val);
box:mb << Set Focus(1); // to break focus from number edit box
,
box:last_val = val;
)
))
),
Unlineup Box(box:mb = Mouse Box());
)
)
);
回覆：如何將 NumberEditBox 中的使用者輸入限制為 7 位數字？謝謝你，馬克！
回覆：如何將 NumberEditBox 中的使用者輸入限制為 7 位數字？謝謝你，賈莫！
