739343_fr-FR

liliconcom

Comment ajouter du texte dans Tabulate.

J'essaie de mettre le bac d'échec, qui est alphabétique dans le tableau. Existe-t-il une solution pour y parvenir ?

Analyse et modélisation des données de baseRe : Comment ajouter du texte dans Tabulate.

Voici ma façon alternative d'aborder cette demande, en utilisant du JSL pour créer une Table Box

Names Default To Here( 1 );
dt = New Table( "JMP Help",
	Add Rows( 9 ),
	New Column( "Run",
		Numeric,
		"Ordinal",
		Format( "Best", 12 ),
		Formula( Col Cumulative Sum( 1, :Serial Number ) ),
		Set Display Width( 38 )
	),
	New Column( "Serial Number",
		Character( 4 ),
		Set Values(
			{"1001", "1001", "1001", "1002", "1002", "1002", "1003", "1003", "1003"}
		),
		Set Display Width( 81 )
	),
	New Column( "Failure Bin",
		Character( 1 ),
		Set Values( {"A", "A", "B", "A", "B", "B", "C", "C", "A"} ),
		Set Display Width( 59 )
	)
);

dtSplit = dt << Split(
	Split By( :Run ),
	Split( :Failure Bin ),
	Group( :Serial Number ),
	Output Table( "Split" ),
	Sort by Column Property
);

nw = New Window( "Tabulate",
	tb = Table Box(
		Col Span Box(
			"",
			sn = String Col Box( "Serial Number",
				dtSplit:Serial Number << get values
			)
		),
		Col Span Box(
			"Run",
			scb1 = String Col Box( "1", dtSplit:"1"n << get values ),
			scb2 = String Col Box( "2", dtSplit:"2"n << get values ),
			scb3 = String Col Box( "3", dtSplit:"3"n << get values )
		)
	)
);
sn << set width( 100 );
scb1 << set width( 30 ) << set justify( "center" );
scb2 << set width( 30 ) << set justify( "center" );
scb3 << set width( 30 ) << set justify( "center" );
tb << Set Row Borders( 1 );
tb << Set Column Borders( 1 );

Re : Comment ajouter du texte dans Tabulate.

Je ne suis pas sûr que vous puissiez obtenir ce type de résultat en utilisant Tabulate ( utilisez la plate-forme Tabulate pour construire de manière interactive des tableaux récapitulatifs, ou des tableaux croisés dynamiques, de statistiques descriptives ), mais vous pouvez créer un tableau similaire en utilisant Split ou Transpose

et renommez ensuite ces 1 2 3 en Run1, Run2, Run3.

Avec tabulate, vous obtiendrez quelque chose comme