744967_zh-TW

liliconcom

字串解析問題

親愛的社區，

我正在 1 個單元格中接收帶有識別資訊的資料。

Names Default to Here(1);

dt = New Table("Sample",
add rows(2),
	New Column( "Field_9630", Character, "Nominal" )
);

dt:Field_9630 << Set Values({"Customer: Mr A LoyalProduct: Cabinet HardwareRegion: Suburban New Dev", "Customer: Jenifer B Ashley LeighProduct: LumberRegion: Suburban Existing"});

目標是產生三列 - 客戶、產品、區域

dt2 = New Table( "Sample 2",
	Add Rows( 2 ),
	New Column( "Field_9630",
		Character,
		"Nominal",
		Set Selected,
		Set Values(
			{"Customer: Mr A LoyalProduct: Cabinet HardwareRegion: Suburban New Dev",
			"Customer: Jenifer B Ashley LeighProduct: LumberRegion: Suburban Existing"
			}
		),
		Set Display Width( 132 )
	),
	New Column( "Customer",
		Character,
		"Nominal",
		Set Values( {"Mr A Loyal", "Jenifer B Ashley Leigh"} )
	),
	New Column( "Product",
		Character,
		"Nominal",
		Set Values( {"Cabinet Hardware", "Lumber"} )
	),
	New Column( "Region",
		Character,
		"Nominal",
		Set Values( {"Suburban New Dev", "Suburban Existing"} )
	)
);

提前謝謝了！

真摯地，

MG

自動化和腳本編寫資料混合與清理回覆：字串解析問題

你好，

當沒有明確的分隔符號時，解析字串總是很困難。

假設輸入字串始終包含關鍵字“Customer:”、“Product:”和“Region:”，您可以使用下列方法：

1. 使用 SUBSTITUTE() 函數將關鍵字替換為“,”
2. 使用WORD()函數解析相關信息
3. 使用 TRIM() 函數清理產生的字串。

New Table( "Sample_PARSED",
	Add Rows( 2 ),
	New Column( "Field_9630",
		Character,
		"Nominal",
		Set Values(
			{"Customer: Mr A LoyalProduct: Cabinet HardwareRegion: Suburban New Dev",
			"Customer: Jenifer B Ashley LeighProduct: LumberRegion: Suburban Existing"
			}
		),
		Set Display Width( 726 )
	),
	New Column( "TEMP",
		Character,
		"Nominal",
		Formula(
			Substitute( :Field_9630,
				"Customer:", ",",
				"Product:", ",",
				"Region:", ","
			)
		)
	),
	New Column( "Column 2",
		Character,
		"Nominal",
		Formula( Trim( Word( 1, :TEMP, "," ) ) ),
		Set Display Width( 157 )
	),
	New Column( "Column 3",
		Character,
		"Nominal",
		Formula( Trim( Word( 2, :TEMP, "," ) ) )
	),
	New Column( "Column 4",
		Character,
		"Nominal",
		Formula( Trim( Word( 3, :TEMP, "," ) ) ),
		Set Display Width( 200 )
	)
)

我希望它有幫助。

最好的，

TS

回覆：字串解析問題

@Thierry_S感謝您的快速回覆和解決方案。非常感激！