Wie beschränke ich die Benutzereingabe in NumberEditBox auf 7 Ziffern?ECN = 0,
Text Box( "System ECN:" ),
S1 = Number Edit Box(ECN, <<SET property=""></SET>
The user shouldn't be able to enter more than 7 digits. For example: 1234567... the user shouldn't be able to enter 8.
How did achieve this?
Any help is appreciated.
<LINGO-LABS id="lingo-labs-750800" slang="en-US" mode="CREATE"><LINGO-LABEL>Datenexploration und -visualisierung</LINGO-LABEL><LINGO-LABEL>Windows</LINGO-LABEL></LINGO-LABS>Betreff: Wie kann ich die Benutzereingabe in der NumberEditBox auf 7 Ziffern beschränken?Danke, Mark!
Ich habe den Code wie unten gezeigt geändert, aber immer noch keinen Erfolg. Glauben Sie, dass es in der JMP-Software eine große Rolle spielt?
Names Default to Here( 1 );
last = eon = 0;
New Window( "Only Seven",
Outline Box( "Enter EON",
Line Up Box( N Col( 2 ),
Text Box( "System EON:" ),
neb = Number Edit Box( eon,
<< Set Integer Only( 1 ),
<< Set Minimum( 0 ),
<< Set Tip( "Enter an integer number with no more than 7 digits")
<< Set Number Changed(
Function( { self, number },
If( Length( Char( number ) ) > 7,
self << Set( last ),
last = number
);
);
),
<< Set Max Length(7) // Limit the number of digits to 7
)
)
)
)Betreff: Wie kann ich die Benutzereingabe in der NumberEditBox auf 7 Ziffern beschränken?In diese Richtung können Sie starten.
Names Default to Here( 1 );
last = eon = 0;
New Window( "Only Seven",
Outline Box( "Enter EON",
Line Up Box( N Col( 2 ),
Text Box( "System EON:" ),
neb = Number Edit Box( eon,
<< Set Integer Only( 1 ),
<< Set Minimum( 0 ),
<< Set Tip( "Enter an integer number with no more than 7 digits")
<< Set Number Changed(
Function( { self, number },
If( Length( Char( number ) ) > 7,
self << Set( last ),
last = number
);
);
)
)
)
)
)Betreff: Wie kann ich die Benutzereingabe in der NumberEditBox auf 7 Ziffern beschränken?Wo haben Sie diese Nachricht gefunden:
<< Set Max Length(7) // Limit the number of digits to 7
Ich sehe es nicht im Protokoll für ein Nummernbearbeitungsfeld.
Betreff: Wie kann ich die Benutzereingabe in der NumberEditBox auf 7 Ziffern beschränken?Hallo @PunitPanjwani
Dies ist eine modifizierte Version des Beispiels von set number changed() und get number changed() im Scripting Index. Ich denke, damit kommen Sie Ihrem Ziel ziemlich nahe:
Names Default To Here( 1 );
New Window( "Example",
numBox = Number Edit Box(
.,
10,
<< set number changed(
Function( { thisBox, value }, /* put my value into my sibling's display */
if( length( char( value ) ) > 7,
// > 7 digits
thisBox << set( . );
( thisBox << sib ) << settext( "Too many digits" ),
// <= 7 digits
( thisBox << sib ) << settext( char( value ) )
)
)
)
),
Text Box( "" )/* here's the sibling box, waiting to show a message */
);
numBox << get number changed()
Betreff: Wie kann ich die Benutzereingabe in der NumberEditBox auf 7 Ziffern beschränken?Diese Version erfordert, dass der Benutzer die Änderungen an der Nummer bestätigt.
Names Default to Here( 1 );
last = eon = 0;
New Window( "Only Seven",
Outline Box( "Enter EON",
Line Up Box( N Col( 2 ),
Text Box( "System EON:" ),
neb = Number Edit Box( eon,
<< Set Integer Only( 1 ),
<< Set Minimum( 0 ),
<< Set Tip( "Enter an integer number with no more than 7 digits"),
<< Set Function( // called when user commits data entry
Function( { self },
new = self << Get;
If( Length( Char( new ) ) > 7,
self << Set( last ),
last = new
);
);
)
)
)
)
);Betreff: Wie kann ich die Benutzereingabe in der NumberEditBox auf 7 Ziffern beschränken?Hierfür gibt es verschiedene Möglichkeiten und es hängt davon ab, welches Verhalten Ihre Benutzeroberfläche haben soll:
- Wenn der Benutzer zu viele Zahlen eingibt, wird eine Fehlermeldung ausgegeben
- Wenn der Benutzer zu viele Zahlen eingibt, setzen Sie den Wert auf die maximal zulässige Zahl
- Wenn der Benutzer zu viele Zahlen eingibt, setzen Sie den Wert auf einen leeren Wert (fehlender Wert).
- Wenn der Benutzer zu viele Zahlen eingibt, setzen Sie den Wert auf den letzten „gültigen“ Wert
- ...
Anschließend muss entschieden werden, wann der Wert aktualisiert werden soll: beim Commit oder bei jeder Zahlenänderung?
Nachfolgend finden Sie einige Optionen, die nach Bedarf kombiniert werden können
Mehr sehen...
Names Default To Here(1);
nw = New Window("Example",
Lineup Box(N Col(2),
Text Box("Set to max value on COMMIT:"),
Number Edit Box(
.
, 10
, << Set Maximum(9999999)
, << Set Exclude Maximum(0)
, << Set Integer Only(1)
),
Text Box("Set to last COMMITTED value on COMMIT:"),
cb = Context Box(
box:last_val = .;
Number Edit Box(
.
, 10
, << Set Function(function({this},
If((this << get) >= 10000000,
this << set(box:last_val)
,
box:last_val = this << get;
)
))
)
),
Text Box("Throw on COMMIT"),
cb = Context Box(
box:last_val = .;
Number Edit Box(
.
, 10
, << Set Function(function({this},
If((this << get) >= 10000000,
this << set(box:last_val);
Throw("No values longer than 7 digits allowed");
,
box:last_val = this << get;
)
))
)
),
Text Box("Set to last changed value on change and break focus:"),
cb = Context Box(
box:last_val = .;
Number Edit Box(
.
, 10
, << Set Number Changed(function({this, val},
If((val) >= 10000000,
this << set(box:last_val);
box:mb << Set Focus(1); // to break focus from number edit box
,
box:last_val = val;
)
))
),
Unlineup Box(box:mb = Mouse Box());
)
)
);
Betreff: Wie kann ich die Benutzereingabe in der NumberEditBox auf 7 Ziffern beschränken?Danke, Mark!
Betreff: Wie kann ich die Benutzereingabe in der NumberEditBox auf 7 Ziffern beschränken?Danke, Jarmo!
