750800_ja-JP

liliconcom

NumberEditBox でユーザー入力を 7 桁に制限するにはどうすればよいですか?

ECN = 0,

Text Box( "System ECN:" ),

S1 = Number Edit Box(ECN, <<SET property=""></SET>

The user shouldn't be able to enter more than 7 digits. For example: 1234567... the user shouldn't be able to enter 8.

How did achieve this?

Any help is appreciated.

<LINGO-LABS id="lingo-labs-750800" slang="en-US" mode="CREATE"><LINGO-LABEL>データの探索と視覚化</LINGO-LABEL><LINGO-LABEL>ウィンドウズ</LINGO-LABEL></LINGO-LABS>Re: NumberEditBox でユーザー入力を 7 桁に制限するにはどうすればよいですか?

ありがとう、マーク！

以下のようにコードを変更しましたが、まだ成功しません。これは JMP ソフトウェアの問題だと思いますか?

Names Default to Here( 1 );

last = eon = 0;

New Window( "Only Seven",
    Outline Box( "Enter EON",
        Line Up Box( N Col( 2 ),
            Text Box( "System EON:" ),
            neb = Number Edit Box( eon,
                << Set Integer Only( 1 ),
                << Set Minimum( 0 ),
                << Set Tip( "Enter an integer number with no more than 7 digits")
                << Set Number Changed(
                    Function( { self, number },
                        If( Length( Char( number ) ) > 7,
                            self << Set( last ),
                            last = number
                        );
                    );
                ),
                << Set Max Length(7) // Limit the number of digits to 7
            )
        )
    )
)

Re: NumberEditBox でユーザー入力を 7 桁に制限するにはどうすればよいですか?

この方向から始めることができます。

Names Default to Here( 1 );

last = eon = 0;

New Window( "Only Seven",
	Outline Box( "Enter EON",
		Line Up Box( N Col( 2 ),
			Text Box( "System EON:" ),
			neb = Number Edit Box( eon,
				<< Set Integer Only( 1 ),
				<< Set Minimum( 0 ),
				<< Set Tip( "Enter an integer number with no more than 7 digits")
				<< Set Number Changed(
					Function( { self, number },
						If( Length( Char( number ) ) > 7,
							self << Set( last ),
							last = number
						);
					);
				)
			)
		)
	)
)

Re: NumberEditBox でユーザー入力を 7 桁に制限するにはどうすればよいですか?

このメッセージはどこで見つかりましたか:

<< Set Max Length(7) // Limit the number of digits to 7

数値編集ボックスのプロトコルには表示されません。

Re: NumberEditBox でユーザー入力を 7 桁に制限するにはどうすればよいですか?

こんにちは@PunitPanjwani

これは、スクリプト インデックスの set number changed() と get number changed() の例の修正版です。これで目標にかなり近づくと思います。

Names Default To Here( 1 );
New Window( "Example",
	numBox = Number Edit Box(
		.,
		10,
		<< set number changed(
			Function( { thisBox, value }, /* put my value into my sibling's display */
				if( length( char( value ) ) > 7,
					// > 7 digits
					thisBox << set( . );
					( thisBox << sib ) << settext( "Too many digits" ),
				
					// <= 7 digits
					( thisBox << sib ) << settext( char( value ) )
				)
			)
		)
	),
	Text Box( "" )/* here's the sibling box, waiting to show a message */
);
numBox << get number changed()

Re: NumberEditBox でユーザー入力を 7 桁に制限するにはどうすればよいですか?

このバージョンでは、ユーザーが番号の変更をコミットする必要があります。

Names Default to Here( 1 );

last = eon = 0;

New Window( "Only Seven",
	Outline Box( "Enter EON",
		Line Up Box( N Col( 2 ),
			Text Box( "System EON:" ),
			neb = Number Edit Box( eon,
				<< Set Integer Only( 1 ),
				<< Set Minimum( 0 ),
				<< Set Tip( "Enter an integer number with no more than 7 digits"),
				<< Set Function(	// called when user commits data entry
					Function( { self },
						new = self << Get;
						If( Length( Char( new ) ) > 7,
							self << Set( last ),
							last = new
						);
					);
				)
			)
		)
	)
);

Re: NumberEditBox でユーザー入力を 7 桁に制限するにはどうすればよいですか?

これを行うにはさまざまな方法があり、UI をどのように動作させたいかによって異なります。

• ユーザーが数字を入力しすぎると、エラーメッセージが表示されます
• ユーザーが入力した数字が多すぎる場合は、値を最大許容数に設定します
• ユーザーが入力した数字が多すぎる場合は、値を空の値（欠損値）に設定します。
• ユーザーが入力した数字が多すぎる場合は、値を最後の「有効な」値に設定します。
• ...

次に、コミット時か、数値の変更ごとに値を更新するかを決定する必要があります。

以下にいくつかのオプションを示します。必要に応じて組み合わせることができます。

もっと見る...

Names Default To Here(1);

nw = New Window("Example",
	Lineup Box(N Col(2),
	
		Text Box("Set to max value on COMMIT:"),
		Number Edit Box(
			.
			, 10
			, << Set Maximum(9999999)
			, << Set Exclude Maximum(0)
			, << Set Integer Only(1)
		),
		
		Text Box("Set to last COMMITTED value on COMMIT:"),
		cb = Context Box(
			box:last_val = .;
			Number Edit Box(
				.
				, 10
				, << Set Function(function({this},
					If((this << get) >= 10000000,
						this << set(box:last_val)
					,
						box:last_val = this << get;
					)
				))
			)
		),
		
		Text Box("Throw on COMMIT"),
		cb = Context Box(
			box:last_val = .;
			Number Edit Box(
				.
				, 10
				, << Set Function(function({this},
					If((this << get) >= 10000000,
						this << set(box:last_val);
						Throw("No values longer than 7 digits allowed");
					,	
						box:last_val = this << get;
					)
				))
			)
		),
		
		Text Box("Set to last changed value on change and break focus:"),
		cb = Context Box(
			box:last_val = .;
			Number Edit Box(
				.
				, 10
				, << Set Number Changed(function({this, val},
					If((val) >= 10000000,
						this << set(box:last_val);
						box:mb << Set Focus(1); // to break focus from number edit box
					,
						box:last_val = val;
					)
				))
			),
			Unlineup Box(box:mb = Mouse Box());
		)
	)
);

Re: NumberEditBox でユーザー入力を 7 桁に制限するにはどうすればよいですか?

ありがとう、マーク！

Re: NumberEditBox でユーザー入力を 7 桁に制限するにはどうすればよいですか?

ありがとう、Jarmo！