Comment limiter la saisie utilisateur à 7 chiffres dans NumberEditBox ?ECN = 0,
Text Box( "System ECN:" ),
S1 = Number Edit Box(ECN, <<SET property=""></SET>
The user shouldn't be able to enter more than 7 digits. For example: 1234567... the user shouldn't be able to enter 8.
How did achieve this?
Any help is appreciated.
<LINGO-LABS id="lingo-labs-750800" slang="en-US" mode="CREATE"><LINGO-LABEL>Exploration et visualisation des données</LINGO-LABEL><LINGO-LABEL>les fenêtres</LINGO-LABEL></LINGO-LABS>Re : Comment limiter la saisie utilisateur à 7 chiffres dans NumberEditBox ?Merci Marc !
J'ai modifié le code comme indiqué ci-dessous, mais toujours sans succès. Pensez-vous que c'est un élément important du logiciel JMP ?
Names Default to Here( 1 );
last = eon = 0;
New Window( "Only Seven",
Outline Box( "Enter EON",
Line Up Box( N Col( 2 ),
Text Box( "System EON:" ),
neb = Number Edit Box( eon,
<< Set Integer Only( 1 ),
<< Set Minimum( 0 ),
<< Set Tip( "Enter an integer number with no more than 7 digits")
<< Set Number Changed(
Function( { self, number },
If( Length( Char( number ) ) > 7,
self << Set( last ),
last = number
);
);
),
<< Set Max Length(7) // Limit the number of digits to 7
)
)
)
)Re : Comment limiter la saisie utilisateur à 7 chiffres dans NumberEditBox ?Vous pouvez commencer dans cette direction.
Names Default to Here( 1 );
last = eon = 0;
New Window( "Only Seven",
Outline Box( "Enter EON",
Line Up Box( N Col( 2 ),
Text Box( "System EON:" ),
neb = Number Edit Box( eon,
<< Set Integer Only( 1 ),
<< Set Minimum( 0 ),
<< Set Tip( "Enter an integer number with no more than 7 digits")
<< Set Number Changed(
Function( { self, number },
If( Length( Char( number ) ) > 7,
self << Set( last ),
last = number
);
);
)
)
)
)
)Re : Comment limiter la saisie utilisateur à 7 chiffres dans NumberEditBox ?Où as-tu trouvé ce message :
<< Set Max Length(7) // Limit the number of digits to 7
Je ne le vois pas dans le protocole d'une zone d'édition de numéro.
Re : Comment limiter la saisie utilisateur à 7 chiffres dans NumberEditBox ?Salut @PunitPanjwani
Il s'agit d'une version modifiée de l'exemple de set number changes() et get number changes() dans l'index de script. Je pense que cela vous rapproche assez de votre objectif :
Names Default To Here( 1 );
New Window( "Example",
numBox = Number Edit Box(
.,
10,
<< set number changed(
Function( { thisBox, value }, /* put my value into my sibling's display */
if( length( char( value ) ) > 7,
// > 7 digits
thisBox << set( . );
( thisBox << sib ) << settext( "Too many digits" ),
// <= 7 digits
( thisBox << sib ) << settext( char( value ) )
)
)
)
),
Text Box( "" )/* here's the sibling box, waiting to show a message */
);
numBox << get number changed()
Re : Comment limiter la saisie utilisateur à 7 chiffres dans NumberEditBox ?Cette version nécessite que l'utilisateur valide les modifications apportées au numéro.
Names Default to Here( 1 );
last = eon = 0;
New Window( "Only Seven",
Outline Box( "Enter EON",
Line Up Box( N Col( 2 ),
Text Box( "System EON:" ),
neb = Number Edit Box( eon,
<< Set Integer Only( 1 ),
<< Set Minimum( 0 ),
<< Set Tip( "Enter an integer number with no more than 7 digits"),
<< Set Function( // called when user commits data entry
Function( { self },
new = self << Get;
If( Length( Char( new ) ) > 7,
self << Set( last ),
last = new
);
);
)
)
)
)
);Re : Comment limiter la saisie utilisateur à 7 chiffres dans NumberEditBox ?Il existe différentes manières de procéder et cela dépend de la manière dont vous souhaitez que votre interface utilisateur se comporte :
- Si l'utilisateur insère trop de nombres, un message d'erreur est généré
- Si l'utilisateur insère trop de nombres, définissez la valeur sur le nombre maximum autorisé.
- Si l'utilisateur insère trop de nombres, définissez la valeur sur une valeur vide (valeur manquante)
- Si l'utilisateur insère trop de nombres, définissez la valeur sur la dernière valeur "valide"
- ...
Ensuite, vous devez décider quand la valeur doit être mise à jour : à la validation ou à chaque changement de numéro ?
Vous trouverez ci-dessous quelques options, celles-ci peuvent être combinées selon vos besoins
Voir plus...
Names Default To Here(1);
nw = New Window("Example",
Lineup Box(N Col(2),
Text Box("Set to max value on COMMIT:"),
Number Edit Box(
.
, 10
, << Set Maximum(9999999)
, << Set Exclude Maximum(0)
, << Set Integer Only(1)
),
Text Box("Set to last COMMITTED value on COMMIT:"),
cb = Context Box(
box:last_val = .;
Number Edit Box(
.
, 10
, << Set Function(function({this},
If((this << get) >= 10000000,
this << set(box:last_val)
,
box:last_val = this << get;
)
))
)
),
Text Box("Throw on COMMIT"),
cb = Context Box(
box:last_val = .;
Number Edit Box(
.
, 10
, << Set Function(function({this},
If((this << get) >= 10000000,
this << set(box:last_val);
Throw("No values longer than 7 digits allowed");
,
box:last_val = this << get;
)
))
)
),
Text Box("Set to last changed value on change and break focus:"),
cb = Context Box(
box:last_val = .;
Number Edit Box(
.
, 10
, << Set Number Changed(function({this, val},
If((val) >= 10000000,
this << set(box:last_val);
box:mb << Set Focus(1); // to break focus from number edit box
,
box:last_val = val;
)
))
),
Unlineup Box(box:mb = Mouse Box());
)
)
);
Re : Comment limiter la saisie utilisateur à 7 chiffres dans NumberEditBox ?Merci, Marc!
Re : Comment limiter la saisie utilisateur à 7 chiffres dans NumberEditBox ?Merci Jarmo !
