739343_de-DE

liliconcom

So fügen Sie Text in Tabulate hinzu.

Ich versuche, den Fehlerbehälter, der alphabetisch geordnet ist, in die Tabelle einzufügen. Gibt es eine Möglichkeit, dies zu erreichen?

Grundlegende Datenanalyse und ModellierungBetreff: So fügen Sie in Tabulate Text hinzu.

Ich bin nicht sicher, ob Sie diese Art von Ergebnis mit Tabulate erzielen können ( verwenden Sie die Tabulate- Plattform, um interaktiv Übersichtstabellen oder Pivot-Tabellen mit beschreibenden Statistiken zu erstellen ), aber Sie können ähnliche Tabellen mit Split oder Transpose erstellen.

und benennen Sie diese 1 2 3 dann in Run1, Run2, Run3 um.

Mit tabulate erhalten Sie etwas wie

Betreff: So fügen Sie in Tabulate Text hinzu.

Hier ist meine alternative Herangehensweise an diese Anfrage, indem ich etwas JSL verwende, um eine Tabellenbox zu erstellen

Names Default To Here( 1 );
dt = New Table( "JMP Help",
	Add Rows( 9 ),
	New Column( "Run",
		Numeric,
		"Ordinal",
		Format( "Best", 12 ),
		Formula( Col Cumulative Sum( 1, :Serial Number ) ),
		Set Display Width( 38 )
	),
	New Column( "Serial Number",
		Character( 4 ),
		Set Values(
			{"1001", "1001", "1001", "1002", "1002", "1002", "1003", "1003", "1003"}
		),
		Set Display Width( 81 )
	),
	New Column( "Failure Bin",
		Character( 1 ),
		Set Values( {"A", "A", "B", "A", "B", "B", "C", "C", "A"} ),
		Set Display Width( 59 )
	)
);

dtSplit = dt << Split(
	Split By( :Run ),
	Split( :Failure Bin ),
	Group( :Serial Number ),
	Output Table( "Split" ),
	Sort by Column Property
);

nw = New Window( "Tabulate",
	tb = Table Box(
		Col Span Box(
			"",
			sn = String Col Box( "Serial Number",
				dtSplit:Serial Number << get values
			)
		),
		Col Span Box(
			"Run",
			scb1 = String Col Box( "1", dtSplit:"1"n << get values ),
			scb2 = String Col Box( "2", dtSplit:"2"n << get values ),
			scb3 = String Col Box( "3", dtSplit:"3"n << get values )
		)
	)
);
sn << set width( 100 );
scb1 << set width( 30 ) << set justify( "center" );
scb2 << set width( 30 ) << set justify( "center" );
scb3 << set width( 30 ) << set justify( "center" );
tb << Set Row Borders( 1 );
tb << Set Column Borders( 1 );